Adding metadata

2 files changed, 0 insertions, 161 deletions

diff --git a/dev-python/aiohttp/Manifest b/dev-python/aiohttp/Manifest
index 5c1ef98e09a2..37ac564ef756 100644
--- a/dev-python/aiohttp/Manifest
+++ b/dev-python/aiohttp/Manifest
@@ -1,4 +1,3 @@
-DIST aiohttp-3.13.0.tar.gz 7832348 BLAKE2B 14f482a2f72197ebfc4b841b45d73833c0037443706b12fb7b945a0a54a54964019964d500013a1abfe74fbd49f439d936a2628c33401fddce48642f4ee8602f SHA512 9ed39fa35250e40efaee3ce9be0f3cd9a0fd6b4c5ec2a3c67c173e23153307fc958570d8530ea3919a5db3cd452102d0c81bb3fb127d51b224658e1264a5b73c
 DIST aiohttp-3.13.2.tar.gz 7837994 BLAKE2B 7caefa888fe7ffb3b0440b6b1e49a67f06d8895139636e873cf37aecdacc30401dd573e6e7ad62bedf5cff39316aebc2c3888a22337b9d7bf7d30374ee57197c SHA512 eb90bf5ea3e8b2e1dd600694247ee418bc932554d0517a7aa14641e9aa9abab90563fdeae5389e2fb8149b35b4f60449b5c8960c0d21e7ee738c52d0de782602
 DIST aiohttp-3.13.2.tar.gz.provenance 9242 BLAKE2B 37aef0018873d460c8d63d00c20e1bf9545de241638b7935762d787f71c02ae486ec6e6c1c453aaa3ca1ce7a17dc11d6f8cff57c06e2f05f8455db021b6aa782 SHA512 07e145a856084fd2b6f3f8fcc7e382ac75ceb06ac56fdc3f6d1de47e7bb9f21176e8f2023d83063b857f519bd6cf3e5b45bfe2004b726e0baa2376e36ec666a3
 DIST aiohttp-3.13.5.tar.gz 7858271 BLAKE2B 33b8f7f977a429fcd14401042f0be88c4cf6879e2f991783c28bf26d2eaefb4ebeab64edfa4bd34f239c50574b3d5c5adb64b651716c8b7dc1fa4a41ca211d99 SHA512 42aafde39a7e0d270a43733293be1450ca7d72be9658403218f4c338fba7f942bd362637676146cc77579a0946303a44b012b070a25027d3b87abfb6bc0f9fb9
diff --git a/dev-python/aiohttp/aiohttp-3.13.0.ebuild b/dev-python/aiohttp/aiohttp-3.13.0.ebuild
deleted file mode 100644
index fd7ac6fc4a73..000000000000
--- a/dev-python/aiohttp/aiohttp-3.13.0.ebuild
+++ /dev/null
@@ -1,160 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_EXT=1
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{10..14} )
-
-inherit distutils-r1 pypi
-
-DESCRIPTION="HTTP client/server for asyncio"
-HOMEPAGE="
-	https://github.com/aio-libs/aiohttp/
-	https://pypi.org/project/aiohttp/
-"
-
-LICENSE="Apache-2.0"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
-IUSE="+native-extensions test-rust"
-
-DEPEND="
-	native-extensions? (
-		$(python_gen_cond_dep '
-			net-libs/llhttp:=
-		' 'python3*')
-	)
-"
-RDEPEND="
-	${DEPEND}
-	>=dev-python/aiodns-3.3.0[${PYTHON_USEDEP}]
-	>=dev-python/aiohappyeyeballs-2.5.0[${PYTHON_USEDEP}]
-	>=dev-python/aiosignal-1.4.0[${PYTHON_USEDEP}]
-	>=dev-python/attrs-17.3.0[${PYTHON_USEDEP}]
-	dev-python/brotlicffi[${PYTHON_USEDEP}]
-	>=dev-python/frozenlist-1.1.1[${PYTHON_USEDEP}]
-	>=dev-python/multidict-4.5.0[${PYTHON_USEDEP}]
-	>=dev-python/propcache-0.2.0[${PYTHON_USEDEP}]
-	>=dev-python/yarl-1.17.0[${PYTHON_USEDEP}]
-"
-BDEPEND="
-	>=dev-python/multidict-4.5.0[${PYTHON_USEDEP}]
-	dev-python/pkgconfig[${PYTHON_USEDEP}]
-	native-extensions? (
-		>=dev-python/cython-3.1.1[${PYTHON_USEDEP}]
-		dev-python/pkgconfig[${PYTHON_USEDEP}]
-	)
-	test? (
-		dev-python/blockbuster[${PYTHON_USEDEP}]
-		dev-python/freezegun[${PYTHON_USEDEP}]
-		dev-python/isal[${PYTHON_USEDEP}]
-		dev-python/re-assert[${PYTHON_USEDEP}]
-		$(python_gen_cond_dep '
-			dev-python/time-machine[${PYTHON_USEDEP}]
-		' 'python3*')
-		dev-python/zlib-ng[${PYTHON_USEDEP}]
-		$(python_gen_cond_dep '
-			dev-python/zstandard[${PYTHON_USEDEP}]
-		' 3.11 3.12)
-		www-servers/gunicorn[${PYTHON_USEDEP}]
-		test-rust? (
-			dev-python/trustme[${PYTHON_USEDEP}]
-		)
-	)
-"
-
-DOCS=( CHANGES.rst CONTRIBUTORS.txt README.rst )
-
-EPYTEST_PLUGIN_LOAD_VIA_ENV=1
-EPYTEST_PLUGINS=( pytest-{mock,xdist} )
-EPYTEST_RERUNS=5
-: ${EPYTEST_TIMEOUT:=180}
-EPYTEST_XDIST=1
-distutils_enable_tests pytest
-
-src_prepare() {
-	distutils-r1_src_prepare
-
-	# increase the timeout a little
-	sed -e '/abs=/s/0.001/0.01/' -i tests/test_helpers.py || die
-	# xfail_strict fails on py3.10
-	sed -i -e '/--cov/d' -e '/pytest_cov/d' -e '/xfail_strict/d' setup.cfg || die
-	sed -i -e 's:-Werror::' Makefile || die
-	# remove vendored llhttp
-	rm -r vendor || die
-}
-
-python_configure() {
-	# check for .install-cython, so that we do this only once
-	if [[ ! -f .install-cython && ${EPYTHON} != pypy3 ]] &&
-		use native-extensions
-	then
-		# force rehashing first
-		emake requirements/.hash/cython.txt.hash
-		> .update-pip || die
-		> .install-cython || die
-		emake cythonize
-	fi
-}
-
-python_compile() {
-	local -x AIOHTTP_USE_SYSTEM_DEPS=1
-	# implicitly disabled for pypy3
-	if [[ ${EPYTHON} == pypy3* ]] || ! use native-extensions; then
-		local -x AIOHTTP_NO_EXTENSIONS=1
-	fi
-
-	distutils-r1_python_compile
-}
-
-python_test() {
-	local EPYTEST_IGNORE=(
-		# proxy is not packaged
-		tests/test_proxy_functional.py
-		# python_on_whales is not packaged
-		tests/autobahn/test_autobahn.py
-		# benchmarks
-		tests/test_benchmarks_client.py
-		tests/test_benchmarks_client_request.py
-		tests/test_benchmarks_client_ws.py
-		tests/test_benchmarks_cookiejar.py
-		tests/test_benchmarks_http_websocket.py
-		tests/test_benchmarks_http_writer.py
-		tests/test_benchmarks_web_fileresponse.py
-		tests/test_benchmarks_web_middleware.py
-		tests/test_benchmarks_web_response.py
-		tests/test_benchmarks_web_urldispatcher.py
-	)
-
-	local EPYTEST_DESELECT=(
-		# Internet
-		tests/test_client_session.py::test_client_session_timeout_zero
-		tests/test_connector.py::test_tcp_connector_ssl_shutdown_timeout_nonzero_passed
-		tests/test_connector.py::test_tcp_connector_ssl_shutdown_timeout_passed_to_create_connection
-		tests/test_connector.py::test_tcp_connector_ssl_shutdown_timeout_zero_not_passed
-		# broken by irrelevant deprecation warnings
-		tests/test_circular_imports.py::test_no_warnings
-	)
-
-	case ${EPYTHON} in
-		python3.14)
-			EPYTEST_DESELECT+=(
-				# TODO
-				tests/test_cookiejar.py::test_pickle_format
-				# different exception message
-				tests/test_client_functional.py::test_aiohttp_request_coroutine
-			)
-			;;
-	esac
-
-	# upstream unconditionally blocks building C extensions
-	# on PyPy3 but the test suite needs an explicit switch
-	if [[ ${EPYTHON} == pypy3* ]] || ! use native-extensions; then
-		local -x AIOHTTP_NO_EXTENSIONS=1
-	fi
-
-	rm -rf aiohttp || die
-	epytest -m "not internal and not dev_mode"
-}