Adding metadata

3 files changed, 94 insertions, 2 deletions

diff --git a/dev-python/hypothesis/Manifest b/dev-python/hypothesis/Manifest
index 59ae8d30df71..a7b3bffe58da 100644
--- a/dev-python/hypothesis/Manifest
+++ b/dev-python/hypothesis/Manifest
@@ -8,3 +8,4 @@ DIST hypothesis-6.148.9.gh.tar.gz 9927137 BLAKE2B 04a5b5c8a120fec3926082b3607cc3
 DIST hypothesis-6.149.0.gh.tar.gz 9932424 BLAKE2B eb7433e0b5ab92dafd7d5659d1141e1d64ce808144ce3bc2b0b1717e1f76afc2c6d2adb597ba66124fe5df4d9e5ec5f87eb9875f1f17272873ee02c985761777 SHA512 0d1d79664f695bb4e674cc65125aee5a8940754801ffbc2f97a95291835415b541a86d3157164f7a5284afbca2c2cfee5c958f242c4309e584445d4356c500a8
 DIST hypothesis-6.149.1.gh.tar.gz 9932484 BLAKE2B 41bdda077c6cdd1e2b2f7650e8b4f5e125680ec3cea2979ad14dadcb553f36f0fd5970290d23aadd5bad64ba88c9dbb669946ca71021460c509e25bccdf394fa SHA512 78dfbdd8f48ca9c483b74fb13200b340b1791df977f79d8fc687cecc21a6c69dc37a6e0c184643f2eb13d5a49651e13e4ea2ed93976dcc4fa7ee135c2d4ee052
 DIST hypothesis-6.150.0.gh.tar.gz 9932927 BLAKE2B b20631a108f8c79635be7ad57587f6a5f3020f653d087a26749cb9e0fe9e357942103a9e391d5fd16e1d771538009979f2ceb21fa421396219f33d45a6a75d10 SHA512 490eda1bbe74fc26365452ecf5641830cf9991a46ca877c2b823f8ab8cc05917fd2742b973ae2c91ceaefe8440b82961a5b14cb4381572fa8416877c784c3afa
+DIST hypothesis-6.150.1.gh.tar.gz 9878291 BLAKE2B 13a7ca820e8127fd86895cc203ef150046117ab8d9178a77b5c0844120ebc329e812d5d3d205ba03a9b96a5a7f8cc3ec4db17c04c4f459526e30fcc1659e2684 SHA512 bd5a8838fcc20cc78eae56df7ac380cfae4cffc5b8e8761f5ab4907cc98e83304221d967e1e583f1d42810da801e8083d919f7898c23d6d8389fef82a082d8a8
diff --git a/dev-python/hypothesis/hypothesis-6.148.7.ebuild b/dev-python/hypothesis/hypothesis-6.148.7.ebuild
index 3239d4fba180..1a631a4da6cb 100644
--- a/dev-python/hypothesis/hypothesis-6.148.7.ebuild
+++ b/dev-python/hypothesis/hypothesis-6.148.7.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2025 Gentoo Authors
+# Copyright 1999-2026 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -25,7 +25,7 @@ S="${WORKDIR}/${MY_P}/hypothesis-python"
 
 LICENSE="MPL-2.0"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
 IUSE="cli"
 
 RDEPEND="
diff --git a/dev-python/hypothesis/hypothesis-6.150.1.ebuild b/dev-python/hypothesis/hypothesis-6.150.1.ebuild
new file mode 100644
index 000000000000..8a0d46501a31
--- /dev/null
+++ b/dev-python/hypothesis/hypothesis-6.150.1.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+CLI_COMPAT=( python3_{11..13} )
+PYTHON_COMPAT=( python3_{10..14} )
+PYTHON_REQ_USE="threads(+),sqlite"
+
+inherit distutils-r1 optfeature
+
+TAG=hypothesis-python-${PV}
+MY_P=hypothesis-${TAG}
+DESCRIPTION="A library for property based testing"
+HOMEPAGE="
+	https://github.com/HypothesisWorks/hypothesis/
+	https://pypi.org/project/hypothesis/
+"
+SRC_URI="
+	https://github.com/HypothesisWorks/hypothesis/archive/${TAG}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/hypothesis-python"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="cli"
+
+RDEPEND="
+	>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
+	cli? (
+		$(python_gen_cond_dep '
+			dev-python/black[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+		' "${CLI_COMPAT[@]}")
+	)
+"
+BDEPEND="
+	test? (
+		>=dev-python/attrs-22.2.0[${PYTHON_USEDEP}]
+		dev-python/pexpect[${PYTHON_USEDEP}]
+		>=dev-python/pytest-8[${PYTHON_USEDEP}]
+	)
+"
+PDEPEND="
+	dev-python/hypothesis-gentoo[${PYTHON_USEDEP}]
+"
+
+EPYTEST_PLUGIN_LOAD_VIA_ENV=1
+EPYTEST_PLUGINS=( "${PN}" pytest-xdist )
+EPYTEST_RERUNS=5
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+	# NB: paths need to be relative to pytest.ini,
+	# i.e. start with hypothesis-python/
+
+	local -x HYPOTHESIS_NO_PLUGINS=1
+	epytest -o filterwarnings= tests/{cover,pytest,quality}
+}
+
+src_install() {
+	local HAD_CLI=
+
+	distutils-r1_src_install
+
+	if [[ ! ${HAD_CLI} ]]; then
+		rm -r "${ED}/usr/bin" || die
+	fi
+}
+
+python_install() {
+	distutils-r1_python_install
+	if use cli && has "${EPYTHON}" "${CLI_COMPAT[@]/_/.}"; then
+		HAD_CLI=1
+	else
+		rm -r "${D}$(python_get_scriptdir)" || die
+	fi
+}
+
+pkg_postinst() {
+	optfeature "datetime support" dev-python/pytz
+	optfeature "dateutil support" dev-python/python-dateutil
+	optfeature "numpy support" dev-python/numpy
+	optfeature "django support" dev-python/django dev-python/pytz
+	optfeature "pandas support" dev-python/pandas
+	optfeature "pytest support" dev-python/pytest
+}