Updating liguros repo

6 files changed, 338 insertions, 0 deletions

diff --git a/dev-python/autobahn/Manifest b/dev-python/autobahn/Manifest
new file mode 100644
index 000000000000..a8a3e1c69b92
--- /dev/null
+++ b/dev-python/autobahn/Manifest
@@ -0,0 +1,3 @@
+DIST autobahn-17.5.1.tar.gz 205144 BLAKE2B a026381330d062059f23bd0fe20de12bf227fec45c816ce41a05d81951a2cb263e70ec3a5cee265ea3cc1f6910975903b493a767dce64c5bbb13be077561cabd SHA512 904f8f4c527a6c1c7840ea8634d0c0a47141458500c6d29f4aa1f05ff51f91c65a451b7c447201cbdf5e255c4c2d07509efa106790217b09398e7d50c1d85382
+DIST autobahn-18.3.1.tar.gz 213042 BLAKE2B 2f5eb92212f57d2301dbac1108a81cbbd339da4cb5527e3eb55f1ae7dcb951fed3cb7c643e76beaa0a83d623fe96f9eebcf7945e10efb0773e102d0234ebc479 SHA512 3d122cfb54eff0697cf60cd155a07699c6f6b39e573616c247ea79e65e6fa0a86d505ea8bc4f4755dbf266fb8bc7fadabb4338aeb1b9e6a2f0503e1b4d25e2e6
+DIST autobahn-20.4.3.tar.gz 938992 BLAKE2B 259d18f4aa46f7eaeac75811c1c193f3046aca5c5e37627d9ac62eeaa3dc944d05a8d87a558e241bdef56c799be4d89f65d4c8ee7c1a2be20f892896227eb5f9 SHA512 c34f29951b8f9ff5161851cf3a7e964de136f6091b0231a8e78e7fe74cb085077be5078cee352b2c27412d9aa4303de1eb85aa1890b4fb583575638a9c47c6fb
diff --git a/dev-python/autobahn/autobahn-17.5.1-r2.ebuild b/dev-python/autobahn/autobahn-17.5.1-r2.ebuild
new file mode 100644
index 000000000000..ff8c6a009590
--- /dev/null
+++ b/dev-python/autobahn/autobahn-17.5.1-r2.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+PYTHON_COMPAT=( python3_6 )
+
+inherit distutils-r1 versionator
+
+MY_P="${PN}-$(replace_version_separator 3 -)"
+
+DESCRIPTION="WebSocket and WAMP for Twisted and Asyncio"
+HOMEPAGE="https://pypi.org/project/autobahn/
+	https://crossbar.io/autobahn/
+	https://github.com/crossbario/autobahn-python"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_P}.tar.gz"
+
+SLOT="0"
+LICENSE="MIT"
+KEYWORDS="amd64 x86"
+IUSE="crypt test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/cbor-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/lz4-0.7.0[${PYTHON_USEDEP}]
+	crypt? (
+		>=dev-python/pyopenssl-16.2.0[${PYTHON_USEDEP}]
+		>=dev-python/pynacl-1.0.1[${PYTHON_USEDEP}]
+		>=dev-python/pytrie-0.2[${PYTHON_USEDEP}]
+		>=dev-python/pyqrcode-1.1.0[${PYTHON_USEDEP}]
+		>=dev-python/service_identity-16.0.0
+	)
+	>=dev-python/six-1.10.0[${PYTHON_USEDEP}]
+	>=dev-python/snappy-0.5[${PYTHON_USEDEP}]
+	>=dev-python/twisted-16.6.0-r2[${PYTHON_USEDEP}]
+	>=dev-python/txaio-2.6.1[${PYTHON_USEDEP}]
+	>=dev-python/u-msgpack-2.1[${PYTHON_USEDEP}]
+	>=dev-python/py-ubjson-0.8.4[${PYTHON_USEDEP}]
+	>=dev-python/wsaccel-0.6.2[${PYTHON_USEDEP}]
+	>=dev-python/zope-interface-3.6[${PYTHON_USEDEP}]
+	"
+DEPEND="${RDEPEND}
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		>=dev-python/pynacl-1.0.1[${PYTHON_USEDEP}]
+		>=dev-python/pytrie-0.2[${PYTHON_USEDEP}]
+		>=dev-python/pyqrcode-1.1.0[${PYTHON_USEDEP}]
+	)"
+
+S="${WORKDIR}"/${MY_P}
+
+python_test() {
+	#esetup.py test
+	cd "${BUILD_DIR}"/lib || die
+	py.test -v || die
+}
+
+pkg_postinst() {
+	python_foreach_impl twisted-regen-cache || die
+}
+
+pkg_postrm() {
+	python_foreach_impl twisted-regen-cache || die
+}
diff --git a/dev-python/autobahn/autobahn-18.3.1.ebuild b/dev-python/autobahn/autobahn-18.3.1.ebuild
new file mode 100644
index 000000000000..9be3fd5f6a50
--- /dev/null
+++ b/dev-python/autobahn/autobahn-18.3.1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+PYTHON_COMPAT=( python3_6 )
+
+inherit distutils-r1 versionator
+
+MY_P="${PN}-$(replace_version_separator 3 -)"
+
+DESCRIPTION="WebSocket and WAMP for Twisted and Asyncio"
+HOMEPAGE="https://pypi.org/project/autobahn/
+	https://crossbar.io/autobahn/
+	https://github.com/crossbario/autobahn-python"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_P}.tar.gz"
+
+SLOT="0"
+LICENSE="MIT"
+KEYWORDS="amd64 ~arm ~arm64 x86 ~amd64-linux ~x86-linux"
+IUSE="crypt test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/cbor-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/lz4-0.7.0[${PYTHON_USEDEP}]
+	>=dev-python/py-ubjson-0.8.4[${PYTHON_USEDEP}]
+	>=dev-python/six-1.10.0[${PYTHON_USEDEP}]
+	>=dev-python/snappy-0.5[${PYTHON_USEDEP}]
+	>=dev-python/twisted-16.6.0-r2[${PYTHON_USEDEP}]
+	>=dev-python/txaio-2.7.0[${PYTHON_USEDEP}]
+	>=dev-python/u-msgpack-2.1[${PYTHON_USEDEP}]
+	>=dev-python/wsaccel-0.6.2[${PYTHON_USEDEP}]
+	>=dev-python/zope-interface-3.6[${PYTHON_USEDEP}]
+	crypt? (
+		>=dev-python/pyopenssl-16.2.0[${PYTHON_USEDEP}]
+		>=dev-python/pynacl-1.0.1[${PYTHON_USEDEP}]
+		>=dev-python/pytrie-0.2[${PYTHON_USEDEP}]
+		>=dev-python/pyqrcode-1.1.0[${PYTHON_USEDEP}]
+		>=dev-python/service_identity-16.0.0
+	)
+	"
+DEPEND="${RDEPEND}
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		>=dev-python/pynacl-1.0.1[${PYTHON_USEDEP}]
+		>=dev-python/pytrie-0.2[${PYTHON_USEDEP}]
+		>=dev-python/pyqrcode-1.1.0[${PYTHON_USEDEP}]
+		dev-python/unittest2[${PYTHON_USEDEP}]
+	)"
+
+PATCHES=(
+	"${FILESDIR}/${P}-Fix-cs-test-955.patch"
+)
+
+S="${WORKDIR}"/${MY_P}
+
+python_test() {
+	echo "Testing all, cryptosign using twisted"
+	export USE_TWISTED=true
+	cd "${BUILD_DIR}"/lib || die
+	py.test -v || die
+	echo "RE-testing cryptosign using asyncio"
+	export USE_TWISTED=false
+	export USE_ASYNCIO=true
+	py.test -v autobahn/wamp/test/test_cryptosign.py || die
+	rm -r .pytest_cache || die
+}
+
+pkg_postinst() {
+	python_foreach_impl twisted-regen-cache || die
+}
+
+pkg_postrm() {
+	python_foreach_impl twisted-regen-cache || die
+}
diff --git a/dev-python/autobahn/autobahn-20.4.3.ebuild b/dev-python/autobahn/autobahn-20.4.3.ebuild
new file mode 100644
index 000000000000..e3bfba3353da
--- /dev/null
+++ b/dev-python/autobahn/autobahn-20.4.3.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit distutils-r1
+
+MY_P=${PN}-$(ver_rs 3 -)
+
+DESCRIPTION="WebSocket and WAMP for Twisted and Asyncio"
+HOMEPAGE="https://pypi.org/project/autobahn/
+	https://crossbar.io/autobahn/
+	https://github.com/crossbario/autobahn-python"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_P}.tar.gz"
+
+SLOT="0"
+LICENSE="MIT"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="crypt test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/cbor-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/cbor2-5.1.0[${PYTHON_USEDEP}]
+	>=dev-python/flatbuffers-1.10.0[${PYTHON_USEDEP}]
+	>=dev-python/lz4-0.7.0[${PYTHON_USEDEP}]
+	>=dev-python/msgpack-0.6.1[${PYTHON_USEDEP}]
+	>=dev-python/py-ubjson-0.8.4[${PYTHON_USEDEP}]
+	>=dev-python/snappy-0.5[${PYTHON_USEDEP}]
+	>=dev-python/twisted-20.3.0[${PYTHON_USEDEP}]
+	>=dev-python/txaio-20.3.1[${PYTHON_USEDEP}]
+	>=dev-python/ujson-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/wsaccel-0.6.2[${PYTHON_USEDEP}]
+	>=dev-python/zope-interface-3.6[${PYTHON_USEDEP}]
+	crypt? (
+		>=dev-python/pyopenssl-16.2.0[${PYTHON_USEDEP}]
+		>=dev-python/pynacl-1.0.1[${PYTHON_USEDEP}]
+		>=dev-python/pytrie-0.2[${PYTHON_USEDEP}]
+		>=dev-python/pyqrcode-1.1.0[${PYTHON_USEDEP}]
+		>=dev-python/service_identity-18.1.0
+	)
+	"
+DEPEND="${RDEPEND}
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		>=dev-python/pynacl-1.0.1[${PYTHON_USEDEP}]
+		>=dev-python/pytrie-0.2[${PYTHON_USEDEP}]
+		>=dev-python/pyqrcode-1.1.0[${PYTHON_USEDEP}]
+	)"
+
+S="${WORKDIR}"/${MY_P}
+
+python_test() {
+	echo "Testing all, cryptosign using twisted"
+	export USE_TWISTED=true
+	cd "${BUILD_DIR}"/lib || die
+	"${EPYTHON}" -m twisted.trial autobahn || die
+	unset USE_TWISTED
+	echo "RE-testing cryptosign and component_aio using asyncio"
+	export USE_ASYNCIO=true
+	py.test -v autobahn/wamp/test/test_cryptosign.py || die
+	py.test -v autobahn/wamp/test/test_component_aio.py || die
+	unset USE_ASYNCIO
+	rm -r .pytest_cache || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	# delete the dropin.cache so we don't have collisions if it exists
+	rm "${D}"/usr/lib*/python*/site-packages/twisted/plugins//dropin.cache > /dev/null
+}
+
+pkg_postinst() {
+	python_foreach_impl twisted-regen-cache || die
+}
+
+pkg_postrm() {
+	python_foreach_impl twisted-regen-cache || die
+}
diff --git a/dev-python/autobahn/files/autobahn-18.3.1-Fix-cs-test-955.patch b/dev-python/autobahn/files/autobahn-18.3.1-Fix-cs-test-955.patch
new file mode 100644
index 000000000000..a62f48569ce1
--- /dev/null
+++ b/dev-python/autobahn/files/autobahn-18.3.1-Fix-cs-test-955.patch
@@ -0,0 +1,95 @@
+From 604bc53a3beec173020c944ce9cb38afca2a9126 Mon Sep 17 00:00:00 2001
+From: Tobias Oberstein <tobias.oberstein@crossbario.com>
+Date: Fri, 9 Mar 2018 10:37:31 +0100
+Subject: [PATCH] Fix cs test (#955)
+
+* encode test string
+
+* already an instance
+
+* add extra deps (encryption)
+
+* add extra deps
+
+* deactivate py 3.3, tx < 15.4
+
+* systematic version coverage
+
+* fix coverage (hopefully)
+
+* another try
+
+* actually need to yield, as a future is returned
+---
+ .travis.yml                           | 58 ++++++++++++++++++++++++++++++++---
+ Makefile                              |  3 ++
+ autobahn/asyncio/rawsocket.py         |  2 +-
+ autobahn/wamp/test/test_cryptosign.py | 18 +++++++++--
+ tox.ini                               | 32 ++++++++++---------
+ 5 files changed, 89 insertions(+), 24 deletions(-)
+
+diff --git a/autobahn/asyncio/rawsocket.py b/autobahn/asyncio/rawsocket.py
+index 130a8e41..bbb83337 100644
+--- a/autobahn/asyncio/rawsocket.py
++++ b/autobahn/asyncio/rawsocket.py
+@@ -408,7 +408,7 @@ class WampRawSocketClientProtocol(WampRawSocketMixinGeneral, WampRawSocketMixinA
+     @property
+     def serializer_id(self):
+         if not hasattr(self, '_serializer'):
+-            self._serializer = self.factory._serializer()
++            self._serializer = self.factory._serializer
+         return self._serializer.RAWSOCKET_SERIALIZER_ID
+ 
+     def get_channel_id(self, channel_id_type=u'tls-unique'):
+diff --git a/autobahn/wamp/test/test_cryptosign.py b/autobahn/wamp/test/test_cryptosign.py
+index 700ca3cc..78f8d556 100644
+--- a/autobahn/wamp/test/test_cryptosign.py
++++ b/autobahn/wamp/test/test_cryptosign.py
+@@ -25,9 +25,21 @@
+ ###############################################################################
+ 
+ from __future__ import absolute_import
++
+ import hashlib
++import os
++
+ from mock import Mock
+ 
++import txaio
++
++if os.environ.get('USE_TWISTED', False):
++    txaio.use_twisted()
++elif os.environ.get('USE_ASYNCIO', False):
++    txaio.use_asyncio()
++else:
++    raise Exception('no networking framework selected')
++
+ from autobahn.wamp.cryptosign import _makepad, HAS_CRYPTOSIGN
+ from autobahn.wamp import types
+ from autobahn.wamp.auth import create_authenticator
+@@ -59,14 +71,14 @@ def setUp(self):
+         self.key = SigningKey.from_ssh_data(keybody)
+         self.privkey_hex = self.key._key.encode(encoder=HexEncoder)
+         m = hashlib.sha256()
+-        m.update("some TLS message")
++        m.update("some TLS message".encode())
+         self.channel_id = m.digest()
+ 
+     def test_valid(self):
+         session = Mock()
+         session._transport.get_channel_id = Mock(return_value=self.channel_id)
+         challenge = types.Challenge(u"ticket", dict(challenge="ff" * 32))
+-        signed = self.key.sign_challenge(session, challenge)
++        signed = yield self.key.sign_challenge(session, challenge)
+         self.assertEqual(
+             u'9b6f41540c9b95b4b7b281c3042fa9c54cef43c842d62ea3fd6030fcb66e70b3e80d49d44c29d1635da9348d02ec93f3ed1ef227dfb59a07b580095c2b82f80f9d16ca518aa0c2b707f2b2a609edeca73bca8dd59817a633f35574ac6fd80d00',
+             signed.result,
+@@ -81,7 +93,7 @@ def test_authenticator(self):
+         session = Mock()
+         session._transport.get_channel_id = Mock(return_value=self.channel_id)
+         challenge = types.Challenge(u"cryptosign", dict(challenge="ff" * 32))
+-        reply = authenticator.on_challenge(session, challenge)
++        reply = yield authenticator.on_challenge(session, challenge)
+         self.assertEqual(
+             reply.result,
+             u'9b6f41540c9b95b4b7b281c3042fa9c54cef43c842d62ea3fd6030fcb66e70b3e80d49d44c29d1635da9348d02ec93f3ed1ef227dfb59a07b580095c2b82f80f9d16ca518aa0c2b707f2b2a609edeca73bca8dd59817a633f35574ac6fd80d00',
diff --git a/dev-python/autobahn/metadata.xml b/dev-python/autobahn/metadata.xml
new file mode 100644
index 000000000000..c9f94f8f13df
--- /dev/null
+++ b/dev-python/autobahn/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+    <maintainer type="person">
+        <email>dolsen@gentoo.org</email>
+        <name>Brian Dolbec</name>
+    </maintainer>
+  <upstream>
+    <remote-id type="pypi">autobahn</remote-id>
+    <remote-id type="github">crossbar/autobahn</remote-id>
+  </upstream>
+	<origin>gentoo-staging</origin>
+</pkgmetadata>