Adding metadata

1 files changed, 81 insertions, 0 deletions

diff --git a/dev-python/gitpython/gitpython-3.1.47.ebuild b/dev-python/gitpython/gitpython-3.1.47.ebuild
new file mode 100644
index 000000000000..4668ff2a57d0
--- /dev/null
+++ b/dev-python/gitpython/gitpython-3.1.47.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_PN=GitPython
+PYTHON_COMPAT=( python3_{10..14} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 pypi
+
+TEST_P=GitPython-${PV}
+GITDB_P=gitdb-4.0.12
+SMMAP_P=smmap-5.0.1
+
+DESCRIPTION="Library used to interact with Git repositories"
+HOMEPAGE="
+	https://github.com/gitpython-developers/GitPython/
+	https://pypi.org/project/GitPython/
+"
+SRC_URI+="
+	test? (
+		https://distfiles.gentoo.org/pub/proj/python/GitPython/${TEST_P}.gitbundle
+		https://distfiles.gentoo.org/pub/proj/python/GitPython/${GITDB_P}.gitbundle
+		https://distfiles.gentoo.org/pub/proj/python/GitPython/${SMMAP_P}.gitbundle
+	)
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-vcs/git
+	>=dev-python/gitdb-4.0.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/ddt-1.1.1[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-mock )
+distutils_enable_tests pytest
+
+src_test() {
+	git config --global user.email "travis@ci.com" || die
+	git config --global user.name "Travis Runner" || die
+
+	git clone "${DISTDIR}/${TEST_P}.gitbundle" "${T}"/test || die
+	git clone "${DISTDIR}/${GITDB_P}.gitbundle" \
+		"${T}"/test/git/ext/gitdb || die
+	git clone "${DISTDIR}/${SMMAP_P}.gitbundle" \
+		"${T}"/test/git/ext/gitdb/gitdb/ext/smmap || die
+
+	cd "${T}"/test || die
+	git rev-parse HEAD > .git/refs/remotes/origin/master || die
+	# this tries to fetch again
+	sed -i -e '/git submodule/d' init-tests-after-clone.sh || die
+	TRAVIS=1 ./init-tests-after-clone.sh || die
+	cat test/fixtures/.gitconfig >> ~/.gitconfig || die
+
+	distutils-r1_src_test
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# performance tests are unreliable by design
+		test/performance
+		# unimportant and problematic
+		test/test_installation.py
+		# Internet
+		test/test_quick_doc.py::QuickDoc::test_cloned_repo_object
+		# TODO
+		test/test_submodule.py::TestSubmodule::test_base_rw
+		test/test_submodule.py::TestSubmodule::test_root_module
+	)
+
+	epytest -o addopts= test
+}