Adding metadata

7 files changed, 144 insertions, 0 deletions

diff --git a/dev-libs/hidapi-hotplug/Manifest b/dev-libs/hidapi-hotplug/Manifest
new file mode 100644
index 000000000000..78585be3c9da
--- /dev/null
+++ b/dev-libs/hidapi-hotplug/Manifest
@@ -0,0 +1 @@
+DIST hidapi-hotplug-0.15.0.tar.gz 389797 BLAKE2B b484b857a3e6f54334df0084278bff05fab2ce0fc4c7696bd905bb09febc9e7cf6de22db516873179abd001115963e7c4404cf8439e0cb7ec6268757df99d30d SHA512 a256c9d7f71512f0327abf75754a8ff6125a30cecf64f9f652dc60abb8a67c0545278af912d64a7dc03080d65e59c28b590d30eae6caf2cd9b430bb5be149943
diff --git a/dev-libs/hidapi-hotplug/hidapi-hotplug-0.15.0.ebuild b/dev-libs/hidapi-hotplug/hidapi-hotplug-0.15.0.ebuild
new file mode 100644
index 000000000000..e9eeff36c2ea
--- /dev/null
+++ b/dev-libs/hidapi-hotplug/hidapi-hotplug-0.15.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake-multilib flag-o-matic
+
+DESCRIPTION="Fork of dev-libs/hidapi with hotplug support"
+HOMEPAGE="https://codeberg.org/OpenRGB/hidapi-hotplug"
+SRC_URI="https://codeberg.org/OpenRGB/hidapi-hotplug/archive/${P}.tar.gz"
+S="${WORKDIR}/${PN}"
+
+LICENSE="|| ( BSD GPL-3 HIDAPI )"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="doc"
+
+DEPEND="
+	virtual/libusb:1[${MULTILIB_USEDEP}]
+	virtual/libudev:0[${MULTILIB_USEDEP}]
+"
+RDEPEND="${DEPEND}"
+BDEPEND="doc? ( app-text/doxygen )"
+
+multilib_src_configure() {
+	append-lfs-flags
+
+	local mycmakeargs=(
+		# Doesn't do anything as of 0.14.0
+		-DHIDAPI_WITH_TESTS=OFF
+	)
+
+	cmake_src_configure
+}
+
+multilib_src_compile() {
+	cmake_src_compile
+
+	if use doc && multilib_is_native_abi; then
+		cd "${S}/doxygen" || die
+		doxygen Doxyfile || die
+	fi
+}
+
+multilib_src_install() {
+	cmake_src_install
+
+	if use doc && multilib_is_native_abi; then
+		local HTML_DOCS=( "${S}/doxygen/html/." )
+	fi
+	einstalldocs
+}
diff --git a/dev-libs/hidapi-hotplug/metadata.xml b/dev-libs/hidapi-hotplug/metadata.xml
new file mode 100644
index 000000000000..6e8108963732
--- /dev/null
+++ b/dev-libs/hidapi-hotplug/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>chutzpah@gentoo.org</email>
+    <name>Patrick McLean</name>
+  </maintainer>
+  <maintainer type="person" proxied="yes">
+    <email>alexey+gentoo@asokolov.org</email>
+    <name>Alexey Sokolov</name>
+  </maintainer>
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
diff --git a/dev-libs/hyprland-protocols/Manifest b/dev-libs/hyprland-protocols/Manifest
index a15c9ae1f9d8..b676ac841c29 100644
--- a/dev-libs/hyprland-protocols/Manifest
+++ b/dev-libs/hyprland-protocols/Manifest
@@ -1 +1,2 @@
 DIST hyprland-protocols-0.7.0.tar.gz 11543 BLAKE2B 5c6d21acdcb203002de503149ee3acb53e407dc35afc78890eb3d1371520981ed9255503574d93eaa9e2529d531ecfca8bf5a749490a280528ebdbbed49d474d SHA512 809016a2d25b6cd91befc34d89c4acc3c1fce5628cac490a149f3aa5b413b680cecb4c66e86e59e02c55c2a3cfee2be911cd26c55910527e02e6983245a481a5
+DIST hyprland-protocols-0.7.1.tar.gz 11621 BLAKE2B cd0e4423bf3b2531fc22e467ec9e26981849d58b4d15d09193dded6a193992cc2e5fb9ab80752afcdac57a2ac929671ed2b2943334396b2a63fada60a526afc2 SHA512 7d4eb5e9e21f38bb6d632a85ec1727154ff7f9c5171b0d62d0f11ea0905b8fc2e3ced2a4a4f602ecbeae18d2de9eb6f1c051a38263c24f878379cee699a2ef59
diff --git a/dev-libs/hyprland-protocols/hyprland-protocols-0.7.1.ebuild b/dev-libs/hyprland-protocols/hyprland-protocols-0.7.1.ebuild
new file mode 100644
index 000000000000..3f516e6226e6
--- /dev/null
+++ b/dev-libs/hyprland-protocols/hyprland-protocols-0.7.1.ebuild
@@ -0,0 +1,25 @@
+# Copyright 2023-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Wayland protocol extensions for Hyprland"
+HOMEPAGE="https://github.com/hyprwm/hyprland-protocols"
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/hyprwm/${PN^}.git"
+else
+	SRC_URI="https://github.com/hyprwm/${PN^}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="BSD"
+SLOT="0/$(ver_cut 1-2)"
+
+BDEPEND="
+	dev-util/wayland-scanner
+	virtual/pkgconfig
+"
diff --git a/dev-libs/kirigami-addons/Manifest b/dev-libs/kirigami-addons/Manifest
index b64d9255d657..d9ae965ce0d1 100644
--- a/dev-libs/kirigami-addons/Manifest
+++ b/dev-libs/kirigami-addons/Manifest
@@ -1,2 +1,3 @@
 DIST kirigami-addons-1.12.1.tar.xz 2815592 BLAKE2B 4635e756e7c463b0d7c091db2714a23cf0a005666abf05063be96a0221b4147ec3d701f1b1366014769821fea6f55f9e84ed4aa899b222adccd5b2870a10e267 SHA512 365021b896c8a6ad7bfc1e98ff554040bdc50c109e25b362e8e4dc9219b721cf68092d0cef5b64884c9cee6367d65377621cccd0a9fdd8a79a515c739b136c2d
 DIST kirigami-addons-1.13.1.tar.xz 3023492 BLAKE2B 026f56a978b079cb85c3273bcf547dbb84cb783d791a9dd8b88296abac824d94951ddf80e37f01706be0b5a1236456f512749dcda6eb0672db50c1754b3fb4bd SHA512 be7499358b5a30ca44e50b8579a7fbf69569c42cc4bfb28473f05444f534548d301997f4608b3c2ab68bef22e56cbf8b21c474949125d116ac945b7357ca51f8
+DIST kirigami-addons-1.14.0.tar.xz 3068160 BLAKE2B 58d538d2d52b0d027b94cec2e20eebff3d61713fcda60dbb6e95e654bfd2a08c6667cf9c7d536f8314b33cc2bfff321914184995b91ce4ec186b20695dea1aa0 SHA512 46067606afa0c3084f46a3e421b04f0dc51c3105289e24991bb7340d6055592c1de86983635be4fc6375bad5c975def8c378b74bfcd9451b22376ec0306a5740
diff --git a/dev-libs/kirigami-addons/kirigami-addons-1.14.0.ebuild b/dev-libs/kirigami-addons/kirigami-addons-1.14.0.ebuild
new file mode 100644
index 000000000000..f55fee8ab698
--- /dev/null
+++ b/dev-libs/kirigami-addons/kirigami-addons-1.14.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 2021-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# TODO: ECMGenerateQDoc
+ECM_TEST="true"
+KFMIN=6.27.0
+QTMIN=6.11.2
+inherit ecm kde.org
+
+if [[ ${KDE_BUILD_TYPE} = release ]]; then
+	SRC_URI="mirror://kde/stable/${PN}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+fi
+
+DESCRIPTION="Visual end user components for Kirigami-based applications"
+HOMEPAGE="https://invent.kde.org/libraries/kirigami-addons"
+
+LICENSE="|| ( GPL-2 GPL-3 LGPL-3 ) LGPL-2.1+"
+SLOT="6"
+IUSE=""
+
+# would profit from VIRTUALX_REQUIRED=test, but then still requires
+# org.qt-project.qt.mediaplayer service and fails, bug 911186
+RESTRICT="test"
+
+COMMON_DEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[gui]
+	>=dev-qt/qtdeclarative-${QTMIN}:6
+	>=kde-frameworks/kcolorscheme-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kcrash-${KFMIN}:6
+	>=kde-frameworks/kglobalaccel-${KFMIN}:6
+	>=kde-frameworks/kguiaddons-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kiconthemes-${KFMIN}:6
+	>=kde-frameworks/kirigami-${KFMIN}:6
+"
+RDEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtmultimedia-${QTMIN}:6[qml]
+	>=kde-frameworks/qqc2-desktop-style-${KFMIN}:6
+	kde-plasma/libplasma:6=
+"
+DEPEND="${COMMON_DEPEND}
+	test? (
+		>=dev-qt/qtmultimedia-${QTMIN}:6[qml]
+		x11-themes/sound-theme-freedesktop
+	)
+"