Adding metadata

5 files changed, 93 insertions, 3 deletions

diff --git a/dev-python/elasticsearch/Manifest b/dev-python/elasticsearch/Manifest
index 4ea9081b8098..d5cce6ee01b9 100644
--- a/dev-python/elasticsearch/Manifest
+++ b/dev-python/elasticsearch/Manifest
@@ -1,2 +1,3 @@
 DIST elasticsearch-py-9.3.0.gh.tar.gz 2522110 BLAKE2B c0ff3ea253156aa8eeb264bca5f9a088a7c20fb93267b0c49e113b5865a3c5745203c4f7285a4f10da02e29db469cbac8d8e7de5b478a022e019d34080ec28bf SHA512 1398bea065f48dbf87b42801a2e19d91a27a5b13bbc158535657b49b40a4b914b9ddc610cc88cfab5b56d69106f530eb472e6a1222f26b7c792db844091bbad8
 DIST elasticsearch-py-9.4.0.gh.tar.gz 2554289 BLAKE2B b8e48559989b20cad7b4aadddf4f8d3b72d0c6e40b70c76ba82a1365bf6b15c7b0e729eade2709ea12efe350d88b73bd137551ef6bc5d6e5d633ed40065a5402 SHA512 48396b40f9eab9ceb41c2a4c4124bea0f4037ff8345a1c8a7d6d417154866b31a9e30c4822c360e1bb41a2f19b4c8ccdce38153861acf3c210578d629b3bcaf2
+DIST elasticsearch-py-9.4.1.gh.tar.gz 2556895 BLAKE2B 56563f06057450c071cd2c3a70d96d457d7b03ee5a6e421721cbd2b684a1667b5d4d41e079cfc54105da338f6985c5526a30599817fdb8da9b3e7d83dc8d2d89 SHA512 a8513c2340bb596b1f648509fccbc9855644e8bee3b9aa3f655a85e0ce1a037a07c47ce5e24fe07ed8bd33069806953535c46c52d0e0c05224ab2126c424cbed
diff --git a/dev-python/elasticsearch/elasticsearch-9.3.0.ebuild b/dev-python/elasticsearch/elasticsearch-9.3.0.ebuild
index 2d39d1dcbb10..1a8fe41912aa 100644
--- a/dev-python/elasticsearch/elasticsearch-9.3.0.ebuild
+++ b/dev-python/elasticsearch/elasticsearch-9.3.0.ebuild
@@ -4,7 +4,7 @@
 EAPI=8
 
 DISTUTILS_USE_PEP517=hatchling
-PYTHON_COMPAT=( python3_{10..14} )
+PYTHON_COMPAT=( python3_{12..14} )
 
 inherit distutils-r1
 
diff --git a/dev-python/elasticsearch/elasticsearch-9.4.0.ebuild b/dev-python/elasticsearch/elasticsearch-9.4.0.ebuild
index 1b2a2c50d933..cd56a0860ade 100644
--- a/dev-python/elasticsearch/elasticsearch-9.4.0.ebuild
+++ b/dev-python/elasticsearch/elasticsearch-9.4.0.ebuild
@@ -4,7 +4,7 @@
 EAPI=8
 
 DISTUTILS_USE_PEP517=hatchling
-PYTHON_COMPAT=( python3_{10..14} )
+PYTHON_COMPAT=( python3_{12..14} )
 
 inherit distutils-r1
 
diff --git a/dev-python/elasticsearch/elasticsearch-9.4.1.ebuild b/dev-python/elasticsearch/elasticsearch-9.4.1.ebuild
new file mode 100644
index 000000000000..68368ef701d4
--- /dev/null
+++ b/dev-python/elasticsearch/elasticsearch-9.4.1.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{12..14} )
+
+inherit distutils-r1
+
+MY_P="elasticsearch-py-${PV}"
+DESCRIPTION="Official Elasticsearch client library for Python"
+HOMEPAGE="
+	https://ela.st/es-python
+	https://github.com/elastic/elasticsearch-py/
+	https://pypi.org/project/elasticsearch/
+"
+SRC_URI="
+	https://github.com/elastic/elasticsearch-py/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0/$(ver_cut 1)"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	<dev-python/aiohttp-4[${PYTHON_USEDEP}]
+	>=dev-python/aiohttp-3[${PYTHON_USEDEP}]
+	dev-python/anyio[${PYTHON_USEDEP}]
+	<dev-python/elastic-transport-10[${PYTHON_USEDEP}]
+	>=dev-python/elastic-transport-9.4.1[${PYTHON_USEDEP}]
+	>=dev-python/orjson-3[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	<dev-python/requests-3[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.4[${PYTHON_USEDEP}]
+	dev-python/sniffio[${PYTHON_USEDEP}]
+	dev-python/typing-extensions[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		${RDEPEND}
+		dev-python/httpx[${PYTHON_USEDEP}]
+		dev-python/mapbox-vector-tile[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/opentelemetry-api[${PYTHON_USEDEP}]
+		dev-python/opentelemetry-sdk[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/pyarrow[${PYTHON_USEDEP}]
+		dev-python/pydantic[${PYTHON_USEDEP}]
+		dev-python/python-dateutil[${PYTHON_USEDEP}]
+		>=dev-python/pyyaml-5.4[${PYTHON_USEDEP}]
+		dev-python/trio[${PYTHON_USEDEP}]
+		dev-python/unasync[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/sphinx \
+	dev-python/sphinx-autodoc-typehints \
+	dev-python/sphinx-rtd-theme
+
+EPYTEST_PLUGINS=( anyio pytest-asyncio )
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# REST api tests are a black hole for effort. It downloads the tests
+		# so its an ever moving target. It also requires effort to blacklist
+		# tests for apis which are license restricted.
+		"test_elasticsearch/test_server/test_rest_api_spec.py"
+		# Counting deprecation warnings from python is bound to fail even
+		# if all are fixed in this package. Not worth it.
+		"test_elasticsearch/test_client/test_deprecated_options.py"
+		# Running daemon for tests is finicky and upstream CI fails at it
+		# as well.
+		"test_elasticsearch/test_server/"
+		"test_elasticsearch/test_async/test_server/"
+		"test_elasticsearch/test_dsl/test_integration/"
+		"test_elasticsearch/test_dsl/_async/test_esql.py"
+		"test_elasticsearch/test_dsl/_sync/test_esql.py"
+		# require nltk
+		"test_elasticsearch/test_dsl/test_integration/test_examples/_async/test_vectors.py"
+		"test_elasticsearch/test_dsl/test_integration/test_examples/_sync/test_vectors.py"
+	)
+
+	local -x TEST_WITH_OTEL=1
+	epytest -o addopts=
+}
diff --git a/dev-python/elasticsearch/metadata.xml b/dev-python/elasticsearch/metadata.xml
index 622096baab3e..80c9f6adf563 100644
--- a/dev-python/elasticsearch/metadata.xml
+++ b/dev-python/elasticsearch/metadata.xml
@@ -16,6 +16,6 @@
  <upstream>
   <doc>https://elasticsearch-py.readthedocs.io/</doc>
  </upstream>
- <origin>gentoo-staging</origin>
+ <origin>liguros-repo</origin>
  <stabilize-allarches/>
 </pkgmetadata>
\ No newline at end of file