Adding metadata

4 files changed, 186 insertions, 0 deletions

diff --git a/dev-python/astroid/Manifest b/dev-python/astroid/Manifest
new file mode 100644
index 000000000000..529aaef4a178
--- /dev/null
+++ b/dev-python/astroid/Manifest
@@ -0,0 +1,3 @@
+DIST astroid-4.0.4.gh.tar.gz 476682 BLAKE2B 513e70a4cf4791a3493bf43a1544d9eaf7dcda1c6b6602edba7314455507aff70d5f137d798243671848a9a9c070d39b6aea6442f3f15506959a4f066418b855 SHA512 37b7dffa92e7ca2e4a2039d9f0c4ff1235daa5e64d6bcaeffd9ed9240c5b24fd6c2f2508c4b20844f3be7bd5daaf98d5ed72f87b65c2288c40ffe7cb0446ddf3
+DIST astroid-4.1.2.tar.gz 414896 BLAKE2B 1888ca1d5f035fa2c4288e52392baefdb601aed629e260f8cfee21106a4ca74fbfb5fbe03da94aaa6cd7739b0324cfdf0c605814dbc8a56523bc0cbc9ac87a63 SHA512 92569b277033085c0a622f5a702daeda99a96d293c74ceb47ffec070408868508893d892eb3131b119b2339f8e5e6fc0d4b694065b68f7fded4857f03fc0b35d
+DIST astroid-4.1.2.tar.gz.provenance 9395 BLAKE2B 0a178a7e3e1392b71c0a6ea9f910821581801f79c89345cf9aa62dfe1ea5c5f18b026f003ad88796b518054f859fc6b82c564a7a8af6f44fccf8a7c00f5e68e3 SHA512 59de972e0f8754be6d218d1d3f04942e9ffc8aaf277cdb1564f11024baea7085cad98610cb297d9076ce50ab28136e3577863456cb0b5215ed07c345853c3df9
diff --git a/dev-python/astroid/astroid-4.0.4.ebuild b/dev-python/astroid/astroid-4.0.4.ebuild
new file mode 100644
index 000000000000..b62d24b8fcc7
--- /dev/null
+++ b/dev-python/astroid/astroid-4.0.4.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1
+
+MY_P=${P/_/}
+DESCRIPTION="Abstract Syntax Tree for logilab packages"
+HOMEPAGE="
+	https://github.com/pylint-dev/astroid/
+	https://pypi.org/project/astroid/
+"
+SRC_URI="
+	https://github.com/pylint-dev/astroid/archive/v${PV/_/}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
+
+# dev-python/regex isn't available for pypy
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/attrs[${PYTHON_USEDEP}]
+		>=dev-python/numpy-1.17.0[${PYTHON_USEDEP}]
+		dev-python/python-dateutil[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/regex[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+python_test() {
+	local EPYTEST_IGNORE=()
+	local EPYTEST_DESELECT=(
+		# hangs randomly
+		tests/test_nodes.py::AsStringTest::test_recursion_error_trapped
+		# no clue why they're broken
+		tests/test_modutils.py::GetModulePartTest::test_known_values_get_builtin_module_part
+		# TODO
+		tests/test_builder.py::BuilderTest::test_data_build_error_filename
+		# numpy-2 (https://github.com/pylint-dev/astroid/issues/2442)
+		tests/brain/numpy/test_core_einsumfunc.py::test_numpy_function_calls_inferred_as_ndarray
+		tests/brain/numpy/test_core_fromnumeric.py::BrainNumpyCoreFromNumericTest::test_numpy_function_calls_inferred_as_ndarray
+		tests/brain/numpy/test_core_multiarray.py::BrainNumpyCoreMultiarrayTest::test_numpy_function_calls_inferred_as_ndarray
+		tests/brain/numpy/test_core_numerictypes.py::NumpyBrainCoreNumericTypesTest::test_datetime_astype_return
+		tests/brain/numpy/test_core_numerictypes.py::NumpyBrainCoreNumericTypesTest::test_generic_types_are_subscriptables
+		tests/brain/numpy/test_core_umath.py::NumpyBrainCoreUmathTest::test_numpy_core_umath_functions_return_type
+		tests/brain/numpy/test_core_umath.py::NumpyBrainCoreUmathTest::test_numpy_core_umath_functions_return_type_tuple
+		# old pythons only
+		tests/brain/test_dataclasses.py::test_pydantic_field
+		tests/test_regrtest.py::NonRegressionTests::test_numpy_distutils
+		# -Werror, sigh
+		tests/test_nodes.py::test_deprecated_nodes_import_from_toplevel
+	)
+
+	if ! has_version "dev-python/mypy[${PYTHON_USEDEP}]"; then
+		EPYTEST_IGNORE+=(
+			tests/test_raw_building.py
+		)
+	fi
+
+	epytest
+}
diff --git a/dev-python/astroid/astroid-4.1.2.ebuild b/dev-python/astroid/astroid-4.1.2.ebuild
new file mode 100644
index 000000000000..ad7d5e824ca6
--- /dev/null
+++ b/dev-python/astroid/astroid-4.1.2.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_VERIFY_REPO=https://github.com/pylint-dev/astroid
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Abstract Syntax Tree for logilab packages"
+HOMEPAGE="
+	https://github.com/pylint-dev/astroid/
+	https://pypi.org/project/astroid/
+"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
+
+# dev-python/regex isn't available for pypy
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/attrs[${PYTHON_USEDEP}]
+		>=dev-python/numpy-1.17.0[${PYTHON_USEDEP}]
+		dev-python/python-dateutil[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/regex[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+python_test() {
+	local EPYTEST_IGNORE=()
+	local EPYTEST_DESELECT=(
+		# hangs randomly
+		tests/test_nodes.py::AsStringTest::test_recursion_error_trapped
+		# no clue why they're broken
+		tests/test_modutils.py::GetModulePartTest::test_known_values_get_builtin_module_part
+		# TODO
+		tests/test_builder.py::BuilderTest::test_data_build_error_filename
+		# numpy-2 (https://github.com/pylint-dev/astroid/issues/2442)
+		tests/brain/numpy/test_core_einsumfunc.py::test_numpy_function_calls_inferred_as_ndarray
+		tests/brain/numpy/test_core_fromnumeric.py::BrainNumpyCoreFromNumericTest::test_numpy_function_calls_inferred_as_ndarray
+		tests/brain/numpy/test_core_multiarray.py::BrainNumpyCoreMultiarrayTest::test_numpy_function_calls_inferred_as_ndarray
+		tests/brain/numpy/test_core_numerictypes.py::NumpyBrainCoreNumericTypesTest::test_datetime_astype_return
+		tests/brain/numpy/test_core_numerictypes.py::NumpyBrainCoreNumericTypesTest::test_generic_types_are_subscriptables
+		tests/brain/numpy/test_core_umath.py::NumpyBrainCoreUmathTest::test_numpy_core_umath_functions_return_type
+		tests/brain/numpy/test_core_umath.py::NumpyBrainCoreUmathTest::test_numpy_core_umath_functions_return_type_tuple
+		# old pythons only
+		tests/brain/test_dataclasses.py::test_pydantic_field
+		tests/test_regrtest.py::NonRegressionTests::test_numpy_distutils
+		# -Werror, sigh
+		tests/test_nodes.py::test_deprecated_nodes_import_from_toplevel
+	)
+
+	if ! has_version "dev-python/mypy[${PYTHON_USEDEP}]"; then
+		EPYTEST_IGNORE+=(
+			tests/test_raw_building.py
+		)
+	fi
+
+	case ${EPYTHON} in
+		pypy3.11)
+			EPYTEST_DESELECT+=(
+				tests/brain/test_gi.py::GiBrainClassificationTest::test_gi_function_classification
+			)
+			;;
+	esac
+
+	if has_version ">=dev-python/setuptools-82[${PYTHON_USEDEP}]"; then
+		EPYTEST_DESELECT+=(
+			# tests a package using pkg_resources
+			tests/test_manager.py::AstroidManagerTest::test_identify_old_namespace_package_protocol
+		)
+	fi
+
+	epytest
+}
diff --git a/dev-python/astroid/metadata.xml b/dev-python/astroid/metadata.xml
new file mode 100644
index 000000000000..f682415459bb
--- /dev/null
+++ b/dev-python/astroid/metadata.xml
@@ -0,0 +1,21 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <longdescription lang="en">The aim of this module is to provide a common base representation of
+  python source code for projects such as pychecker, pyreverse,
+  pylint... Well, actually the development of this library is
+  essentially governed by pylint's needs.
+  It provides a compatible representation which comes from the _ast
+  module. It rebuilds the tree generated by the builtin _ast module by
+  recursively walking down the AST and building an extended ast (let's
+  call it astng ;). The new node classes have additional methods and
+  attributes for different usages. They include some support for static
+  inference and local name scopes. Furthermore, astng builds partial
+  trees by inspecting living objects.</longdescription>
+  <stabilize-allarches />
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>