Adding metadata

3 files changed, 89 insertions, 0 deletions

diff --git a/dev-python/h5py/Manifest b/dev-python/h5py/Manifest
new file mode 100644
index 000000000000..b9c2f5b916e1
--- /dev/null
+++ b/dev-python/h5py/Manifest
@@ -0,0 +1,2 @@
+DIST h5py-3.16.0.tar.gz 446526 BLAKE2B 16d4329fb38509349f44e3fecf6256105a191d93038d14833c6343bb1be037e54da455f5f24515d30958d6da9ffe78f0a0567fac5ffc4b44ba9f23664028e0fc SHA512 e79be29ef14509d6d02fd71e1e0087e17a2756d0b56b647124406211be446862b395369637954cd1450ab6c068b33249ee57704b656e458a67bb7868d57f4129
+DIST h5py-3.16.0.tar.gz.provenance 9133 BLAKE2B 0847bba5f0ffa9c81f79254027e91a6458b4d18419ea17e1cabb745d1281fb07348a1baaee67955a929d450526df66fd74983ca81370384cc2afe9696ab9e27b SHA512 943489849c3789b9f6c878f17147839dd6987c8314c9cf21150ea2d1480d7413ec289d9ff0b999928b2406ecab95907f9cbb567edf5e02042cdb2003d7e59576
diff --git a/dev-python/h5py/h5py-3.16.0.ebuild b/dev-python/h5py/h5py-3.16.0.ebuild
new file mode 100644
index 000000000000..4b4f5c8b6da5
--- /dev/null
+++ b/dev-python/h5py/h5py-3.16.0.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=standalone
+PYPI_VERIFY_REPO=https://github.com/h5py/h5py
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Simple Python interface to HDF5 files"
+HOMEPAGE="
+	https://www.h5py.org/
+	https://github.com/h5py/h5py/
+	https://pypi.org/project/h5py/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 ~arm arm64 ~riscv x86 ~arm64-macos ~x64-macos"
+IUSE="examples"
+
+DEPEND="
+	>=dev-python/numpy-1.21.2:=[${PYTHON_USEDEP}]
+	>=sci-libs/hdf5-1.10.4:=[hl(+)]
+"
+RDEPEND="
+	${DEPEND}
+"
+
+BDEPEND="
+	>=dev-python/cython-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.14.5[${PYTHON_USEDEP}]
+	>=dev-python/packaging-23.0[${PYTHON_USEDEP}]
+	>=dev-python/pkgconfig-1.5.5[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-77.0.1[${PYTHON_USEDEP}]
+	test? (
+		dev-python/qtpy[testlib,${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	dev-python/sphinx-rtd-theme
+
+python_prepare_all() {
+	# avoid pytest-mpi dep, we do not use mpi anyway
+	sed -i -e 's:pytest-mpi::' pytest.ini || die
+	distutils-r1_python_prepare_all
+
+	export H5PY_SETUP_REQUIRES=0
+}
+
+python_test() {
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	epytest -m "not mpi"
+}
+
+python_install_all() {
+	use examples && dodoc -r examples
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/h5py/metadata.xml b/dev-python/h5py/metadata.xml
new file mode 100644
index 000000000000..fedec919024f
--- /dev/null
+++ b/dev-python/h5py/metadata.xml
@@ -0,0 +1,22 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>sci@gentoo.org</email>
+    <name>Gentoo Science Project</name>
+  </maintainer>
+  <longdescription lang="en">
+  HDF5 for Python (h5py) is a general-purpose simple Python interface to the
+  Hierarchical Data Format library, version 5. Existing Python and
+  Numpy concepts are used for the interface. Almost all HDF5 features
+  are available from Python, including things like compound datatypes
+  (as used with Numpy recarray types), HDF5 attributes, hyperslab and
+  point-based I/O, and more recent features in HDF 1.8 like resizable
+  datasets and recursive iteration over entire files.
+  </longdescription>
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>