Updating liguros repov21.1.3

1 files changed, 46 insertions, 0 deletions

diff --git a/dev-python/blosc/blosc-1.10.2.ebuild b/dev-python/blosc/blosc-1.10.2.ebuild
new file mode 100644
index 000000000000..976d1dd18db6
--- /dev/null
+++ b/dev-python/blosc/blosc-1.10.2.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="High performance compressor optimized for binary data"
+HOMEPAGE="https://python-blosc.blosc.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+SLOT="0"
+LICENSE="MIT"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND=">=dev-libs/c-blosc-1.19.0:="
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-python/scikit-build[${PYTHON_USEDEP}]
+	test? (
+		dev-python/numpy[${PYTHON_USEDEP}]
+	)
+"
+
+DOCS=( ANNOUNCE.rst README.rst RELEASE_NOTES.rst )
+PATCHES=(
+	"${FILESDIR}"/blosc-1.10.0-unbundle.patch
+)
+
+python_prepare_all() {
+	export BLOSC_DIR="${EPREFIX}/usr"
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	"${EPYTHON}" -m blosc.test -v || die
+}
+
+python_install() {
+	distutils-r1_python_install
+	python_optimize
+}