Adding metadata

2 files changed, 74 insertions, 1 deletions

diff --git a/dev-python/h2/h2-3.2.0-r1.ebuild b/dev-python/h2/h2-3.2.0-r1.ebuild
new file mode 100644
index 000000000000..778f4d39bb91
--- /dev/null
+++ b/dev-python/h2/h2-3.2.0-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+MY_P=hyper-h2-${PV}
+DESCRIPTION="HTTP/2 State-Machine based protocol implementation"
+HOMEPAGE="
+	https://python-hyper.org/projects/h2/en/stable/
+	https://github.com/python-hyper/h2/
+	https://pypi.org/project/h2/
+"
+SRC_URI="https://github.com/python-hyper/${PN}/archive/v${PV}.tar.gz -> ${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/hyperframe-5.2.0[${PYTHON_USEDEP}]
+	<dev-python/hyperframe-6.0.0[${PYTHON_USEDEP}]
+	>=dev-python/hpack-3.0.0[${PYTHON_USEDEP}]
+	<dev-python/hpack-4.0.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+PATCHES=(
+	# From https://github.com/python-hyper/h2/pull/1248
+	# Disables some failing healthchecks
+	"${FILESDIR}/hyper-h2-3.2.0-failed-healthcheck.patch"
+)
+
+python_test() {
+	local EPYTEST_DESELECT=()
+	[[ ${EPYTHON} == python3.1[01] ]] && EPYTEST_DESELECT+=(
+		# these rely on fixed string repr() and fail because enum repr
+		# changed in py3.10
+		test/test_basic_logic.py::TestBasicServer::test_stream_repr
+		test/test_events.py::TestEventReprs::test_remotesettingschanged_repr
+		test/test_events.py::TestEventReprs::test_streamreset_repr
+		test/test_events.py::TestEventReprs::test_settingsacknowledged_repr
+		test/test_events.py::TestEventReprs::test_connectionterminated_repr
+	)
+
+	epytest --hypothesis-profile=travis
+}
diff --git a/dev-python/h2/h2-4.1.0-r1.ebuild b/dev-python/h2/h2-4.1.0-r1.ebuild
index b26b747fb8fe..4ecfccf4e5a3 100644
--- a/dev-python/h2/h2-4.1.0-r1.ebuild
+++ b/dev-python/h2/h2-4.1.0-r1.ebuild
@@ -12,7 +12,8 @@ DESCRIPTION="HTTP/2 State-Machine based protocol implementation"
 HOMEPAGE="
 	https://python-hyper.org/projects/h2/en/stable/
 	https://github.com/python-hyper/h2/
-	https://pypi.org/project/h2/"
+	https://pypi.org/project/h2/
+"
 SRC_URI="https://github.com/python-hyper/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
 
 LICENSE="MIT"
@@ -32,3 +33,17 @@ BDEPEND="
 "
 
 distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=()
+	if [[ ${EPYTHON} == python3.11 ]]; then
+		EPYTEST_DESELECT+=(
+			test/test_events.py::TestEventReprs::test_remotesettingschanged_repr
+			test/test_events.py::TestEventReprs::test_streamreset_repr
+			test/test_events.py::TestEventReprs::test_settingsacknowledged_repr
+			test/test_events.py::TestEventReprs::test_connectionterminated_repr
+		)
+	fi
+
+	epytest
+}