Adding metadataHEADdevelop

1 files changed, 55 insertions, 0 deletions

diff --git a/dev-python/github3-py/github3-py-4.0.1.ebuild b/dev-python/github3-py/github3-py-4.0.1.ebuild
new file mode 100644
index 000000000000..3dff9efcc5ba
--- /dev/null
+++ b/dev-python/github3-py/github3-py-4.0.1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYPI_NO_NORMALIZE=1
+PYPI_PN=${PN/-/.}
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A wrapper for the GitHub API written in python"
+HOMEPAGE="
+	https://github.com/sigmavirus24/github3.py/
+	https://pypi.org/project/github3.py/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-vcs/git
+	>=dev-python/pyjwt-2.3.0[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.6.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.18[${PYTHON_USEDEP}]
+	>=dev-python/uritemplate-3.0.0[${PYTHON_USEDEP}]
+"
+# via PyJWT[crypto]
+RDEPEND+="
+	>=dev-python/cryptography-3.3.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/betamax-0.8.0[${PYTHON_USEDEP}]
+		>=dev-python/betamax-matchers-0.3.0[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# betamax / urllib3 problem
+		# upstream marked these tests xfail...
+		# https://github.com/sigmavirus24/github3.py/commit/9d6124c09b0997b5e83579549bcf22b3e901d7e5
+		tests/integration/test_repos_repo.py::TestRepoCommit::test_{diff,patch}
+		tests/integration/test_repos_repo.py::TestComparison::test_{diff,patch}
+	)
+
+	epytest -o addopts=
+}