Adding metadata

4 files changed, 0 insertions, 172 deletions

diff --git a/dev-python/ensurepip-setuptools/Manifest b/dev-python/ensurepip-setuptools/Manifest
deleted file mode 100644
index ad7da0f2da0e..000000000000
--- a/dev-python/ensurepip-setuptools/Manifest
+++ /dev/null
@@ -1,2 +0,0 @@
-DIST setuptools-79.0.1-py3-none-any.whl 1256281 BLAKE2B 8ae51bdd1c0ccada116757c2bd765225fcf4bedc7ada18567ae12f09b6978cdbcddd4f635a39a5568b6d3ed4388e4f73af5c33a7060f2ac0d0907fc82d8fd74f SHA512 fef6cfc6f95a5bb7320f1680e1c665cb8d9a4e4227cde4d8aab8a50bed4bcf04320085b9d7d5343359f887008db5c5a861e57f3d08b7b0b2311a28adaeee6b4a
-DIST setuptools-82.0.1.tar.gz 1152316 BLAKE2B d7f6eaf62ec66355b65642bc20a7a549e167dd6d1c0cdb15926b6644a23cab7737d713cd9418e0cc09161eb0bff53ffd0b8781c96d9203717077121c1e3cc0d5 SHA512 5d70e9efd818245fb8119a4eed64d776078469ed884facc188f141ea491efd9fde5c10c928d3236ea5e2e431b16616f18ed14870b867f95e6320251707332395
diff --git a/dev-python/ensurepip-setuptools/ensurepip-setuptools-79.0.1.ebuild b/dev-python/ensurepip-setuptools/ensurepip-setuptools-79.0.1.ebuild
deleted file mode 100644
index ffe5f412fbe9..000000000000
--- a/dev-python/ensurepip-setuptools/ensurepip-setuptools-79.0.1.ebuild
+++ /dev/null
@@ -1,20 +0,0 @@
-# Copyright 2022-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit pypi
-
-DESCRIPTION="Shared setuptools wheel for ensurepip Python module"
-HOMEPAGE="https://pypi.org/project/setuptools/"
-SRC_URI="$(pypi_wheel_url "${PN#ensurepip-}")"
-S=${DISTDIR}
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~arm64-macos ~x64-macos ~x64-solaris"
-
-src_install() {
-	insinto /usr/lib/python/ensurepip
-	doins "${A}"
-}
diff --git a/dev-python/ensurepip-setuptools/ensurepip-setuptools-82.0.1.ebuild b/dev-python/ensurepip-setuptools/ensurepip-setuptools-82.0.1.ebuild
deleted file mode 100644
index 224badad4d90..000000000000
--- a/dev-python/ensurepip-setuptools/ensurepip-setuptools-82.0.1.ebuild
+++ /dev/null
@@ -1,137 +0,0 @@
-# Copyright 1999-2026 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=standalone
-PYPI_PN=${PN#ensurepip-}
-# PYTHON_COMPAT used only for testing
-PYTHON_COMPAT=( python3_{13..14} )
-PYTHON_REQ_USE="xml(+)"
-
-inherit distutils-r1 pypi
-
-DESCRIPTION="Shared setuptools wheel for ensurepip Python module"
-HOMEPAGE="
-	https://github.com/pypa/setuptools/
-	https://pypi.org/project/setuptools/
-"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~arm64-macos ~x64-macos ~x64-solaris"
-IUSE="test"
-RESTRICT="!test? ( test )"
-
-BDEPEND="
-	${RDEPEND}
-	test? (
-		>=dev-python/build-1.0.3[${PYTHON_USEDEP}]
-		>=dev-python/ini2toml-0.14[${PYTHON_USEDEP}]
-		>=dev-python/filelock-3.4.0[${PYTHON_USEDEP}]
-		>=dev-python/jaraco-envs-2.2[${PYTHON_USEDEP}]
-		>=dev-python/jaraco-path-3.7.2[${PYTHON_USEDEP}]
-		>=dev-python/jaraco-test-5.5[${PYTHON_USEDEP}]
-		dev-python/pip[${PYTHON_USEDEP}]
-		dev-python/pyproject-hooks[${PYTHON_USEDEP}]
-		>=dev-python/tomli-w-1.0.0[${PYTHON_USEDEP}]
-		>=dev-python/virtualenv-20[${PYTHON_USEDEP}]
-	)
-"
-
-EPYTEST_PLUGINS=( pytest-{home,subprocess,timeout} )
-EPYTEST_XDIST=1
-distutils_enable_tests pytest
-
-declare -A VENDOR_LICENSES=(
-	[autocommand]=LGPL-3
-	[backports.tarfile]=MIT
-	[importlib_metadata]=Apache-2.0
-	[jaraco_context]=MIT
-	[jaraco_functools]=MIT
-	[jaraco.text]=MIT
-	[more_itertools]=MIT
-	[packaging]="|| ( Apache-2.0 MIT )"
-	[platformdirs]=MIT
-	[tomli]=MIT
-	[wheel]=MIT
-	[zipp]=MIT
-)
-LICENSE+=" ${VENDOR_LICENSES[*]}"
-
-src_prepare() {
-	distutils-r1_src_prepare
-
-	# Verify that we've covered licenses for all vendored packages
-	cd setuptools/_vendor || die
-	local packages=( *.dist-info )
-	local pkg missing=()
-	for pkg in "${packages[@]%%-*}"; do
-		if [[ ! -v "VENDOR_LICENSES[${pkg}]" ]]; then
-			missing+=( "${pkg}" )
-		else
-			unset "VENDOR_LICENSES[${pkg}]"
-		fi
-	done
-
-	if [[ ${missing[@]} || ${VENDOR_LICENSES[@]} ]]; then
-		[[ ${missing[@]} ]] &&
-			eerror "License missing for packages: ${missing[*]}"
-		[[ ${VENDOR_LICENSES[@]} ]] &&
-			eerror "Vendored packages removed: ${!VENDOR_LICENSES[*]}"
-		die "VENDOR_LICENSES outdated"
-	fi
-}
-
-python_compile() {
-	# If we're testing, install for all implementations.
-	# If we're not, just get one wheel built.
-	if use test || [[ -z ${DISTUTILS_WHEEL_PATH} ]]; then
-		distutils-r1_python_compile
-	fi
-}
-
-python_test() {
-	local EPYTEST_DESELECT=(
-		# TODO
-		setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_basic
-		setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_ignore_errors
-		# TODO, probably some random package
-		setuptools/tests/config/test_setupcfg.py::TestOptions::test_cmdclass
-		# relies on -Werror
-		setuptools/_static.py::setuptools._static.Dict
-		setuptools/_static.py::setuptools._static.List
-		# Internet
-		setuptools/tests/test_namespaces.py::TestNamespaces::test_mixed_site_and_non_site
-		setuptools/tests/test_namespaces.py::TestNamespaces::test_namespace_package_installed_and_cwd
-		setuptools/tests/test_namespaces.py::TestNamespaces::test_packages_in_the_same_namespace_installed_and_cwd
-		setuptools/tests/test_namespaces.py::TestNamespaces::test_pkg_resources_import
-		# broken by warnings from setuptools-scm
-		setuptools/tests/config/test_apply_pyprojecttoml.py::TestPresetField::test_scripts_dont_require_dynamic_entry_points
-		# TODO
-		setuptools/tests/test_config_discovery.py::TestDiscoverPackagesAndPyModules::test_py_modules_when_wheel_dir_is_cwd
-		'setuptools/tests/test_egg_info.py::TestEggInfo::test_requires[setup_requires_with_markers]'
-	)
-
-	case ${EPYTHON} in
-		pypy3.11)
-			EPYTEST_DESELECT+=(
-				# fails and breaks other tests
-				setuptools/tests/test_editable_install.py
-			)
-			;;
-	esac
-
-	local -x PRE_BUILT_SETUPTOOLS_WHEEL=${DISTUTILS_WHEEL_PATH}
-	epytest -o tmp_path_retention_policy=all \
-		-m "not uses_network" setuptools
-}
-
-src_install() {
-	if [[ ${DISTUTILS_WHEEL_PATH} != *py3-none-any.whl ]]; then
-		die "Non-pure wheel produced?! ${DISTUTILS_WHEEL_PATH}"
-	fi
-	# TODO: compress it?
-	insinto /usr/lib/python/ensurepip
-	doins "${DISTUTILS_WHEEL_PATH}"
-}
diff --git a/dev-python/ensurepip-setuptools/metadata.xml b/dev-python/ensurepip-setuptools/metadata.xml
deleted file mode 100644
index b5dfc54e62fe..000000000000
--- a/dev-python/ensurepip-setuptools/metadata.xml
+++ /dev/null
@@ -1,13 +0,0 @@
-<?xml version="1.0" encoding="UTF-8"?>
-<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
-<pkgmetadata>
-  <maintainer type="project">
-    <email>python@gentoo.org</email>
-    <name>Python</name>
-  </maintainer>
-  <stabilize-allarches />
-  <upstream>
-    <remote-id type="cpe">cpe:/a:python:setuptools</remote-id>
-  </upstream>
-  <origin>baldeagleos-repo</origin>
-</pkgmetadata>