Updating liguros repo

4 files changed, 218 insertions, 0 deletions

diff --git a/dev-python/PythonQt/Manifest b/dev-python/PythonQt/Manifest
new file mode 100644
index 000000000000..22e4ca799117
--- /dev/null
+++ b/dev-python/PythonQt/Manifest
@@ -0,0 +1 @@
+DIST PythonQt3.2.zip 4539058 BLAKE2B c50b8333b71b6cbce6f372a0292a0ccfe791dc7eae5c660d4e6d1f5f2b3355644e3fd8cce9a514f0500e935f96c46976d0046ddd716465adb35d225e3c4cfeca SHA512 1ee0f50f5035568b38e945108f5496ba64355c6357c1ea8dfc17ad90fa360540769f94e0b3e0e398176e8a21c8afe139607f0b5a2e82c63f1cbd40201a25e0f0
diff --git a/dev-python/PythonQt/PythonQt-3.2-r1.ebuild b/dev-python/PythonQt/PythonQt-3.2-r1.ebuild
new file mode 100644
index 000000000000..39deaa6db272
--- /dev/null
+++ b/dev-python/PythonQt/PythonQt-3.2-r1.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7} )
+MY_P=${PN}${PV}
+
+inherit qmake-utils python-single-r1 virtualx
+
+DESCRIPTION="A dynamic Python binding for the Qt framework"
+HOMEPAGE="https://mevislab.github.io/pythonqt"
+SRC_URI="mirror://sourceforge/pythonqt/pythonqt/${P}/${MY_P}.zip"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug doc examples +extensions test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="${PYTHON_DEPS}
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	extensions? (
+		dev-qt/designer:5
+		dev-qt/qtdeclarative:5[widgets]
+		dev-qt/qtmultimedia:5[widgets]
+		dev-qt/qtnetwork:5
+		dev-qt/qtopengl:5
+		dev-qt/qtprintsupport:5
+		dev-qt/qtsql:5
+		dev-qt/qtsvg:5
+		dev-qt/qtxml:5
+		dev-qt/qtxmlpatterns:5
+	)"
+DEPEND="${RDEPEND}
+	dev-qt/qtxml:5
+	test? ( dev-qt/qttest:5 )"
+BDEPEND="app-arch/unzip
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	default
+
+	if ! use examples ; then
+		sed -i '/SUBDIRS/s/examples//' PythonQt.pro || die "sed for examples"
+	fi
+	if ! use extensions ; then
+		sed -i '/SUBDIRS/s/extensions//' PythonQt.pro || die "sed for extensions"
+	fi
+	if ! use test ; then
+		sed -i '/SUBDIRS/s/tests//' PythonQt.pro || die "sed for test"
+	fi
+
+	# Remove webkit support
+	sed -i '/qtHaveModule(webkit):CONFIG += PythonQtWebKit/d' \
+		extensions/PythonQt_QtAll/PythonQt_QtAll.pro \
+		|| die "sed for webkit"
+
+	# Unset python version to use python-config
+	sed -i "/unix:PYTHON_VERSION=/s/2.7//" build/python.prf \
+		|| die "sed for python version"
+}
+
+src_configure() {
+	eqmake5 CONFIG+="$(usex debug debug release '' '')" PREFIX="${ED}"/usr
+}
+
+src_test() {
+	LD_PRELOAD="${S}"/lib/libPythonQt-Qt5-Python"$(usex debug _d '' '' '')".so.3 \
+		virtx ./lib/PythonQtTest"$(usex debug _d '' '' '')"
+}
+
+src_install() {
+	einstalldocs
+
+	# Includes
+	insinto /usr/include/PythonQt
+	doins -r src/*.h
+	insinto /usr/include/PythonQt/gui
+	doins -r src/gui/*.h
+
+	if use extensions ; then
+		insinto /usr/include/PythonQt/extensions/PythonQt_QtAll
+		doins -r extensions/PythonQt_QtAll/*.h
+	fi
+
+	# Libraries
+	dolib.so lib/libPythonQt*
+}
diff --git a/dev-python/PythonQt/PythonQt-9999.ebuild b/dev-python/PythonQt/PythonQt-9999.ebuild
new file mode 100644
index 000000000000..01939249e831
--- /dev/null
+++ b/dev-python/PythonQt/PythonQt-9999.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7} )
+EGIT_REPO_URI="https://github.com/MeVisLab/pythonqt.git"
+
+inherit git-r3 qmake-utils python-single-r1 virtualx
+
+DESCRIPTION="A dynamic Python binding for the Qt framework"
+HOMEPAGE="https://mevislab.github.io/pythonqt"
+SRC_URI=""
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS=""
+IUSE="debug doc examples +extensions test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="${PYTHON_DEPS}
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	extensions? (
+		dev-qt/designer:5
+		dev-qt/qtdeclarative:5[widgets]
+		dev-qt/qtmultimedia:5[widgets]
+		dev-qt/qtnetwork:5
+		dev-qt/qtopengl:5
+		dev-qt/qtprintsupport:5
+		dev-qt/qtsql:5
+		dev-qt/qtsvg:5
+		dev-qt/qtxml:5
+		dev-qt/qtxmlpatterns:5
+	)"
+DEPEND="${RDEPEND}
+	dev-qt/qtxml:5
+	test? ( dev-qt/qttest:5 )"
+BDEPEND="app-arch/unzip
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )"
+
+src_prepare() {
+	default
+
+	if ! use examples ; then
+		sed -i '/SUBDIRS/s/examples//' PythonQt.pro || die "sed for examples"
+	fi
+	if ! use extensions ; then
+		sed -i '/SUBDIRS/s/extensions//' PythonQt.pro || die "sed for extensions"
+	fi
+	if ! use test ; then
+		sed -i '/SUBDIRS/s/tests//' PythonQt.pro || die "sed for test"
+	fi
+
+	# Remove webkit support if not used
+	sed -i '/qtHaveModule(webkit):CONFIG += PythonQtWebKit/d' \
+		extensions/PythonQt_QtAll/PythonQt_QtAll.pro \
+		|| die "sed for webkit"
+
+	# Unset python version to use python-config
+	sed -i "/unix:PYTHON_VERSION=/s/2.7//" build/python.prf \
+		|| die "sed for python version"
+}
+
+src_configure() {
+	eqmake5 CONFIG+="$(usex debug debug release '' '')" PREFIX="${ED}"/usr
+}
+
+src_test() {
+	LD_PRELOAD="${S}"/lib/libPythonQt-Qt5-Python"$(usex debug _d '' '' '')".so.3 \
+		virtx ./lib/PythonQtTest"$(usex debug _d '' '' '')"
+}
+
+src_install() {
+	einstalldocs
+
+	# Includes
+	insinto /usr/include/PythonQt
+	doins -r src/*.h
+	insinto /usr/include/PythonQt/gui
+	doins -r src/gui/*.h
+
+	if use extensions ; then
+		insinto /usr/include/PythonQt/extensions/PythonQt_QtAll
+		doins -r extensions/PythonQt_QtAll/*.h
+	fi
+
+	# Libraries
+	dolib.so lib/libPythonQt*
+}
diff --git a/dev-python/PythonQt/metadata.xml b/dev-python/PythonQt/metadata.xml
new file mode 100644
index 000000000000..c20c410b15d3
--- /dev/null
+++ b/dev-python/PythonQt/metadata.xml
@@ -0,0 +1,27 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>spiderx@spiderx.dp.ua</email>
+		<name>Vladimir Pavljuchenkov</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
+	<longdescription lang="en">
+	PythonQt is a dynamic Python binding for the Qt framework.
+	It offers an easy way to embed the Python scripting language into
+	your C++ Qt applications. The focus of PythonQt is on embedding Python
+	into an existing C++ application, not on writing the whole application
+	completely in Python.
+	</longdescription>
+	<use>
+		<flag name="extensions">Install extensions</flag>
+	</use>
+	<upstream>
+		<remote-id type="github">MeVisLab/pythonqt</remote-id>
+		<remote-id type="sourceforge">pythonqt</remote-id>
+	</upstream>
+	<origin>gentoo-staging</origin>
+</pkgmetadata>