Adding metadata

3 files changed, 127 insertions, 1 deletions

diff --git a/dev-python/hypothesis/Manifest b/dev-python/hypothesis/Manifest
index 05fb219eb57f..6ceebc696fae 100644
--- a/dev-python/hypothesis/Manifest
+++ b/dev-python/hypothesis/Manifest
@@ -8,3 +8,4 @@ DIST hypothesis-6.140.3.gh.tar.gz 9625658 BLAKE2B 4316d4aa5f4b2b2a476c6d978d0934
 DIST hypothesis-6.141.0.gh.tar.gz 9626287 BLAKE2B 0bf4fcc59f7212a4ba78e052527eda19937d31bc22d311a72ee1fb934bf28fd2b1d292438e1dcd3177457b17337f6bfa8d06ee275f47cd1ee129e68833ef5f97 SHA512 f1b9125669e163c98f9c95767129d149bdd357db5adba66bb6867feffb14ab26395d1494bdd437ff18ef41e798ecda04952050b570ce9ff2e487387ca7d8d79d
 DIST hypothesis-6.141.1.gh.tar.gz 9626528 BLAKE2B f7a45ec59649a616cec57f4ceb4d956a4a3c5bf7bdf264873b5244720118160b6b80309336fd58ca6714e6ba70aa9592f5e68eea4f20cd127840bbadb43d68fe SHA512 efec8874ca2f492f067156b18486deb3930b319d69f04decb99de1c01bd3b9cbcd086243b5be5620711486d94b127043a7311019adaa6b10b597f3d079aecb36
 DIST hypothesis-6.142.1.gh.tar.gz 9624401 BLAKE2B 5c736f7af6fa9437699dc85387ee0383e007443b29f16786c86fad056b994d9f5a10142a59098340511f499f02759bf186b542a4522bdb3670672de14b309933 SHA512 ce72892a521ae9d7ae06949efaa04b41ee48d767fb6e8e4b375baa1ed4f9fc77ec0c49b042ccc0f5eff5ca91a60b1f563e7b32ff4f50659ecccab38d4260cca4
+DIST hypothesis-6.142.2.gh.tar.gz 9624421 BLAKE2B b211bf50f2311e8854197a7b9350248885db01efd9d11447f618cf6a4dd89fb7c41de6a3d25485f7152aa04d4e463150253b31580fd3165975f87b97e351f6d3 SHA512 cfd43aafbe45fc575ebd746b8fac4c0932fcf46b78d64f6d9e419f55a1fca05c417915a714ceb57d0e251751cfbc5b1f4db6e91b8227bedf8702b6d095bf1a96
diff --git a/dev-python/hypothesis/hypothesis-6.139.2.ebuild b/dev-python/hypothesis/hypothesis-6.139.2.ebuild
index 69da4112ef36..79d515617895 100644
--- a/dev-python/hypothesis/hypothesis-6.139.2.ebuild
+++ b/dev-python/hypothesis/hypothesis-6.139.2.ebuild
@@ -25,7 +25,7 @@ S="${WORKDIR}/${MY_P}/hypothesis-python"
 
 LICENSE="MPL-2.0"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
 IUSE="cli"
 
 RDEPEND="
diff --git a/dev-python/hypothesis/hypothesis-6.142.2.ebuild b/dev-python/hypothesis/hypothesis-6.142.2.ebuild
new file mode 100644
index 000000000000..69da4112ef36
--- /dev/null
+++ b/dev-python/hypothesis/hypothesis-6.142.2.ebuild
@@ -0,0 +1,125 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+CLI_COMPAT=( python3_{11..13} )
+PYTHON_COMPAT=( python3_{10..14} )
+PYTHON_REQ_USE="threads(+),sqlite"
+
+inherit distutils-r1 optfeature
+
+TAG=hypothesis-python-${PV}
+MY_P=hypothesis-${TAG}
+DESCRIPTION="A library for property based testing"
+HOMEPAGE="
+	https://github.com/HypothesisWorks/hypothesis/
+	https://pypi.org/project/hypothesis/
+"
+SRC_URI="
+	https://github.com/HypothesisWorks/hypothesis/archive/${TAG}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/hypothesis-python"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="cli"
+
+RDEPEND="
+	>=dev-python/attrs-22.2.0[${PYTHON_USEDEP}]
+	>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
+	cli? (
+		$(python_gen_cond_dep '
+			dev-python/black[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+		' "${CLI_COMPAT[@]}")
+	)
+"
+BDEPEND="
+	test? (
+		dev-python/pexpect[${PYTHON_USEDEP}]
+		>=dev-python/pytest-8[${PYTHON_USEDEP}]
+	)
+"
+PDEPEND="
+	dev-python/hypothesis-gentoo[${PYTHON_USEDEP}]
+"
+
+EPYTEST_PLUGIN_LOAD_VIA_ENV=1
+EPYTEST_PLUGINS=( "${PN}" pytest-xdist )
+EPYTEST_RERUNS=5
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+	# NB: paths need to be relative to pytest.ini,
+	# i.e. start with hypothesis-python/
+	local EPYTEST_DESELECT=()
+	case ${EPYTHON} in
+		python3.13t)
+			EPYTEST_DESELECT+=(
+				# TODO: missing warning
+				'hypothesis-python/tests/cover/test_random_module.py::test_passing_referenced_instance_within_function_scope_warns'
+			)
+			;;
+		python3.14*)
+			EPYTEST_DESELECT+=(
+				'hypothesis-python/tests/cover/test_compat.py::test_resolve_fwd_refs[Foo-Union]'
+				'hypothesis-python/tests/cover/test_lookup.py::test_builds_suggests_from_type[Union]'
+				hypothesis-python/tests/cover/test_attrs_inference.py::test_attrs_inference_builds
+				hypothesis-python/tests/cover/test_lookup.py::test_bytestring_not_treated_as_generic_sequence
+				hypothesis-python/tests/cover/test_lookup.py::test_issue_4194_regression
+				hypothesis-python/tests/cover/test_lookup.py::test_resolves_forwardrefs_to_builtin_types
+				hypothesis-python/tests/cover/test_lookup.py::test_specialised_collection_types
+				hypothesis-python/tests/cover/test_lookup_py37.py::test_resolving_standard_collection_as_generic
+				hypothesis-python/tests/cover/test_lookup_py37.py::test_resolving_standard_container_as_generic
+				hypothesis-python/tests/cover/test_lookup_py37.py::test_resolving_standard_contextmanager_as_generic
+				hypothesis-python/tests/cover/test_lookup_py37.py::test_resolving_standard_iterable_as_generic
+				hypothesis-python/tests/cover/test_lookup_py37.py::test_resolving_standard_reversible_as_generic
+				hypothesis-python/tests/cover/test_lookup_py37.py::test_resolving_standard_sequence_as_generic
+				hypothesis-python/tests/cover/test_random_module.py::test_evil_prng_registration_nonsense
+				hypothesis-python/tests/cover/test_random_module.py::test_passing_referenced_instance_within_function_scope_warns
+				hypothesis-python/tests/cover/test_random_module.py::test_register_random_within_nested_function_scope
+				hypothesis-python/tests/cover/test_random_module.py::test_registering_a_Random_is_idempotent
+				hypothesis-python/tests/cover/test_type_lookup_forward_ref.py::test_bound_missing_dot_access_forward_ref
+				hypothesis-python/tests/cover/test_type_lookup_forward_ref.py::test_bound_missing_forward_ref
+				hypothesis-python/tests/cover/test_type_lookup_forward_ref.py::test_bound_type_checking_only_forward_ref_wrong_type
+				hypothesis-python/tests/cover/test_type_lookup_forward_ref.py::test_bound_type_cheking_only_forward_ref
+			)
+			;;
+	esac
+
+	local -x HYPOTHESIS_NO_PLUGINS=1
+	epytest -o filterwarnings= tests/{cover,pytest,quality}
+}
+
+src_install() {
+	local HAD_CLI=
+
+	distutils-r1_src_install
+
+	if [[ ! ${HAD_CLI} ]]; then
+		rm -r "${ED}/usr/bin" || die
+	fi
+}
+
+python_install() {
+	distutils-r1_python_install
+	if use cli && has "${EPYTHON}" "${CLI_COMPAT[@]/_/.}"; then
+		HAD_CLI=1
+	else
+		rm -r "${D}$(python_get_scriptdir)" || die
+	fi
+}
+
+pkg_postinst() {
+	optfeature "datetime support" dev-python/pytz
+	optfeature "dateutil support" dev-python/python-dateutil
+	optfeature "numpy support" dev-python/numpy
+	optfeature "django support" dev-python/django dev-python/pytz
+	optfeature "pandas support" dev-python/pandas
+	optfeature "pytest support" dev-python/pytest
+}