Adding metadata

4 files changed, 116 insertions, 12 deletions

diff --git a/dev-python/authlib/Manifest b/dev-python/authlib/Manifest
index 67e09d6f8363..c150944a2e88 100644
--- a/dev-python/authlib/Manifest
+++ b/dev-python/authlib/Manifest
@@ -1 +1,2 @@
-DIST authlib-1.5.2.tar.gz 153000 BLAKE2B 37689414a73e9c8cc54dc0a5e71e208da4feb319a56a4ce2b9839f9332e845ea45f7ad1942051358bcc55402277d630b3cc149b0fea3ec186dc62cbc02bf572c SHA512 ac7a989f646e34d9b712d951a7024e5dbab9103b922152ce54840f60be208ffde8761a64bf4a49937edf9bddd974bbe04ee849848022248f5c5fd95667a555ed
+DIST authlib-1.5.2.gh.tar.gz 331162 BLAKE2B e4f25f621398ca85b2d1e526aaa24a6ed07512afe85023646764682fb49353b7ae4052405747161b041e5873404ec88396b589463fe27be1495ef4fea9150a49 SHA512 ac396e3ea13637aa612f5893687b9dc51988addf719c304007ec6966ac36f843e82090ebe109d454d8da8766eeb50661a0968ff7f596b00541aaf592df919892
+DIST authlib-1.6.0.gh.tar.gz 341039 BLAKE2B 26faa75dbbaf6ca7350dbcd04d01d38bbbc3ee9f096437bee03be4180ed4b82560707b1ee403abf52eea4f6b53f760e5ad9bd8357cc227ed41b571ad9ff815a6 SHA512 5ff057fe9699b192218bf0863635230137fe1cb86129ba545b468f2df4491b475e81b6c296efd9965cfdb2cfc782f46bd49f93b1b222b5ce1f0b49145ef9ef45
diff --git a/dev-python/authlib/authlib-1.5.2.ebuild b/dev-python/authlib/authlib-1.5.2.ebuild
index 72be9c60dfd4..fd72ae747150 100644
--- a/dev-python/authlib/authlib-1.5.2.ebuild
+++ b/dev-python/authlib/authlib-1.5.2.ebuild
@@ -1,17 +1,24 @@
-# Copyright 2025
+# Copyright 1999-2025 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
 
-PYTHON_COMPAT=( python3_{10,11,12,13} )
-
 DISTUTILS_USE_PEP517="setuptools"
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
 
-inherit distutils-r1 pypi
-
-DESCRIPTION="A Python library in building OAuth and OpenID Connect servers and clients."
+inherit distutils-r1
 
-HOMEPAGE="https://authlib.org/"
+DESCRIPTION="A Python library in building OAuth and OpenID Connect servers and clients"
+HOMEPAGE="
+	https://authlib.org/
+	https://github.com/authlib/authlib/
+	https://pypi.org/project/Authlib/
+"
+# pypi source distribution excludes the tests
+SRC_URI="
+	https://github.com/authlib/authlib/archive/refs/tags/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
 
 LICENSE="BSD"
 SLOT="0"
@@ -30,16 +37,18 @@ RDEPEND="
 	)
 	jose? (
 		>=dev-python/pycryptodome-3.10[${PYTHON_USEDEP}]
-		<dev-python/pycryptodome-4[${PYTHON_USEDEP}]
 	)
 "
 BDEPEND="
 	test? (
-		dev-python/pytest[${PYTHON_USEDEP}]
 		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
 		dev-python/anyio[${PYTHON_USEDEP}]
 		dev-python/cachelib[${PYTHON_USEDEP}]
+		dev-python/django[${PYTHON_USEDEP}]
+		dev-python/flask[${PYTHON_USEDEP}]
+		dev-python/flask-sqlalchemy[${PYTHON_USEDEP}]
 		dev-python/httpx[${PYTHON_USEDEP}]
+		>=dev-python/pycryptodome-3.10[${PYTHON_USEDEP}]
 		dev-python/requests[${PYTHON_USEDEP}]
 		dev-python/starlette[${PYTHON_USEDEP}]
 	)
@@ -47,6 +56,20 @@ BDEPEND="
 
 distutils_enable_tests pytest
 
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# convert from pycryptodomex to pycryptodome
+	sed -i -e 's:from Cryptodome:from Crypto:' \
+		authlib/jose/drafts/_jwe_enc_cryptodome.py || die
+}
+
 python_test() {
-	epytest
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x DJANGO_SETTINGS_MODULE=tests.clients.test_django.settings
+	epytest -p asyncio tests/{core,jose,clients,flask}
+
+	# TODO: django.core.exceptions.AppRegistryNotReady: Apps aren't loaded yet.
+	#local -x DJANGO_SETTINGS_MODULE=tests.django.settings
+	#epytest -p asyncio tests/django
 }
diff --git a/dev-python/authlib/authlib-1.6.0.ebuild b/dev-python/authlib/authlib-1.6.0.ebuild
new file mode 100644
index 000000000000..fd72ae747150
--- /dev/null
+++ b/dev-python/authlib/authlib-1.6.0.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517="setuptools"
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+
+inherit distutils-r1
+
+DESCRIPTION="A Python library in building OAuth and OpenID Connect servers and clients"
+HOMEPAGE="
+	https://authlib.org/
+	https://github.com/authlib/authlib/
+	https://pypi.org/project/Authlib/
+"
+# pypi source distribution excludes the tests
+SRC_URI="
+	https://github.com/authlib/authlib/archive/refs/tags/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="django flask jose test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	django? (
+		dev-python/django[${PYTHON_USEDEP}]
+	)
+	flask? (
+		dev-python/flask[${PYTHON_USEDEP}]
+		dev-python/flask-sqlalchemy[${PYTHON_USEDEP}]
+	)
+	jose? (
+		>=dev-python/pycryptodome-3.10[${PYTHON_USEDEP}]
+	)
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/anyio[${PYTHON_USEDEP}]
+		dev-python/cachelib[${PYTHON_USEDEP}]
+		dev-python/django[${PYTHON_USEDEP}]
+		dev-python/flask[${PYTHON_USEDEP}]
+		dev-python/flask-sqlalchemy[${PYTHON_USEDEP}]
+		dev-python/httpx[${PYTHON_USEDEP}]
+		>=dev-python/pycryptodome-3.10[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/starlette[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# convert from pycryptodomex to pycryptodome
+	sed -i -e 's:from Cryptodome:from Crypto:' \
+		authlib/jose/drafts/_jwe_enc_cryptodome.py || die
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x DJANGO_SETTINGS_MODULE=tests.clients.test_django.settings
+	epytest -p asyncio tests/{core,jose,clients,flask}
+
+	# TODO: django.core.exceptions.AppRegistryNotReady: Apps aren't loaded yet.
+	#local -x DJANGO_SETTINGS_MODULE=tests.django.settings
+	#epytest -p asyncio tests/django
+}
diff --git a/dev-python/authlib/metadata.xml b/dev-python/authlib/metadata.xml
index 02457eacdecd..68005c3d401d 100644
--- a/dev-python/authlib/metadata.xml
+++ b/dev-python/authlib/metadata.xml
@@ -9,6 +9,10 @@
   <email>proxy-maint@gentoo.org</email>
   <name>Proxy Maintainers</name>
  </maintainer>
+ <maintainer type="project">
+  <email>python@gentoo.org</email>
+  <name>Python</name>
+ </maintainer>
  <upstream>
   <bugs-to>https://github.com/authlib/authlib/issues</bugs-to>
   <doc>https://docs.authlib.org/</doc>
@@ -18,5 +22,6 @@
   <flag name="flask">Enable Flask framework support</flag>
   <flag name="jose">Enable JSON Object Signing and Encryption (JOSE) support via <pkg>dev-python/pycryptodome</pkg></flag>
  </use>
- <origin>gentoo-guru-overlay</origin>
+ <origin>gentoo-staging</origin>
+ <stabilize-allarches/>
 </pkgmetadata>
\ No newline at end of file