Updating liguros repo

4 files changed, 108 insertions, 0 deletions

diff --git a/dev-python/inflect/Manifest b/dev-python/inflect/Manifest
new file mode 100644
index 000000000000..b634e09480fa
--- /dev/null
+++ b/dev-python/inflect/Manifest
@@ -0,0 +1,2 @@
+DIST inflect-3.0.2.tar.gz 71546 BLAKE2B 951eb818ba1645a9e426468811ad449378aa5a7341575ac2aff5e9d1e06237fe8e96fa64cd678665cd6c05e1dc5e477a65b261b9d8bd170be4fb923d5fb90e9c SHA512 5858548e947f742b91630fc584f568a2221057ada7cd4a55f39de1b52a82c97884d6a78c2f32e5995e354fd1c4eae4d5b3d30491ef57dd5187fd6baca93d2779
+DIST inflect-4.1.0.tar.gz 72200 BLAKE2B c15f6b0d5d93050283dfc4d691e9fdbc26bb2f71573d6b397834e87af62f3afb8f5cdb0448c531de37e84729c0c6ae0cf4ea7a7b081a9dd784f7c06b962d7def SHA512 9a2ba4777f01475390976f3ac28f046d39d1f86cfdafd161cc7c8d33526aca35d44e6598ccf2a0b68d3511a64b67ed0991b51c78bda8f279cd706fd29a3fa514
diff --git a/dev-python/inflect/inflect-3.0.2.ebuild b/dev-python/inflect/inflect-3.0.2.ebuild
new file mode 100644
index 000000000000..e87f18512a29
--- /dev/null
+++ b/dev-python/inflect/inflect-3.0.2.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy3 python{2_7,3_{6,7}} )
+
+inherit distutils-r1
+
+DESCRIPTION="Correctly inflect words and numbers"
+HOMEPAGE="https://github.com/jazzband/inflect"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="amd64 arm64 x86"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+# nose is still required by some test features
+# https://github.com/jazzband/inflect/issues/90
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	doc? (
+		>=dev-python/jaraco-packaging-3.2[${PYTHON_USEDEP}]
+		>=dev-python/rst-linker-1.9[${PYTHON_USEDEP}]
+		dev-python/alabaster[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/six[${PYTHON_USEDEP}]
+	)
+"
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build docs docs/_build/html || die
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	# Override pytest options to skip flake8
+	pytest -vv tests --override-ini="addopts=--doctest-modules" \
+		|| die "tests failed with ${EPYTHON}"
+}
diff --git a/dev-python/inflect/inflect-4.1.0.ebuild b/dev-python/inflect/inflect-4.1.0.ebuild
new file mode 100644
index 000000000000..11e5def6d12f
--- /dev/null
+++ b/dev-python/inflect/inflect-4.1.0.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy3 python3_{6,7,8} )
+# [options.entry_points] is present in setup.cfg but it is empty
+DISTUTILS_USE_SETUPTOOLS=manual
+
+inherit distutils-r1
+
+DESCRIPTION="Correctly inflect words and numbers"
+HOMEPAGE="https://github.com/jazzband/inflect"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ppc ppc64 sparc x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	$(python_gen_cond_dep 'dev-python/importlib_metadata[${PYTHON_USEDEP}]' pypy3 python3_{6,7})
+"
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/setuptools_scm-3.4.1[${PYTHON_USEDEP}]
+	dev-python/toml[${PYTHON_USEDEP}]
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )
+"
+
+distutils_enable_sphinx docs '>=dev-python/jaraco-packaging-3.2' \
+	'>=dev-python/rst-linker-1.9' dev-python/alabaster
+
+python_test() {
+	# Override pytest options to skip flake8
+	pytest -vv tests --override-ini="addopts=--doctest-modules" \
+		|| die "tests failed with ${EPYTHON}"
+}
diff --git a/dev-python/inflect/metadata.xml b/dev-python/inflect/metadata.xml
new file mode 100644
index 000000000000..ed45fd45e92d
--- /dev/null
+++ b/dev-python/inflect/metadata.xml
@@ -0,0 +1,18 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>sbraz@gentoo.org</email>
+		<name>Louis Sautier</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+		<name>Python</name>
+	</maintainer>
+	<stabilize-allarches/>
+	<upstream>
+		<remote-id type="pypi">inflect</remote-id>
+		<remote-id type="github">jazzband/inflect</remote-id>
+	</upstream>
+	<origin>gentoo-staging</origin>
+</pkgmetadata>