Adding metadata

2 files changed, 96 insertions, 0 deletions

diff --git a/dev-python/httpx/Manifest b/dev-python/httpx/Manifest
index 6dfbfb2e792e..307d6da6aa25 100644
--- a/dev-python/httpx/Manifest
+++ b/dev-python/httpx/Manifest
@@ -1 +1,2 @@
 DIST httpx-0.27.0.gh.tar.gz 2168004 BLAKE2B 2bfe58ffa9bd75b602acf844967d399c2173499981e73296bfc0726ee738219031ac3ac04517dd027f769966b77bf225287490c55435a53aec44b9784a0c4b2e SHA512 9db19cced6554effdb5fb0b442cbe05dc66cbfbdb23e8fbc19f43e1acc81028bca9e0fba5d2dae617b19be9f64baa0f02e727e92fef3f3f1288aa19ae07f35c6
+DIST httpx-0.27.2.gh.tar.gz 2185609 BLAKE2B 7e77cab0e9bda032cd595549e43dfc102f90bb8668b62f6b1f0df6bce6b6358f34aa1f51457a315eb774dde8c76083d180c02ff45283dd348c39b4a659307713 SHA512 c7852ae3e982bacee1587b66aed506f3f7e12caf296e651d3cdd9c111a7d737af49473be455bcabccc8e52487ad18b4821ea56b39500c3b77ed2325fc55505ae
diff --git a/dev-python/httpx/httpx-0.27.2.ebuild b/dev-python/httpx/httpx-0.27.2.ebuild
new file mode 100644
index 000000000000..4b768beb9877
--- /dev/null
+++ b/dev-python/httpx/httpx-0.27.2.ebuild
@@ -0,0 +1,95 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Fully-featured HTTP client which provides sync and async APIs"
+HOMEPAGE="
+	https://www.python-httpx.org/
+	https://github.com/encode/httpx/
+	https://pypi.org/project/httpx/
+"
+SRC_URI="
+	https://github.com/encode/httpx/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="cli"
+
+RDEPEND="
+	dev-python/anyio[${PYTHON_USEDEP}]
+	dev-python/certifi[${PYTHON_USEDEP}]
+	=dev-python/httpcore-1*[${PYTHON_USEDEP}]
+	dev-python/idna[${PYTHON_USEDEP}]
+	dev-python/sniffio[${PYTHON_USEDEP}]
+	cli? (
+		=dev-python/click-8*[${PYTHON_USEDEP}]
+		=dev-python/pygments-2*[${PYTHON_USEDEP}]
+		dev-python/rich[${PYTHON_USEDEP}]
+	)
+"
+BDEPEND="
+	dev-python/hatch-fancy-pypi-readme[${PYTHON_USEDEP}]
+	test? (
+		dev-python/brotlicffi[${PYTHON_USEDEP}]
+		dev-python/chardet[${PYTHON_USEDEP}]
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/h2[${PYTHON_USEDEP}]
+		dev-python/socksio[${PYTHON_USEDEP}]
+		dev-python/trustme[${PYTHON_USEDEP}]
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+		dev-python/uvicorn[${PYTHON_USEDEP}]
+		>=dev-python/zstandard-0.18.0[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/trio[${PYTHON_USEDEP}]
+		' 3.{10..13})
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	local PATCHES=(
+		"${FILESDIR}/${PN}-0.27.0-opt-trio.patch"
+	)
+
+	if ! use cli; then
+		sed -i -e '/^httpx =/d' pyproject.toml || die
+	fi
+	sed -i -e '/rich/s:,<14::' pyproject.toml || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local args=()
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/client/test_proxies.py::test_async_proxy_close
+		tests/client/test_proxies.py::test_sync_proxy_close
+	)
+
+	use cli || EPYTEST_IGNORE+=(
+		tests/test_main.py
+	)
+
+	if ! has_version "dev-python/trio[${PYTHON_USEDEP}]"; then
+		args+=( -o filterwarnings= -k "not trio" )
+	fi
+
+	epytest "${args[@]}"
+}
+
+pkg_postinst() {
+	optfeature "HTTP/2 support" dev-python/h2
+	optfeature "SOCKS proxy support" dev-python/socksio
+	optfeature "Decoding for brotli compressed responses" dev-python/brotlicffi
+}