Adding metadata

2 files changed, 108 insertions, 0 deletions

diff --git a/dev-python/httpx2/Manifest b/dev-python/httpx2/Manifest
index 6d832149447f..efa09e893ff7 100644
--- a/dev-python/httpx2/Manifest
+++ b/dev-python/httpx2/Manifest
@@ -1,2 +1,3 @@
 DIST httpx2-2.4.0.gh.tar.gz 2049043 BLAKE2B ec36c399853c4264bfb8247b770f6ddddecab3de150e75659455820fed1d41758326201684c1ec4adaa4a2e5451fceeba58b4ef0210aed7978e285b750ccf806 SHA512 f6033c1032faa078cb954fc9107a3c34ad46a6ab71ef426048f64147b94bd1737ab80447e5bcceec7c3147fd9ccfdf1b58dbaac5d3b9ab8b9bbb46f9e28617ab
 DIST httpx2-2.5.0.gh.tar.gz 2053138 BLAKE2B 8d436c215dcb47664c41f0b286bfd614e9eef08161a3c534a40bac5e59d5fe57ec51f87ead1498965d13ad41c4939b3a93b2a053ac2a73d0927593aa8cb61a2a SHA512 45cfadee3c884843e595eb8cffb0887fbee98c069d94c1e5c2498e7ac8c90b414c7d4fff2e8ed4a03589b56b605566674f2dd20e22738aa92812795b50c287f3
+DIST httpx2-2.7.0.gh.tar.gz 2084293 BLAKE2B 82a2ba5d9ea378ecd345e2f44e83a231e52c6a4551c854d2719387abc5a6b03da16fa8c99b731773ee73bbd7212eaa0843bab586edf0938751f0e545b7d170c5 SHA512 4badec86b0e5a4bf0c0974168e65ab24033598f414ea57af24d63c33d5c4700637de3a443cb552cf87f33c6aad3ed17fe498a7ed061d96bde0fe8c22073f3fb2
diff --git a/dev-python/httpx2/httpx2-2.7.0.ebuild b/dev-python/httpx2/httpx2-2.7.0.ebuild
new file mode 100644
index 000000000000..91015cb37a30
--- /dev/null
+++ b/dev-python/httpx2/httpx2-2.7.0.ebuild
@@ -0,0 +1,107 @@
+# Copyright 2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1
+
+# This package combines httpx2 and httpcore2 (because of exact version pin).
+DESCRIPTION="The next generation HTTP client (Pydantic fork)"
+HOMEPAGE="
+	https://pypi.org/project/httpx2/
+	https://pypi.org/project/httpcore2/
+	https://github.com/pydantic/httpx2/
+"
+SRC_URI="
+	https://github.com/pydantic/httpx2/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="cli"
+
+RDEPEND="
+	>=dev-python/anyio-4.10[${PYTHON_USEDEP}]
+	>=dev-python/idna-3.18[${PYTHON_USEDEP}]
+	>=dev-python/h11-0.16[${PYTHON_USEDEP}]
+	>=dev-python/truststore-0.10[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/typing-extensions-4.5.0[${PYTHON_USEDEP}]
+	' 3.12)
+	cli? (
+		>=dev-python/click-8.4[${PYTHON_USEDEP}]
+		=dev-python/pygments-2*[${PYTHON_USEDEP}]
+		>=dev-python/rich-10[${PYTHON_USEDEP}]
+	)
+"
+BDEPEND="
+	dev-python/hatch-fancy-pypi-readme[${PYTHON_USEDEP}]
+	dev-python/uv-dynamic-versioning[${PYTHON_USEDEP}]
+	test? (
+		dev-python/brotlicffi[${PYTHON_USEDEP}]
+		dev-python/chardet[${PYTHON_USEDEP}]
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/h2[${PYTHON_USEDEP}]
+		dev-python/starlette[${PYTHON_USEDEP}]
+		dev-python/socksio[${PYTHON_USEDEP}]
+		dev-python/trio[${PYTHON_USEDEP}]
+		dev-python/trustme[${PYTHON_USEDEP}]
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+		dev-python/uvicorn[${PYTHON_USEDEP}]
+		dev-python/websockets[${PYTHON_USEDEP}]
+		>=dev-python/wsproto-1.2[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			>=dev-python/zstandard-0.18.0[${PYTHON_USEDEP}]
+		' 3.12 3.13)
+	)
+"
+
+EPYTEST_PLUGINS=( anyio flaky pytest-{httpbin,trio} )
+EPYTEST_RERUNS=5
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_compile() {
+	local -x UV_DYNAMIC_VERSIONING_BYPASS=${PV}
+
+	cd src/httpcore2 || die
+	distutils-r1_python_compile
+	cd ../httpx2 || die
+	distutils-r1_python_compile
+	cd ../.. || die
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# random HTTP header case mismatch
+		tests/httpx2/test_main.py::test_auth
+		tests/httpx2/test_main.py::test_binary
+		tests/httpx2/test_main.py::test_follow_redirects
+		tests/httpx2/test_main.py::test_get
+		tests/httpx2/test_main.py::test_json
+		tests/httpx2/test_main.py::test_post
+		tests/httpx2/test_main.py::test_redirects
+		tests/httpx2/test_main.py::test_verbose
+		# Internet
+		tests/httpcore2/test_cancellations.py::test_h2_timeout_during_request
+		tests/httpx2/client/test_proxies.py::test_async_proxy_close
+		tests/httpx2/client/test_proxies.py::test_sync_proxy_close
+		# unexpected logs from uvicorn
+		tests/httpx2/test_utils.py::test_logging_request
+		tests/httpx2/test_utils.py::test_logging_redirect_chain
+	)
+
+	local EPYTEST_IGNORE=()
+	if ! use cli; then
+		EPYTEST_IGNORE+=(
+			tests/httpx2/test_main.py
+		)
+	fi
+
+	epytest tests/{httpcore2,httpx2}
+}