Adding metadata

2 files changed, 78 insertions, 0 deletions

diff --git a/dev-python/automat/automat-20.2.0-r1.ebuild b/dev-python/automat/automat-20.2.0-r1.ebuild
new file mode 100644
index 000000000000..027f4e5612f8
--- /dev/null
+++ b/dev-python/automat/automat-20.2.0-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+MY_P=${P^}
+DESCRIPTION="Self-service finite-state machines for the programmer on the go"
+HOMEPAGE="https://github.com/glyph/automat https://pypi.org/project/Automat/"
+SRC_URI="mirror://pypi/${MY_P::1}/${PN^}/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="examples"
+
+RDEPEND="
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+"
+
+PATCHES=(
+	"${FILESDIR}/automat-0.8.0-no-setup-py-m2r-import.patch"
+	"${FILESDIR}/test_visualize-twisted-import-errors.patch"
+	"${FILESDIR}/${P}-py311.patch"
+)
+
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+	benchmark
+)
+
+python_install_all() {
+	if use examples; then
+		docinto examples
+		dodoc docs/examples/*.py
+	fi
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	einfo "For additional visualization functionality install both these optional dependencies"
+	einfo "    >=dev-python/twisted-16.1.1"
+	einfo "    media-gfx/graphviz[python]"
+}
diff --git a/dev-python/automat/files/automat-20.2.0-py311.patch b/dev-python/automat/files/automat-20.2.0-py311.patch
new file mode 100644
index 000000000000..14ca69e7235d
--- /dev/null
+++ b/dev-python/automat/files/automat-20.2.0-py311.patch
@@ -0,0 +1,23 @@
+https://github.com/glyph/automat/commit/d0c2845ead9b8f576042d42134bfb5c63086be39
+
+diff --git a/automat/_introspection.py b/automat/_introspection.py
+index 3f7307d..403cddb 100644
+--- a/automat/_introspection.py
++++ b/automat/_introspection.py
+@@ -6,6 +6,8 @@
+ 
+ 
+ def copycode(template, changes):
++    if hasattr(code, "replace"):
++        return template.replace(**{"co_" + k : v for k, v in changes.items()})
+     names = [
+         "argcount", "nlocals", "stacksize", "flags", "code", "consts",
+         "names", "varnames", "filename", "name", "firstlineno", "lnotab",
+@@ -23,7 +25,6 @@ def copycode(template, changes):
+     return code(*values)
+ 
+ 
+-
+ def copyfunction(template, funcchanges, codechanges):
+     names = [
+         "globals", "name", "defaults", "closure",