Updating liguros repo

4 files changed, 96 insertions, 0 deletions

diff --git a/dev-python/blockdiag/Manifest b/dev-python/blockdiag/Manifest
new file mode 100644
index 000000000000..9835e8b7d3e5
--- /dev/null
+++ b/dev-python/blockdiag/Manifest
@@ -0,0 +1 @@
+DIST blockdiag-1.5.4.tar.gz 2693073 BLAKE2B 8a825742b4144667153af00d5e334325f8a3b49823355787dbd577729da8b0fc221ead14ab899ef8aef1800bbc2cdc47f060330bf0a2f2f1bcd055d172d8adbb SHA512 0eef8b3837282ed611e044ee618abca1f799b4a151bc2d7cece140c97ac728b2f3b9a3bb6877d3fed42a74e0173d0cbfd2966521c4dfb21c266975b4062405d2
diff --git a/dev-python/blockdiag/blockdiag-1.5.4.ebuild b/dev-python/blockdiag/blockdiag-1.5.4.ebuild
new file mode 100644
index 000000000000..7be9f5a83637
--- /dev/null
+++ b/dev-python/blockdiag/blockdiag-1.5.4.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit distutils-r1
+
+DESCRIPTION="Generate block-diagram image from text"
+HOMEPAGE="http://blockdiag.com/ https://pypi.org/project/blockdiag/ https://bitbucket.org/blockdiag/blockdiag/"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="amd64 ~arm ~arm64 x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/funcparserlib-0.3.6[${PYTHON_USEDEP}]
+	>=dev-python/pillow-2.2.1[${PYTHON_USEDEP}]
+	dev-python/webcolors[${PYTHON_USEDEP}]
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/reportlab[${PYTHON_USEDEP}]
+		dev-python/docutils[${PYTHON_USEDEP}]
+		media-fonts/ja-ipafonts
+	)
+"
+
+PATCHES=( "${FILESDIR}/blockdiag-1.5.3-py2_7-test-fix.patch")
+python_prepare_all() {
+	sed -i -e /build-base/d setup.cfg || die
+	# unnecessary dep
+	sed -i -e '/pep8/d' setup.py || die
+	# disable tests requiring Internet access
+	sed -i -e 's:test_app_cleans_up_images:_&:' \
+		src/blockdiag/tests/test_command.py || die
+	sed -i -e 's:ghostscript_not_found_test:_&:' \
+		src/blockdiag/tests/test_generate_diagram.py || die
+	rm src/blockdiag/tests/diagrams/node_icon.diag || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	esetup.py test
+}
+
+pkg_postinst() {
+	einfo "For additional functionality, install the following optional packages:"
+	einfo "    dev-python/reportlab for pdf format"
+	einfo "    media-gfx/imagemagick"
+	einfo "    wand: https://pypi.org/project/Wand"
+	einfo "          Ctypes-based simple MagickWand API binding for Python"
+}
diff --git a/dev-python/blockdiag/files/blockdiag-1.5.3-py2_7-test-fix.patch b/dev-python/blockdiag/files/blockdiag-1.5.3-py2_7-test-fix.patch
new file mode 100644
index 000000000000..e9ccfc82b9a0
--- /dev/null
+++ b/dev-python/blockdiag/files/blockdiag-1.5.3-py2_7-test-fix.patch
@@ -0,0 +1,12 @@
+diff -r 07f96892bfda src/blockdiag/tests/test_utils_fontmap.py
+--- a/src/blockdiag/tests/test_utils_fontmap.py	Sat Aug 22 13:38:35 2015 +0900
++++ b/src/blockdiag/tests/test_utils_fontmap.py	Mon Apr 10 05:56:48 2017 -0700
+@@ -223,7 +223,7 @@
+         _config = u("[fontmap]\nsansserif: %s\nsansserif: %s\n") % \
+                   (self.fontpath[0], self.fontpath[1])
+         config = StringIO(_config)
+-        if sys.version_info[0] == 2:
++        if sys.version_info < (2, 7):
+             fmap = FontMap(config)
+ 
+             font1 = fmap.find()
diff --git a/dev-python/blockdiag/metadata.xml b/dev-python/blockdiag/metadata.xml
new file mode 100644
index 000000000000..f0b8aa6b2080
--- /dev/null
+++ b/dev-python/blockdiag/metadata.xml
@@ -0,0 +1,22 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+		<name>Python</name>
+	</maintainer>
+	<upstream>
+		<maintainer>
+			<email>i.tkomiya@gmail.com</email>
+			<name>Takeshi Komiya</name>
+		</maintainer>
+		<remote-id type="pypi">blockdiag</remote-id>
+		<remote-id type="bitbucket">blockdiag/blockdiag</remote-id>
+	</upstream>
+	<longdescription>blockdiag generate block-diagram image file from spec-text
+	file.  Additional functionality is available with dev-python/reportlab
+	(pdf's), media-gfx/imagemagick and an imagemagic python bindings package
+	named wand (available from pypi).
+	</longdescription>
+	<origin>gentoo-staging</origin>
+</pkgmetadata>