Adding metadata

3 files changed, 3 insertions, 158 deletions

diff --git a/dev-python/aiohttp/Manifest b/dev-python/aiohttp/Manifest
index 18c5cf4656c8..ceb61d3afde5 100644
--- a/dev-python/aiohttp/Manifest
+++ b/dev-python/aiohttp/Manifest
@@ -1,5 +1,4 @@
 DIST aiohttp-3.11.14.tar.gz 7676994 BLAKE2B e8e048c01db9600df3bdc7bdc6e5066094b4575d08fef3ec7d0a78763a701cd3501dce435b80d3fbea28d2e7bf4110a5cc9e0ccec2bc3745835cadcb27528404 SHA512 38e51d3640b533d9bd639a59657bf7affbfc0b1a9dc40d77175d6528044e23b1e524589b9a10e0159eb8f9ba29e96b3e67529a9d11f1c53760a70800d813d13f
 DIST aiohttp-3.11.18.tar.gz 7678653 BLAKE2B 5886778fd0456ef40f1da5abd3d6a3864db03fad01d53755bb34afd77152da338480ba534c5dc1574bd5aa178943ec52814f1ceff736d668868803b19f6c102f SHA512 9b25ad5f9800cd84014c55f6a4f7ac217a788a43e301a83c18667b6f294388adf53c81360fd3219007b10b42ce165331dad1907582dc9d3081fd8585b5bcd042
-DIST aiohttp-3.12.10.tar.gz 7810445 BLAKE2B facab7e18040a9d2cdb8281426b54d2d7cbbc2ba0c7dc41c90d93ebf45566d5a305efe453ca6ce181c07a47b7f67b6f271922e8eb2926060228fc42ad62f3f24 SHA512 a58a52c992b3a1ae3e2d307b0113efe52a26a84b40196bc1ec9e2e167c38c5223371cd2a78a3077fb5e1d987e55b498e3af9dc6a64141ebfb9e338793fed3f4d
 DIST aiohttp-3.12.11.tar.gz 7814403 BLAKE2B c08c9ad1a8d194e3d50e92c3c42f50031c0e6592eaab19fc80a4a80ae3a1ce63218b4c54307fed137c83a759207909a5023320e3906aa717944cfdc046457a10 SHA512 9be3e04fad4b2d3b3a72fdfb4a0cfb1cfbe19d3e2beb4589166c6f6aad017e42d4164a0fa542a18935e86cbffdf8c7f20a261a99ba7bcead42ce0f8a1b783b4e
-DIST aiohttp-3.12.9.tar.gz 7810207 BLAKE2B 352fea5e4580781626e414118d24bc7817bb488d2dd83d0690e67f8308fa12c9d4dd4a9ab80e1222fa06b37047469a5c87c33b7b5aea84627ec7151151cd96f4 SHA512 afd7e25a3e762eecf96a7e335bfb42e5becc5df3eb4de73c0c40995508ec736a100375fdc70d51e04f2b4e0f154a20a10d5090f9c0b11aae662d3bf23f49b9a4
+DIST aiohttp-3.12.12.tar.gz 7818643 BLAKE2B 95086465a2645505d42f61ee8dfc68d094ea692946fe98550f3afa25bff5427315c9a66d3c6e906f15e4136c634ee9b812eb0467d2bc7a43610a6fac75ac48ab SHA512 a9d127dd7098fc4661c5d1c421161696f07d38163ba7df2e87fc142d6815589615ea76cbe966aa2f24bf0e8c3737c03149104e769cca5d2c2b55d86739aa90f8
diff --git a/dev-python/aiohttp/aiohttp-3.12.10.ebuild b/dev-python/aiohttp/aiohttp-3.12.12.ebuild
index ecd1fee92d09..562da68a921d 100644
--- a/dev-python/aiohttp/aiohttp-3.12.10.ebuild
+++ b/dev-python/aiohttp/aiohttp-3.12.12.ebuild
@@ -126,7 +126,9 @@ python_test() {
 	local EPYTEST_DESELECT=(
 		# Internet
 		tests/test_client_session.py::test_client_session_timeout_zero
+		tests/test_connector.py::test_tcp_connector_ssl_shutdown_timeout_nonzero_passed
 		tests/test_connector.py::test_tcp_connector_ssl_shutdown_timeout_passed_to_create_connection
+		tests/test_connector.py::test_tcp_connector_ssl_shutdown_timeout_zero_not_passed
 		# broken by irrelevant deprecation warnings
 		tests/test_circular_imports.py::test_no_warnings
 	)
diff --git a/dev-python/aiohttp/aiohttp-3.12.9.ebuild b/dev-python/aiohttp/aiohttp-3.12.9.ebuild
deleted file mode 100644
index e78bfc2e4845..000000000000
--- a/dev-python/aiohttp/aiohttp-3.12.9.ebuild
+++ /dev/null
@@ -1,156 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_EXT=1
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{9,10,11,12,13} pypy3 )
-
-inherit distutils-r1 pypi
-
-DESCRIPTION="HTTP client/server for asyncio"
-HOMEPAGE="
-	https://github.com/aio-libs/aiohttp/
-	https://pypi.org/project/aiohttp/
-"
-
-LICENSE="Apache-2.0"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~riscv ~x86"
-IUSE="+native-extensions test-rust"
-
-DEPEND="
-	native-extensions? (
-		$(python_gen_cond_dep '
-			net-libs/llhttp:=
-		' 'python3*')
-	)
-"
-RDEPEND="
-	${DEPEND}
-	>=dev-python/aiodns-3.3.0[${PYTHON_USEDEP}]
-	>=dev-python/aiohappyeyeballs-2.5.0[${PYTHON_USEDEP}]
-	>=dev-python/aiosignal-1.1.2[${PYTHON_USEDEP}]
-	>=dev-python/attrs-17.3.0[${PYTHON_USEDEP}]
-	dev-python/brotlicffi[${PYTHON_USEDEP}]
-	>=dev-python/frozenlist-1.1.1[${PYTHON_USEDEP}]
-	>=dev-python/multidict-4.5.0[${PYTHON_USEDEP}]
-	>=dev-python/propcache-0.2.0[${PYTHON_USEDEP}]
-	>=dev-python/yarl-1.17.0[${PYTHON_USEDEP}]
-"
-BDEPEND="
-	>=dev-python/multidict-4.5.0[${PYTHON_USEDEP}]
-	native-extensions? (
-		>=dev-python/cython-3.1.1[${PYTHON_USEDEP}]
-		dev-python/pkgconfig[${PYTHON_USEDEP}]
-	)
-	test? (
-		dev-python/blockbuster[${PYTHON_USEDEP}]
-		dev-python/freezegun[${PYTHON_USEDEP}]
-		dev-python/isal[${PYTHON_USEDEP}]
-		dev-python/pytest-mock[${PYTHON_USEDEP}]
-		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
-		dev-python/pytest-xdist[${PYTHON_USEDEP}]
-		dev-python/re-assert[${PYTHON_USEDEP}]
-		$(python_gen_cond_dep '
-			dev-python/time-machine[${PYTHON_USEDEP}]
-		' 'python3*')
-		dev-python/zlib-ng[${PYTHON_USEDEP}]
-		www-servers/gunicorn[${PYTHON_USEDEP}]
-		test-rust? (
-			dev-python/trustme[${PYTHON_USEDEP}]
-		)
-	)
-"
-
-DOCS=( CHANGES.rst CONTRIBUTORS.txt README.rst )
-
-EPYTEST_XDIST=1
-distutils_enable_tests pytest
-
-src_prepare() {
-	distutils-r1_src_prepare
-
-	# increase the timeout a little
-	sed -e '/abs=/s/0.001/0.01/' -i tests/test_helpers.py || die
-	# xfail_strict fails on py3.10
-	sed -i -e '/--cov/d' -e '/pytest_cov/d' -e '/xfail_strict/d' setup.cfg || die
-	sed -i -e 's:-Werror::' Makefile || die
-	# remove vendored llhttp
-	rm -r vendor || die
-}
-
-python_configure() {
-	# check for .install-cython, so that we do this only once
-	if [[ ! -f .install-cython && ${EPYTHON} != pypy3 ]] &&
-		use native-extensions
-	then
-		# force rehashing first
-		emake requirements/.hash/cython.txt.hash
-		> .update-pip || die
-		> .install-cython || die
-		emake cythonize
-	fi
-}
-
-python_compile() {
-	local -x AIOHTTP_USE_SYSTEM_DEPS=1
-	# implicitly disabled for pypy3
-	if [[ ${EPYTHON} == pypy3* ]] || ! use native-extensions; then
-		local -x AIOHTTP_NO_EXTENSIONS=1
-	fi
-
-	distutils-r1_python_compile
-}
-
-python_test() {
-	local EPYTEST_IGNORE=(
-		# proxy is not packaged
-		tests/test_proxy_functional.py
-		# python_on_whales is not packaged
-		tests/autobahn/test_autobahn.py
-		# benchmarks
-		tests/test_benchmarks_client.py
-		tests/test_benchmarks_client_request.py
-		tests/test_benchmarks_client_ws.py
-		tests/test_benchmarks_cookiejar.py
-		tests/test_benchmarks_http_websocket.py
-		tests/test_benchmarks_http_writer.py
-		tests/test_benchmarks_web_fileresponse.py
-		tests/test_benchmarks_web_middleware.py
-		tests/test_benchmarks_web_response.py
-		tests/test_benchmarks_web_urldispatcher.py
-	)
-
-	local EPYTEST_DESELECT=(
-		# Internet
-		tests/test_client_session.py::test_client_session_timeout_zero
-		tests/test_connector.py::test_tcp_connector_ssl_shutdown_timeout_passed_to_create_connection
-		# broken by irrelevant deprecation warnings
-		tests/test_circular_imports.py::test_no_warnings
-	)
-
-	case ${EPYTHON} in
-		python3.14)
-			EPYTEST_DESELECT+=(
-				# TODO
-				tests/test_cookiejar.py::test_pickle_format
-				# different exception message
-				tests/test_client_functional.py::test_aiohttp_request_coroutine
-			)
-			;;
-	esac
-
-	# upstream unconditionally blocks building C extensions
-	# on PyPy3 but the test suite needs an explicit switch
-	if [[ ${EPYTHON} == pypy3* ]] || ! use native-extensions; then
-		local -x AIOHTTP_NO_EXTENSIONS=1
-	fi
-
-	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
-	local -x PYTEST_PLUGINS=pytest_mock,xdist.plugin
-	rm -rf aiohttp || die
-	epytest -m "not internal and not dev_mode" \
-		-p rerunfailures --reruns=5
-}