Adding metadata

4 files changed, 171 insertions, 0 deletions

diff --git a/dev-python/jedi/Manifest b/dev-python/jedi/Manifest
new file mode 100644
index 000000000000..84e7519b7beb
--- /dev/null
+++ b/dev-python/jedi/Manifest
@@ -0,0 +1,4 @@
+DIST django-stubs-fd057010f6cbf176f57d1099e82be46d39b99cb9.tar.gz 183312 BLAKE2B a68f6139903f5001db994ee0d881f40ab74932e81c3e2c3a0c22dc56e6be681d0fb42ce837603b21e4d0d448ccb25884ef0f69039305f309e82603267cee9f6a SHA512 506322c132f94e6a1e88cdbde6027a566387731fa6ad59934f95c3511f49d90eff2a3138363811be648b096407d418cd1f801df0bc35b1e464ef181e4076ada1
+DIST jedi-0.19.2.gh.tar.gz 475890 BLAKE2B e68a6245b0887e50e97f490b15b3f21865250cb954fb7aaa825755c54489aab6543256a4941feb41570cf0cc747f929634e0323aad57a13c0f4273de2af0e3de SHA512 5146e804b7b1b9f9dff2e372c4e3384c15dc05643b399d0aaab797451e9ef43a84914cc5fd4b130c9b4a9d2eff5ab917b3956f4fc6b71394d8e6c8a39467a4ad
+DIST jedi-0.20.0.tar.gz 3119416 BLAKE2B a5e70e6e815b417ce22f518af384d26452695bcc3693505960aba5ed417fdf06f23e9d9d197b1b0aae17fd302c77fc3275390da3828767b395211c118b253970 SHA512 17775ab845b661dd3b93963b12055013a54314680d717087d49f64cb03332a5b5716dbfeb59e821aba34e2962c8bd01b86e8de881fb64dd31b374ef58b50ff00
+DIST typeshed-ae9d4f4b21bb5e1239816c301da7b1ea904b44c3.tar.gz 602044 BLAKE2B 53298918a7e9a1163e76d4c70ad2a2117ee90b49329aa82d82b2aaaeaf000c971872f83ed283af6dc4be068b813876760c8b1b4acb4131865572a4aed3ea9230 SHA512 b3b9da66b6c6e03e0b262b3262df31215a5e080468ca9ebf4332ed53d715cd3956db7067fad3ec267042ff704f81ac665c703ef2fd0c5b445d440bd8e52bf1aa
diff --git a/dev-python/jedi/jedi-0.19.2.ebuild b/dev-python/jedi/jedi-0.19.2.ebuild
new file mode 100644
index 000000000000..463dfb0490de
--- /dev/null
+++ b/dev-python/jedi/jedi-0.19.2.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1
+
+TYPESHED_P="typeshed-ae9d4f4b21bb5e1239816c301da7b1ea904b44c3"
+DJANGO_STUBS_P="django-stubs-fd057010f6cbf176f57d1099e82be46d39b99cb9"
+EGIT_COMMIT="82d1902f382ddac5b0e6647646b72f28a3181ec3"
+
+DESCRIPTION="Autocompletion library for Python"
+HOMEPAGE="
+	https://github.com/davidhalter/jedi/
+	https://pypi.org/project/jedi/
+"
+SRC_URI="
+	https://github.com/davidhalter/jedi/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+	https://github.com/davidhalter/typeshed/archive/${TYPESHED_P#typeshed-}.tar.gz
+		-> ${TYPESHED_P}.tar.gz
+	https://github.com/davidhalter/django-stubs/archive/${DJANGO_STUBS_P#django-stubs-}.tar.gz
+		-> ${DJANGO_STUBS_P/v/}.tar.gz
+"
+
+LICENSE="
+	MIT
+	test? ( Apache-2.0 )
+"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ppc ppc64 ~riscv ~s390 ~sparc x86 ~arm64-macos ~x64-macos"
+
+RDEPEND="
+	<dev-python/parso-0.9[${PYTHON_USEDEP}]
+	>=dev-python/parso-0.8.3[${PYTHON_USEDEP}]
+"
+
+# RDEPEND needed because of an import jedi inside conf.py
+distutils_enable_sphinx docs \
+	dev-python/parso \
+	dev-python/sphinx-rtd-theme
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# upstream includes these as submodules ...
+	rmdir "${S}"/jedi/third_party/{django-stubs,typeshed} || die
+	mv "${WORKDIR}/${DJANGO_STUBS_P/v/}" \
+		"${S}/jedi/third_party/django-stubs" || die
+	mv "${WORKDIR}/${TYPESHED_P}" \
+		"${S}/jedi/third_party/typeshed" || die
+
+	# test_complete_expanduser relies on $HOME not being empty
+	> "${HOME}"/somefile || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# fragile
+		test/test_speed.py
+		# assumes pristine virtualenv
+		test/test_inference/test_imports.py::test_duplicated_import
+		test/test_inference/test_imports.py::test_os_issues
+	)
+
+	case ${EPYTHON} in
+		pypy3.11)
+			EPYTEST_DESELECT+=(
+				test/test_api/test_interpreter.py::test_param_infer_default
+				test/test_inference/test_compiled.py::test_next_docstr
+				test/test_inference/test_compiled.py::test_time_docstring
+				test/test_inference/test_gradual/test_typeshed.py::test_module_exists_only_as_stub
+			)
+			;;
+		python3.14*)
+			EPYTEST_DESELECT+=(
+				# type annotation printing difference
+				test/test_inference/test_mixed.py::test_compiled_signature_annotation_string
+				# extra attributes in os
+				test/test_utils.py::TestSetupReadline::test_import
+			)
+			;;
+	esac
+
+	# some plugin breaks case-insensitivity on completions
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	# django and pytest tests are very version dependent
+	epytest -o addopts= -k "not django and not pytest"
+}
diff --git a/dev-python/jedi/jedi-0.20.0.ebuild b/dev-python/jedi/jedi-0.20.0.ebuild
new file mode 100644
index 000000000000..c32bbb4cd1bd
--- /dev/null
+++ b/dev-python/jedi/jedi-0.20.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Autocompletion library for Python"
+HOMEPAGE="
+	https://github.com/davidhalter/jedi/
+	https://pypi.org/project/jedi/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
+
+RDEPEND="
+	<dev-python/parso-0.9[${PYTHON_USEDEP}]
+	>=dev-python/parso-0.8.6[${PYTHON_USEDEP}]
+"
+
+# RDEPEND needed because of an import jedi inside conf.py
+distutils_enable_sphinx docs \
+	dev-python/parso \
+	dev-python/sphinx-rtd-theme
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# test_complete_expanduser relies on $HOME not being empty
+	> "${HOME}"/somefile || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# fragile
+		test/test_speed.py
+		# assumes pristine virtualenv
+		test/test_inference/test_imports.py::test_duplicated_import
+		test/test_inference/test_imports.py::test_os_issues
+	)
+
+	case ${EPYTHON} in
+		pypy3.11)
+			EPYTEST_DESELECT+=(
+				test/test_api/test_api.py::test_preload_modules
+				test/test_api/test_interpreter.py::test_param_infer_default
+				test/test_inference/test_compiled.py::test_next_docstr
+				test/test_inference/test_compiled.py::test_time_docstring
+				test/test_inference/test_gradual/test_typeshed.py::test_module_exists_only_as_stub
+				test/test_utils.py::TestSetupReadline::test_import
+			)
+			;;
+	esac
+
+	# django and pytest tests are very version dependent
+	epytest -o addopts= -k "not django and not pytest"
+}
diff --git a/dev-python/jedi/metadata.xml b/dev-python/jedi/metadata.xml
new file mode 100644
index 000000000000..5e95859f915a
--- /dev/null
+++ b/dev-python/jedi/metadata.xml
@@ -0,0 +1,10 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <stabilize-allarches />
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>