Adding metadata

1 files changed, 38 insertions, 0 deletions

diff --git a/dev-python/construct/construct-2.10.61.ebuild b/dev-python/construct/construct-2.10.61.ebuild
new file mode 100644
index 000000000000..6412b720ac1f
--- /dev/null
+++ b/dev-python/construct/construct-2.10.61.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="A powerful declarative parser for binary data"
+HOMEPAGE="https://construct.readthedocs.io/en/latest/ https://pypi.org/project/construct/"
+SRC_URI="https://github.com/construct/construct/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+BDEPEND="
+	test? (
+		dev-python/arrow[${PYTHON_USEDEP}]
+		dev-python/cloudpickle[${PYTHON_USEDEP}]
+		dev-python/lz4[${PYTHON_USEDEP}]
+		>=dev-python/numpy-1.15.4[${PYTHON_USEDEP}]
+		dev-python/ruamel-yaml[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+	rm tests/test_benchmarks.py || die
+}
+
+pkg_postinst() {
+	ewarn "Version 2.10.x has significant API and implementation changes from"
+	ewarn "previous 2.9.x releases. Please read the documentation at"
+	ewarn "https://construct.readthedocs.io/en/latest/transition210.html"
+	ewarn "for more info."
+}