Adding metadata

1 files changed, 44 insertions, 0 deletions

diff --git a/dev-python/hypercorn/hypercorn-0.18.0.ebuild b/dev-python/hypercorn/hypercorn-0.18.0.ebuild
new file mode 100644
index 000000000000..4b4b43915049
--- /dev/null
+++ b/dev-python/hypercorn/hypercorn-0.18.0.ebuild
@@ -0,0 +1,44 @@
+# Copyright 2022-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pdm-backend
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="A ASGI Server based on Hyper libraries and inspired by Gunicorn"
+HOMEPAGE="
+	https://github.com/pgjones/hypercorn/
+	https://pypi.org/project/Hypercorn/
+"
+SRC_URI="
+	https://github.com/pgjones/hypercorn/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
+
+RDEPEND="
+	dev-python/h11[${PYTHON_USEDEP}]
+	>=dev-python/h2-4.3.0[${PYTHON_USEDEP}]
+	dev-python/priority[${PYTHON_USEDEP}]
+	>=dev-python/wsproto-0.14.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/httpx[${PYTHON_USEDEP}]
+		>=dev-python/trio-0.22.0[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-{asyncio,trio} )
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e 's:--no-cov-on-fail::' pyproject.toml || die
+	distutils-r1_src_prepare
+}