Adding metadata

1 files changed, 41 insertions, 0 deletions

diff --git a/dev-lua/lua-resty-string/lua-resty-string-0.16.ebuild b/dev-lua/lua-resty-string/lua-resty-string-0.16.ebuild
new file mode 100644
index 000000000000..419f037f009a
--- /dev/null
+++ b/dev-lua/lua-resty-string/lua-resty-string-0.16.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# Openresty only ever supports luajit.
+LUA_COMPAT=( lua5-{1,3,4} luajit )
+inherit lua-single
+
+DESCRIPTION="String utilities and common hash functions for the ngx-lua-module NGINX module"
+HOMEPAGE="https://github.com/openresty/lua-resty-string"
+SRC_URI="
+	https://github.com/openresty/lua-resty-string/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz
+"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+# Tests require replicating much of nginx-module_src_test() in each
+# dev-lua/lua-resty-* ebuild.
+RESTRICT="test"
+
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+BDEPEND="virtual/pkgconfig"
+DEPEND="
+	${LUA_DEPS}
+	dev-libs/openssl:=
+"
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.16-explicitly-load-libcrypto.patch"
+)
+
+src_configure() {
+	# The directory where to Lua files are to be installed, used by the build
+	# system.
+	export LUA_LIB_DIR="$(lua_get_lmod_dir)"
+	default
+}