Adding metadata

23 files changed, 734 insertions, 61 deletions

diff --git a/dev-libs/ktextaddons/ktextaddons-2.0.1.ebuild b/dev-libs/ktextaddons/ktextaddons-2.0.1-r1.ebuild
index 994bddc4e5e9..17a1840586dd 100644
--- a/dev-libs/ktextaddons/ktextaddons-2.0.1.ebuild
+++ b/dev-libs/ktextaddons/ktextaddons-2.0.1-r1.ebuild
@@ -6,7 +6,7 @@ EAPI=8
 ECM_DESIGNERPLUGIN="true"
 ECM_QTHELP="false" # TODO: Port to ECMGenerateQDoc
 ECM_TEST="true"
-KFMIN=6.19.0
+KFMIN=6.20.0
 QTMIN=6.9.0
 inherit ecm kde.org
 
diff --git a/dev-libs/libbpf/libbpf-1.7.0-r1.ebuild b/dev-libs/libbpf/libbpf-1.7.0-r1.ebuild
index 6b00e9cd8945..d030567232e9 100644
--- a/dev-libs/libbpf/libbpf-1.7.0-r1.ebuild
+++ b/dev-libs/libbpf/libbpf-1.7.0-r1.ebuild
@@ -13,7 +13,7 @@ if [[ ${PV} =~ [9]{4,} ]]; then
 	EGIT_REPO_URI="https://github.com/libbpf/libbpf.git"
 else
 	SRC_URI="https://github.com/libbpf/libbpf/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+	KEYWORDS="~alpha amd64 ~arm arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
 fi
 S="${WORKDIR}/${P}/src"
 
diff --git a/dev-libs/libbson/Manifest b/dev-libs/libbson/Manifest
index 0ec6bc908e63..48160e63d85e 100644
--- a/dev-libs/libbson/Manifest
+++ b/dev-libs/libbson/Manifest
@@ -1,2 +1,2 @@
-DIST libbson-2.2.3.tar.gz 7901284 BLAKE2B 151d5bacb58297163ef2c2c8b5d6baf46f8cd2e9f956d899f96c0045cef93538ebe978fc5d8e462087cf5177c3681bec1d444ba5bb6fa1516f5c1747490a3345 SHA512 faa03472f646f724b10192540eaaac931f74d7c5b7f2a717b6d6f274a5ab4f2bf088b601d8d5947ae23688e225dd352f335c0234866ada080d3ad7b9190b2ac8
 DIST libbson-2.2.4.tar.gz 7901472 BLAKE2B 186a26f5e0ce8bd5c75b56ff3f111db850289927374593365c1931917ef1cb6fe35f6a918241ce6bccfd3c1a424e52460101369e5af45e9991cdf2ee59b4a5eb SHA512 5864963832dc89928de209da9b41b835b4e25e645d4b8934b132111e5d5c7950e4868de0633a4f03bc4b54318466f319c6591be5d840d329f0c527ef455f64ed
+DIST libbson-2.3.0.tar.gz 7976622 BLAKE2B 5feba0dd5e48a5b0f878dc44c9eed62aadc23e683bedcf3a5a99004eeffe7536b9295e2c52da1603f187cd2a3839b7227d0dfaf9532f5448bbc3cca6e007cb2e SHA512 68120e46868d04c194baacd73946aa20c239313eb8aa81afbcfed7482fc33e58e42df36ff14477969911da343cb74a73d554f595cca8b1af0db479ffcc6e53b6
diff --git a/dev-libs/libbson/libbson-2.2.3.ebuild b/dev-libs/libbson/libbson-2.3.0.ebuild
index 0a36a74dcd3b..0a36a74dcd3b 100644
--- a/dev-libs/libbson/libbson-2.2.3.ebuild
+++ b/dev-libs/libbson/libbson-2.3.0.ebuild
diff --git a/dev-libs/libburn/Manifest b/dev-libs/libburn/Manifest
index 6694916106ef..490520ad9253 100644
--- a/dev-libs/libburn/Manifest
+++ b/dev-libs/libburn/Manifest
@@ -1 +1,2 @@
 DIST libburn-1.5.6.tar.gz 995353 BLAKE2B 2c4b2e0a191c2a02327177bc5acd418d14a0c6eb9de065de171b0c4240a8bd7746ab2fd775fa1f0433bc1fe98dd47620524ec2954f4aa0f2015557cf881a5d3f SHA512 549cb25310aac5ce445639374d84f0c09fb1fdd70be97479588775e5afcc12dd0655c5bf51bd3f1bf8c06a66b318fd1e709dcfd72845e795ffaf353ea621accd
+DIST libburn-1.5.8.tar.gz 1005307 BLAKE2B 8ad02b6e6b24463ce77d725d82a02219bb2610997ed992469014dc7771968bbc518b3d17ab7684f87b3ff3e2761babe1124764bcb6d40e732628c216f41cf78d SHA512 fa290de9c9e5270eea7752418caaf6d8ac9b9291e71ea043637f78493d91bf1daa3ec23f3c4e7b584d0134b123f3ca279c02cbb44ad3027e7e7d439966512280
diff --git a/dev-libs/libburn/libburn-1.5.8.ebuild b/dev-libs/libburn/libburn-1.5.8.ebuild
new file mode 100644
index 000000000000..d54b4a2a22cb
--- /dev/null
+++ b/dev-libs/libburn/libburn-1.5.8.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=9
+
+inherit autotools
+
+DESCRIPTION="Open-source library for reading, mastering and writing optical discs"
+HOMEPAGE="https://dev.lovelyhq.com/libburnia/web/wiki/Libburn https://dev.lovelyhq.com/libburnia/libburn"
+SRC_URI="https://files.libburnia-project.org/releases/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="cdio debug static-libs"
+
+BDEPEND="
+	virtual/pkgconfig
+"
+RDEPEND="
+	cdio? ( dev-libs/libcdio )
+"
+DEPEND="
+	${RDEPEND}
+"
+
+src_prepare() {
+	default
+
+	# Ancient libtool version in 1.5.6 at least (debian's 2.4.2-1.11)
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable static-libs static) \
+		$(use_enable cdio libcdio) \
+		--disable-ldconfig-at-install \
+		$(use_enable debug)
+}
+
+src_install() {
+	default
+
+	dodoc CONTRIBUTORS doc/{comments,*.txt}
+
+	docinto cdrskin
+	dodoc cdrskin/{*.txt,README}
+	docinto cdrskin/html
+	dodoc cdrskin/cdrskin_eng.html
+
+	find "${D}" -name '*.la' -delete || die
+}
diff --git a/dev-libs/libburn/metadata.xml b/dev-libs/libburn/metadata.xml
index 63f9b7e9b848..cb6d7b33cdfa 100644
--- a/dev-libs/libburn/metadata.xml
+++ b/dev-libs/libburn/metadata.xml
@@ -11,5 +11,8 @@
   <description>Upstream - please CC on bugs that concern upstream</description>
  </maintainer>
  
+ <use>
+  <flag name="cdio">Use <pkg>dev-libs/libcdio</pkg> for the transport of SCSI commands</flag>
+ </use>
  <origin>gentoo-staging</origin>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-libs/libisoburn/Manifest b/dev-libs/libisoburn/Manifest
index 34cd3f89bcf2..52834b900564 100644
--- a/dev-libs/libisoburn/Manifest
+++ b/dev-libs/libisoburn/Manifest
@@ -1 +1,2 @@
 DIST libisoburn-1.5.6.tar.gz 1650966 BLAKE2B 56246feb390532588861944944de50fc6e70afa284da78a33e6a1c3a37fdf02cd8362dce2fc59c8f0017cc475eb15db47841759f376342d411d0518e9ba49c9b SHA512 0fc0058aa4cf755f30d5be0de808012978c657348412c7f129b8f8128da41f18216f3e039050a5851b557ffab344cf7dc44df374400ca008e34e2e2524fbd979
+DIST libisoburn-1.5.8.tar.gz 1762206 BLAKE2B d1e266359cc9532d9fc6b30065b00a7e3edfcec0435c767ef88783908d6428bdd2782ac75f1ec03bd4cfcb013665cfff707d886f645b6efd6356f67dd7aa989d SHA512 64a3423b4c60b4cf88914c832aa80db8cdc76c7ff783125148f13c59dba3dc78d66d9cd9eda77864faf2b58eefdc55d5a2a4ff3f97acf6bc5c9778bb0c5653e2
diff --git a/dev-libs/libisoburn/libisoburn-1.5.8.ebuild b/dev-libs/libisoburn/libisoburn-1.5.8.ebuild
new file mode 100644
index 000000000000..3f912163c906
--- /dev/null
+++ b/dev-libs/libisoburn/libisoburn-1.5.8.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=9
+
+inherit autotools
+
+DESCRIPTION="Creation/expansion of ISO-9660 filesystems on CD/DVD media supported by libburn"
+HOMEPAGE="https://dev.lovelyhq.com/libburnia/web/wiki/Libisoburn https://dev.lovelyhq.com/libburnia/libisoburn"
+SRC_URI="https://files.libburnia-project.org/releases/${P}.tar.gz"
+
+LICENSE="GPL-2 GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="acl cdio debug external-filters external-filters-setuid frontend-optional
+	launch-frontend launch-frontend-setuid libedit readline static-libs xattr zlib"
+
+REQUIRED_USE="frontend-optional? ( || ( launch-frontend launch-frontend-setuid ) )"
+
+BDEPEND="
+	virtual/pkgconfig
+"
+RDEPEND="
+	>=dev-libs/libburn-1.5.8
+	>=dev-libs/libisofs-1.5.8
+	readline? ( sys-libs/readline:0= )
+	!readline? (
+		libedit? ( dev-libs/libedit )
+	)
+	acl? (
+		virtual/acl
+		>=dev-libs/libisofs-1.5.8[acl]
+	)
+	xattr? (
+		sys-apps/attr
+		>=dev-libs/libisofs-1.5.8[xattr]
+	)
+	zlib? (
+		virtual/zlib:=
+		>=dev-libs/libisofs-1.5.8[zlib]
+	)
+	cdio? (
+		dev-libs/libcdio
+		>=dev-libs/libburn-1.5.8[cdio]
+	)
+	launch-frontend? (
+		dev-lang/tcl:0
+		dev-lang/tk:0
+	)
+	launch-frontend-setuid? (
+		dev-lang/tcl:0
+		dev-lang/tk:0
+	)
+	frontend-optional? ( dev-tcltk/bwidget )
+"
+DEPEND="
+	${RDEPEND}
+"
+
+src_prepare() {
+	default
+
+	# Ancient libtool version in 1.5.6 at least (debian's 2.4.2-1.11)
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable static-libs static) \
+		$(use_enable readline libreadline) \
+		$(usex readline --disable-libedit $(use_enable libedit)) \
+		$(use_enable acl libacl) \
+		$(use_enable xattr) \
+		$(use_enable zlib) \
+		--disable-libjte \
+		$(use_enable cdio libcdio) \
+		$(use_enable external-filters) \
+		$(use_enable external-filters-setuid) \
+		$(use_enable launch-frontend) \
+		$(use_enable launch-frontend-setuid) \
+		--disable-ldconfig-at-install \
+		--enable-pkg-check-modules \
+		$(use_enable debug)
+}
+
+src_install() {
+	default
+
+	dodoc CONTRIBUTORS doc/{comments,*.wiki,startup_file.txt}
+
+	docinto frontend
+	dodoc frontend/README-tcltk
+	docinto xorriso
+	dodoc xorriso/{changelog.txt,README_gnu_xorriso}
+
+	find "${D}" -name '*.la' -delete || die
+}
diff --git a/dev-libs/libisoburn/metadata.xml b/dev-libs/libisoburn/metadata.xml
index acf8180acae4..65277f571e2f 100644
--- a/dev-libs/libisoburn/metadata.xml
+++ b/dev-libs/libisoburn/metadata.xml
@@ -12,6 +12,7 @@
  </maintainer>
  
  <use>
+  <flag name="cdio">Use <pkg>dev-libs/libcdio</pkg> for the transport of SCSI commands</flag>
   <flag name="external-filters">Allow the use of external processes as file content 
 filters (Note: this is a potential security risk)</flag>
   <flag name="external-filters-setuid">Also allow the use of external setuid 
diff --git a/dev-libs/libisofs/Manifest b/dev-libs/libisofs/Manifest
index 0057a3ef40a4..2e4781462fdf 100644
--- a/dev-libs/libisofs/Manifest
+++ b/dev-libs/libisofs/Manifest
@@ -1 +1,2 @@
 DIST libisofs-1.5.6.pl01.tar.gz 879218 BLAKE2B 466cb1fed6b0a29b2a418dfe7a3ac393d38961b08cf53febfe80f1bf91f891d1c17119a482fb0cb6f44eda0c568b1c00bd7b2eeb028ad749c99451ffb18b7f8b SHA512 7760931abbe508002bd3e7eeb694071425f24316cb11c80a2f162a76c3a1d79c57593b758bc0e540107140fd18714e1bf87ae3a65510956a76a1c09f80453a80
+DIST libisofs-1.5.8.pl01.tar.gz 904992 BLAKE2B 3029e2a025dbbb75159414e671d2b86189b88f46f871e5b81544b91048c4687348c0479dce7b6b05ae79fa73185426aef87d1cd6e7cf88adf943f4edc5a03caf SHA512 6dc5acf83db11c7f5ce574224bc8c58914fc749dd7582e6f69c4199225ad786ab23155f3c753b28b145cd51c6bca4dc4db285cb9b8e99f583966a6baa9284f37
diff --git a/dev-libs/libisofs/libisofs-1.5.8_p1.ebuild b/dev-libs/libisofs/libisofs-1.5.8_p1.ebuild
new file mode 100644
index 000000000000..b1940102f25a
--- /dev/null
+++ b/dev-libs/libisofs/libisofs-1.5.8_p1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=9
+MY_PF=${P/_p1/}
+MY_P=${MY_PF}.pl01
+
+inherit autotools
+
+DESCRIPTION="Open-source library for reading, mastering and writing optical discs"
+HOMEPAGE="https://dev.lovelyhq.com/libburnia/web/wiki/Libisofs https://dev.lovelyhq.com/libburnia/libisofs"
+SRC_URI="https://files.libburnia-project.org/releases/${MY_P}.tar.gz"
+
+S="${WORKDIR}/${MY_PF}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="acl debug static-libs verbose-debug xattr zlib"
+
+BDEPEND="
+	virtual/pkgconfig
+"
+RDEPEND="
+	acl? ( virtual/acl )
+	xattr? ( sys-apps/attr )
+	zlib? ( virtual/zlib:= )
+"
+DEPEND="
+	${RDEPEND}
+"
+
+src_prepare() {
+	default
+
+	# Ancient libtool version in 1.5.6 at least (debian's 2.4.2-1.11)
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable static-libs static) \
+		$(use_enable debug) \
+		$(use_enable verbose-debug) \
+		$(use_enable acl libacl) \
+		$(use_enable xattr) \
+		$(use_enable zlib) \
+		--disable-libjte \
+		--disable-ldconfig-at-install
+}
+
+src_install() {
+	default
+
+	dodoc Roadmap doc/{*.txt,Tutorial}
+
+	find "${D}" -name '*.la' -delete || die
+}
diff --git a/dev-libs/marisa/marisa-0.3.1.ebuild b/dev-libs/marisa/marisa-0.3.1-r1.ebuild
index 6a3a225f493a..15f04ac817f5 100644
--- a/dev-libs/marisa/marisa-0.3.1.ebuild
+++ b/dev-libs/marisa/marisa-0.3.1-r1.ebuild
@@ -37,7 +37,8 @@ PATCHES=(
 src_prepare() {
 	cmake_src_prepare
 
-	sed -e "s:^\([[:space:]]*\)libraries=:\1include_dirs=[\"../../include\"],\n\1library_dirs=[\"../../lib/marisa\"],\n&:" \
+	local cmake_build_dir="${WORKDIR}/${P}_build"
+	sed -e "s:^\([[:space:]]*\)libraries=:\1include_dirs=[\"${S}/include\"],\n\1library_dirs=[\"${cmake_build_dir}/lib/marisa\"],\n&:" \
 		-e "s:setup(name = \"marisa\":setup(name = \"marisa\", version = \"${PV}\":" \
 		-i bindings/python/setup.py || die
 
diff --git a/dev-libs/marisa/marisa-9999.ebuild b/dev-libs/marisa/marisa-9999.ebuild
index 2143ba96fa6e..6124375d63aa 100644
--- a/dev-libs/marisa/marisa-9999.ebuild
+++ b/dev-libs/marisa/marisa-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 2014-2024 Gentoo Authors
+# Copyright 2014-2026 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI="8"
@@ -7,23 +7,15 @@ DISTUTILS_USE_PEP517="setuptools"
 DISTUTILS_OPTIONAL="1"
 DISTUTILS_EXT=1
 
-inherit autotools distutils-r1 toolchain-funcs
-
-if [[ "${PV}" == "9999" ]]; then
-	inherit git-r3
-
-	EGIT_REPO_URI="https://github.com/s-yata/marisa-trie"
-fi
+inherit cmake distutils-r1 git-r3
 
 DESCRIPTION="Matching Algorithm with Recursively Implemented StorAge"
 HOMEPAGE="https://github.com/s-yata/marisa-trie"
-if [[ "${PV}" != "9999" ]]; then
-	SRC_URI="https://github.com/s-yata/marisa-trie/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-fi
+EGIT_REPO_URI="https://github.com/s-yata/marisa-trie"
 
 LICENSE="|| ( BSD-2 LGPL-2.1+ )"
 SLOT="0"
-IUSE="python static-libs"
+IUSE="python tools"
 REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
 
 BDEPEND="python? (
@@ -34,15 +26,17 @@ BDEPEND="python? (
 DEPEND="python? ( ${PYTHON_DEPS} )"
 RDEPEND="${DEPEND}"
 
-if [[ "${PV}" != "9999" ]]; then
-	S="${WORKDIR}/marisa-trie-${PV}"
-fi
+PATCHES=(
+	"${FILESDIR}/marisa-0.3.1-install-all-configs.patch"
+)
 
 src_prepare() {
-	default
-	eautoreconf
+	cmake_src_prepare
 
-	sed -e "s:^\([[:space:]]*\)libraries=:\1include_dirs=[\"../../include\"],\n\1library_dirs=[\"../../lib/marisa/.libs\"],\n&:" -i bindings/python/setup.py || die
+	local cmake_build_dir="${WORKDIR}/${P}_build"
+	sed -e "s:^\([[:space:]]*\)libraries=:\1include_dirs=[\"${S}/include\"],\n\1library_dirs=[\"${cmake_build_dir}/lib/marisa\"],\n&:" \
+		-e "s:setup(name = \"marisa\":setup(name = \"marisa\", version = \"${PV}\":" \
+		-i bindings/python/setup.py || die
 
 	if use python; then
 		pushd bindings/python > /dev/null || die
@@ -52,36 +46,12 @@ src_prepare() {
 }
 
 src_configure() {
-	local -x CPPFLAGS="${CPPFLAGS} ${CXXFLAGS}"
-
-	cpu_instructions_option() {
-		local option="${1}"
-		local macros="${2}"
-		local result="--enable-${option}"
-		local macro
-		for macro in ${macros}; do
-			if ! $(tc-getCC) ${CPPFLAGS} ${CFLAGS} -E -P -dM - < /dev/null 2> /dev/null | grep -Eq "^#define ${macro}([[:space:]]|$)"; then
-				result="--disable-${option}"
-			fi
-		done
-		echo "${result}"
-	}
-
-	local options=(
-		$(cpu_instructions_option sse2 __SSE2__)
-		$(cpu_instructions_option sse3 __SSE3__)
-		$(cpu_instructions_option ssse3 __SSSE3__)
-		$(cpu_instructions_option sse4.1 __SSE4_1__)
-		$(cpu_instructions_option sse4.2 __SSE4_2__)
-		$(cpu_instructions_option sse4 __POPCNT__ __SSE4_2__)
-		$(cpu_instructions_option sse4a __SSE4A__)
-		$(cpu_instructions_option popcnt __POPCNT__)
-		$(cpu_instructions_option bmi __BMI__)
-		$(cpu_instructions_option bmi2 __BMI2__)
-		$(use_enable static-libs static)
+	local mycmakeargs=(
+		-DLIB_INSTALL_DIR="$(get_libdir)"
+		-DENABLE_TOOLS=$(usex tools)
+		-DBUILD_TESTING=OFF
 	)
-
-	econf "${options[@]}"
+	cmake_src_configure
 
 	if use python; then
 		pushd bindings/python > /dev/null || die
@@ -91,7 +61,7 @@ src_configure() {
 }
 
 src_compile() {
-	default
+	cmake_src_compile
 
 	if use python; then
 		emake -C bindings swig-python
@@ -102,8 +72,7 @@ src_compile() {
 }
 
 src_install() {
-	default
-	find "${ED}" -name "*.la" -delete || die
+	cmake_src_install
 
 	(
 		docinto html
diff --git a/dev-libs/mongo-c-driver/Manifest b/dev-libs/mongo-c-driver/Manifest
index 07db2d908243..b351c3b2645b 100644
--- a/dev-libs/mongo-c-driver/Manifest
+++ b/dev-libs/mongo-c-driver/Manifest
@@ -1,2 +1,2 @@
-DIST mongo-c-driver-2.2.3.tar.gz 7901284 BLAKE2B 151d5bacb58297163ef2c2c8b5d6baf46f8cd2e9f956d899f96c0045cef93538ebe978fc5d8e462087cf5177c3681bec1d444ba5bb6fa1516f5c1747490a3345 SHA512 faa03472f646f724b10192540eaaac931f74d7c5b7f2a717b6d6f274a5ab4f2bf088b601d8d5947ae23688e225dd352f335c0234866ada080d3ad7b9190b2ac8
 DIST mongo-c-driver-2.2.4.tar.gz 7901472 BLAKE2B 186a26f5e0ce8bd5c75b56ff3f111db850289927374593365c1931917ef1cb6fe35f6a918241ce6bccfd3c1a424e52460101369e5af45e9991cdf2ee59b4a5eb SHA512 5864963832dc89928de209da9b41b835b4e25e645d4b8934b132111e5d5c7950e4868de0633a4f03bc4b54318466f319c6591be5d840d329f0c527ef455f64ed
+DIST mongo-c-driver-2.3.0.tar.gz 7976622 BLAKE2B 5feba0dd5e48a5b0f878dc44c9eed62aadc23e683bedcf3a5a99004eeffe7536b9295e2c52da1603f187cd2a3839b7227d0dfaf9532f5448bbc3cca6e007cb2e SHA512 68120e46868d04c194baacd73946aa20c239313eb8aa81afbcfed7482fc33e58e42df36ff14477969911da343cb74a73d554f595cca8b1af0db479ffcc6e53b6
diff --git a/dev-libs/mongo-c-driver/mongo-c-driver-2.2.3.ebuild b/dev-libs/mongo-c-driver/mongo-c-driver-2.3.0.ebuild
index 46aba989321b..46aba989321b 100644
--- a/dev-libs/mongo-c-driver/mongo-c-driver-2.2.3.ebuild
+++ b/dev-libs/mongo-c-driver/mongo-c-driver-2.3.0.ebuild
diff --git a/dev-libs/nss/Manifest b/dev-libs/nss/Manifest
index 197ac606490f..ceae1a2dcec7 100644
--- a/dev-libs/nss/Manifest
+++ b/dev-libs/nss/Manifest
@@ -3,3 +3,4 @@ DIST nss-3.112.3.tar.gz 76858959 BLAKE2B 9cc4666cad51a45a4cdac4836b5e746f3ea77fc
 DIST nss-3.112.4.tar.gz 76625575 BLAKE2B dc1df2d54928c79bdd80975308e01205d1c4c18075790cf6a4378b57c536428b9fe128dc2b304b3c703ea93115e1e578066dea7a50d887f6c4526e7c0289dd3c SHA512 4f086be64b351608fbc107f24231956cd55aeb3ee06973e9eafa7e8a4bdba747a0295981a41e703ca0081b29f2e115348267c5df3c0ffbd0e8a3663e09705b24
 DIST nss-3.122.1.tar.gz 77656779 BLAKE2B 0c72fd858b0b979869254d997bbcfb54e96a100e7bdf93253084b51ed8e72d365ed16b99733e4cdb143300df880d946fcc92310e2ba646c13348b8cd9734bb47 SHA512 132cb72032b2d0b1ac962745980190013f29217a126951d6bfe013262e363c94fabe024066da01f1cee1d364b9ff9b08aef0cea86e83a3615ac8e1333b1e3ac9
 DIST nss-3.122.tar.gz 77654239 BLAKE2B a34de23e316cff66f989074c91b6a33788db7fc21bbeadafeb76001aa198dbaf024d33845bbee2c319f5dc65850f0cd6a83cdd50419d2dead6b5ffc25484c03d SHA512 53847c2de0e4608b387d5688ecf005a2a78da67408bda31f522539306816e25580d6046656cd5bb7fb9642feb625a904a17d3102573be96a9fd8b46e14037ff7
+DIST nss-3.123.tar.gz 77762089 BLAKE2B 978c07ecdda3d2eca1670215943583c6bc061c5d2bc9b107eb68c1fd5fddd933d685b110b9dcd0e3e648069d71afc21d9ca4e3bd2b9f164b206845c42117a911 SHA512 99675ce3725c4b9cb84b776b21626c2aa66098aeb6091616de1499bd529fd521b29ace027af4722415f928fa16369e314872fe563243eb27c8e5a454f350db8f
diff --git a/dev-libs/nss/nss-3.123.ebuild b/dev-libs/nss/nss-3.123.ebuild
new file mode 100644
index 000000000000..2127618c2573
--- /dev/null
+++ b/dev-libs/nss/nss-3.123.ebuild
@@ -0,0 +1,438 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit dot-a flag-o-matic multilib toolchain-funcs multilib-minimal
+
+NSPR_VER="4.38.2"
+RTM_NAME="NSS_${PV//./_}_RTM"
+
+# If the release is made in Github only, not released at the official archive.mozilla.org. These
+# Github-only tarballs have a different directory structure. Unfortunately more releases are
+# published through Github-only lately. Leave the variable empty for archive.mozilla.org release:
+# GH_ONLY_REL=
+GH_ONLY_REL=
+
+DESCRIPTION="Mozilla's Network Security Services library that implements PKI support"
+HOMEPAGE="https://developer.mozilla.org/en-US/docs/Mozilla/Projects/NSS"
+
+if [[ -n ${GH_ONLY_REL} ]] ; then
+	SRC_URI="https://github.com/nss-dev/nss/archive/refs/tags/${RTM_NAME}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/${PN}-${RTM_NAME}"
+else
+	SRC_URI="https://archive.mozilla.org/pub/security/nss/releases/${RTM_NAME}/src/${P}.tar.gz"
+	S="${WORKDIR}/${P}/${PN}"
+fi
+SRC_URI+=" cacert? ( https://dev.gentoo.org/~juippis/mozilla/patchsets/nss-3.104-cacert-class1-class3.patch )"
+
+LICENSE="|| ( MPL-2.0 GPL-2 LGPL-2.1 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-solaris"
+IUSE="cacert test test-full +utils cpu_flags_ppc_altivec cpu_flags_x86_avx2 cpu_flags_x86_sse3 cpu_flags_ppc_vsx"
+
+REQUIRED_USE="test-full? ( test )"
+
+PROPERTIES="test_network"
+RESTRICT="test"
+
+# pkg-config called by nss-config -> virtual/pkgconfig in RDEPEND
+RDEPEND="
+	>=dev-libs/nspr-${NSPR_VER}[${MULTILIB_USEDEP}]
+	>=dev-db/sqlite-3.8.2[${MULTILIB_USEDEP}]
+	>=virtual/zlib-1.2.8-r1:=[${MULTILIB_USEDEP}]
+	virtual/pkgconfig
+"
+DEPEND="${RDEPEND}"
+BDEPEND="dev-lang/perl"
+
+MULTILIB_CHOST_TOOLS=(
+	/usr/bin/nss-config
+)
+
+PATCHES=(
+	"${FILESDIR}"/v2-0001-Bug-2027768-Fix-build-failure-due-to-missing-gcm-.patch
+	"${FILESDIR}"/nss-3.103-gentoo-fixes-add-pkgconfig-files.patch
+	"${FILESDIR}"/nss-3.21-gentoo-fixup-warnings.patch
+)
+
+src_prepare() {
+	default
+
+	if use cacert ; then
+		eapply -p2 "${DISTDIR}"/nss-3.104-cacert-class1-class3.patch
+	fi
+
+	pushd coreconf >/dev/null || die
+	# hack nspr paths
+	echo 'INCLUDES += -I$(DIST)/include/dbm' \
+		>> headers.mk || die "failed to append include"
+
+	# modify install path
+	sed -e '/CORE_DEPTH/s:SOURCE_PREFIX.*$:SOURCE_PREFIX = $(CORE_DEPTH)/dist:' \
+		-i source.mk || die
+
+	# Respect LDFLAGS
+	sed -i -e 's/\$(MKSHLIB) -o/\$(MKSHLIB) \$(LDFLAGS) -o/g' rules.mk
+
+	# Workaround make-4.4's change to sub-make, bmo#1800237, bgo#882069
+	sed -i -e "s/^CPU_TAG = _.*/CPU_TAG = _$(nssarch)/" Linux.mk || die
+
+	popd >/dev/null || die
+
+	# Fix pkgconfig file for Prefix
+	sed -i -e "/^PREFIX =/s:= /usr:= ${EPREFIX}/usr:" \
+		config/Makefile || die
+
+	# use host shlibsign if need be #436216
+	if tc-is-cross-compiler ; then
+		sed -i \
+			-e 's:"${2}"/shlibsign:shlibsign:' \
+			cmd/shlibsign/sign.sh || die
+	fi
+
+	# dirty hack
+	sed -i -e "/CRYPTOLIB/s:\$(SOFTOKEN_LIB_DIR):../freebl/\$(OBJDIR):" \
+		lib/ssl/config.mk || die
+	sed -i -e "/CRYPTOLIB/s:\$(SOFTOKEN_LIB_DIR):../../lib/freebl/\$(OBJDIR):" \
+		cmd/platlibs.mk || die
+
+	multilib_copy_sources
+	lto-guarantee-fat
+
+	strip-flags
+}
+
+multilib_src_configure() {
+	# Ensure we stay multilib aware
+	sed -i -e "/@libdir@/ s:lib64:$(get_libdir):" config/Makefile || die
+}
+
+nssarch() {
+	# Most of the arches are the same as $ARCH
+	local t=${1:-${CHOST}}
+	case ${t} in
+		*86*-pc-solaris2*) echo "i86pc"   ;;
+		aarch64*)          echo "aarch64" ;;
+		hppa*)             echo "parisc"  ;;
+		i?86*)             echo "i686"    ;;
+		x86_64*)           echo "x86_64"  ;;
+		*)                 tc-arch ${t}   ;;
+	esac
+}
+
+# @USAGE: <pointer bytes> <tuple>
+nssbits() {
+	case $1 in
+		4) [[ $2 == x86_64* ]] && echo USE_X32=1 ;;
+		8) echo USE_64=1 ;;
+	esac
+}
+
+multilib_src_compile() {
+	tc-export_build_env
+
+	local makeargs=(
+		CC="$(tc-getCC)"
+		CCC="$(tc-getCXX)"
+		AR="$(tc-getAR) rc \$@"
+		RANLIB="$(tc-getRANLIB)"
+		OPTIMIZER=
+		disable_ckbi=0
+		$(nssbits "$(tc-get-ptr-size)" "${CHOST}")
+	)
+
+	# Take care of nspr settings #436216
+	local myCPPFLAGS="${CPPFLAGS} $($(tc-getPKG_CONFIG) nspr --cflags) -D_FILE_OFFSET_BITS=64"
+	unset NSPR_INCLUDE_DIR
+
+	export NSS_ALLOW_SSLKEYLOGFILE=1
+	export NSS_ENABLE_WERROR=0 #567158
+	export BUILD_OPT=1
+	export NSS_USE_SYSTEM_SQLITE=1
+	export NSDISTMODE=copy
+	export FREEBL_NO_DEPEND=1
+	export FREEBL_LOWHASH=1
+	export NSS_SEED_ONLY_DEV_URANDOM=1
+	export USE_SYSTEM_ZLIB=1
+	export ZLIB_LIBS=-lz
+	export ASFLAGS=""
+	# Fix build failure on arm64
+	export NS_USE_GCC=1
+	# Detect compiler type and set proper environment value
+	if tc-is-gcc; then
+		export CC_IS_GCC=1
+	elif tc-is-clang; then
+		export CC_IS_CLANG=1
+
+		# bgo#927839
+		export NSS_DISABLE_UNLOAD=1
+	fi
+
+	export NSS_DISABLE_GTESTS=$(usex !test 1 0)
+
+	# Include exportable custom settings defined by users, #900915
+	# Two examples uses:
+	#   EXTRA_NSSCONF="MYONESWITCH=1"
+	#   EXTRA_NSSCONF="MYVALUE=0 MYOTHERVALUE=1 MYTHIRDVALUE=1"
+	# e.g.
+	#   EXTRA_NSSCONF="NSS_ALLOW_SSLKEYLOGFILE=0"
+	# or
+	#   EXTRA_NSSCONF="NSS_ALLOW_SSLKEYLOGFILE=0 NSS_ENABLE_WERROR=1"
+	# etc.
+	if [[ -n "${EXTRA_NSSCONF}" ]]; then
+		ewarn "EXTRA_NSSCONF applied, please disable custom settings before reporting bugs."
+		read -a myextranssconf <<< "${EXTRA_NSSCONF}"
+
+		for (( i=0; i<${#myextranssconf[@]}; i++ )); do
+			export "${myextranssconf[$i]}"
+			echo "exported ${myextranssconf[$i]}"
+		done
+	fi
+
+	# explicitly disable altivec/vsx if not requested
+	# https://bugs.gentoo.org/789114
+	case ${ARCH} in
+		ppc*)
+			use cpu_flags_ppc_altivec || export NSS_DISABLE_ALTIVEC=1
+			use cpu_flags_ppc_vsx || export NSS_DISABLE_CRYPTO_VSX=1
+			;;
+	esac
+
+	use cpu_flags_x86_avx2 || export NSS_DISABLE_AVX2=1
+	use cpu_flags_x86_sse3 || export NSS_DISABLE_SSE3=1
+
+	local d
+
+	# Disables calling shlibsign during the build #956431 and #436216
+	tc-is-cross-compiler && makeargs+=( CROSS_COMPILE=1 )
+
+	# Build the host tools first.
+	LDFLAGS="${BUILD_LDFLAGS}" \
+	XCFLAGS="${BUILD_CFLAGS} -D_FILE_OFFSET_BITS=64" \
+	NSPR_LIB_DIR="${T}/fakedir" \
+	emake -C coreconf \
+		CC="$(tc-getBUILD_CC)" \
+		$(nssbits "$(tc-get-build-ptr-size)" "${CBUILD}")
+	makeargs+=( NSINSTALL="${PWD}/$(find -type f -name nsinstall)" )
+
+	# Then build the target tools.
+	for d in . lib/dbm ; do
+		CPPFLAGS="${myCPPFLAGS}" \
+		XCFLAGS="${CFLAGS} ${CPPFLAGS} -D_FILE_OFFSET_BITS=64" \
+		NSPR_LIB_DIR="${T}/fakedir" \
+		emake "${makeargs[@]}" -C ${d} OS_TEST="$(nssarch)"
+	done
+}
+
+multilib_src_test() {
+	einfo "Tests can take a *long* time, especially on a multilib system."
+	einfo "~10 minutes per lib configuration with only 'standard' tests,"
+	einfo "~40 minutes per lib configuration with 'full' tests. Bug #852755"
+
+	# https://www.linuxfromscratch.org/blfs/view/svn/postlfs/nss.html
+	# https://firefox-source-docs.mozilla.org/security/nss/legacy/nss_sources_building_testing/index.html#running_the_nss_test_suite
+	# https://www-archive.mozilla.org/projects/security/pki/nss/testnss_32.html (older)
+	export BUILD_OPT=1
+	export HOST="localhost"
+	export DOMSUF="localdomain"
+	export USE_IP=TRUE
+	export IP_ADDRESS="127.0.0.1"
+
+	# Only run the standard cycle instead of full, reducing testing time from 45 minutes to 15
+	# per lib implementation.
+	if use test-full ; then
+		# export NSS_CYCLES="standard pkix sharedb"
+		:;
+	else
+		export NSS_CYCLES="standard"
+	fi
+
+	NSINSTALL="${PWD}/$(find -type f -name nsinstall)"
+
+	cd "${BUILD_DIR}"/tests || die
+	# Hack to get current objdir (prefixed dir where built binaries are)
+	# Without this, at least multilib tests go wrong when building the amd64 variant
+	# after x86.
+	local objdir=$(find "${BUILD_DIR}"/dist -maxdepth 1 -iname Linux* | rev | cut -d/ -f1 | rev)
+
+	# Can tweak to a subset of tests in future if we need to, but would prefer not
+	OBJDIR="${objdir}" DIST="${BUILD_DIR}/dist" MOZILLA_ROOT="${BUILD_DIR}" ./all.sh || die
+}
+
+# Altering these 3 libraries breaks the CHK verification.
+# All of the following cause it to break:
+# - stripping
+# - prelink
+# - ELF signing
+# http://www.mozilla.org/projects/security/pki/nss/tech-notes/tn6.html
+# Either we have to NOT strip them, or we have to forcibly resign after
+# stripping.
+#local_libdir="$(get_libdir)"
+#export STRIP_MASK="
+#	*/${local_libdir}/libfreebl3.so*
+#	*/${local_libdir}/libnssdbm3.so*
+#	*/${local_libdir}/libsoftokn3.so*"
+
+export NSS_CHK_SIGN_LIBS="freebl3 nssdbm3 softokn3"
+
+generate_chk() {
+	local shlibsign="$1"
+	local libdir="$2"
+	einfo "Resigning core NSS libraries for FIPS validation"
+	shift 2
+	local i
+	for i in ${NSS_CHK_SIGN_LIBS} ; do
+		local libname=lib${i}.so
+		local chkname=lib${i}.chk
+		"${shlibsign}" \
+			-i "${libdir}"/${libname} \
+			-o "${libdir}"/${chkname}.tmp \
+		&& mv -f \
+			"${libdir}"/${chkname}.tmp \
+			"${libdir}"/${chkname} \
+		|| die "Failed to sign ${libname}"
+	done
+}
+
+cleanup_chk() {
+	local libdir="$1"
+	shift 1
+	local i
+	for i in ${NSS_CHK_SIGN_LIBS} ; do
+		local libfname="${libdir}/lib${i}.so"
+		# If the major version has changed, then we have old chk files.
+		[ ! -f "${libfname}" -a -f "${libfname}.chk" ] \
+			&& rm -f "${libfname}.chk"
+	done
+}
+
+multilib_src_install() {
+	pushd dist >/dev/null || die
+
+	dodir /usr/$(get_libdir)
+	cp -L */lib/*$(get_libname) "${ED}"/usr/$(get_libdir) || die "copying shared libs failed"
+	local i
+	for i in crmf freebl nssb nssckfw ; do
+		cp -L */lib/lib${i}.a "${ED}"/usr/$(get_libdir) || die "copying libs failed"
+	done
+
+	# Install nss-config and pkgconfig file
+	dodir /usr/bin
+	cp -L */bin/nss-config "${ED}"/usr/bin || die
+	dodir /usr/$(get_libdir)/pkgconfig
+	cp -L */lib/pkgconfig/nss.pc "${ED}"/usr/$(get_libdir)/pkgconfig || die
+
+	# create an nss-softokn.pc from nss.pc for libfreebl and some private headers
+	# bug 517266
+	sed -e 's#Libs:#Libs: -lfreebl#' \
+		-e 's#Cflags:#Cflags: -I${includedir}/private#' \
+		*/lib/pkgconfig/nss.pc >"${ED}"/usr/$(get_libdir)/pkgconfig/nss-softokn.pc \
+		|| die "could not create nss-softokn.pc"
+
+	# all the include files
+	insinto /usr/include/nss
+	doins public/nss/*.{h,api}
+	insinto /usr/include/nss/private
+	doins private/nss/{blapi,alghmac,cmac}.h
+
+	popd >/dev/null || die
+
+	local f nssutils
+	# Always enabled because we need it for chk generation.
+	nssutils=( shlibsign )
+
+	if multilib_is_native_abi ; then
+		if use utils; then
+			# The tests we do not need to install.
+			#nssutils_test="bltest crmftest dbtest dertimetest
+			#fipstest remtest sdrtest"
+			# checkcert utils has been removed in nss-3.22:
+			# https://bugzilla.mozilla.org/show_bug.cgi?id=1187545
+			# https://hg.mozilla.org/projects/nss/rev/df1729d37870
+			# certcgi has been removed in nss-3.36:
+			# https://bugzilla.mozilla.org/show_bug.cgi?id=1426602
+			# conflict removed in 3.122.
+			nssutils+=(
+				addbuiltin
+				atob
+				baddbdir
+				btoa
+				certutil
+				cmsutil
+				crlutil
+				derdump
+				digest
+				makepqg
+				mangle
+				modutil
+				multinit
+				nonspr10
+				ocspclnt
+				oidcalc
+				p7content
+				p7env
+				p7sign
+				p7verify
+				pk11mode
+				pk12util
+				pp
+				rsaperf
+				selfserv
+				signtool
+				signver
+				ssltap
+				strsclnt
+				symkeyutil
+				tstclnt
+				vfychain
+				vfyserv
+			)
+			# install man-pages for utils (bug #516810)
+			doman doc/nroff/*.1
+		fi
+		pushd dist/*/bin >/dev/null || die
+		for f in ${nssutils[@]}; do
+			dobin ${f}
+		done
+		popd >/dev/null || die
+	fi
+	strip-lto-bytecode
+}
+
+pkg_postinst() {
+	if [[ -n "${ROOT}" ]]; then
+		elog "You appear to to be installing in a seperate \$ROOT"
+		elog "to complete the setup and re-sign libraries please run:"
+		elog "emerge --config '=${CATEGORY}/${PF}'"
+	else
+		sign_libraries
+	fi
+}
+
+pkg_config() {
+	sign_libraries
+}
+
+sign_libraries() {
+	multilib_pkg_postinst() {
+		# We must re-sign the libraries AFTER they are stripped.
+		local shlibsign="${EROOT}/usr/bin/shlibsign"
+		# See if we can execute it (cross-compiling & such). #436216
+		"${shlibsign}" -h >&/dev/null
+		if [[ $? -gt 1 ]] ; then
+			shlibsign="shlibsign"
+		fi
+		generate_chk "${shlibsign}" "${EROOT}"/usr/$(get_libdir)
+	}
+
+	multilib_foreach_abi multilib_pkg_postinst
+}
+
+pkg_postrm() {
+	multilib_pkg_postrm() {
+		cleanup_chk "${EROOT}"/usr/$(get_libdir)
+	}
+
+	multilib_foreach_abi multilib_pkg_postrm
+}
diff --git a/dev-libs/pocketfft/metadata.xml b/dev-libs/pocketfft/metadata.xml
index a6b256295160..66ee50826efd 100644
--- a/dev-libs/pocketfft/metadata.xml
+++ b/dev-libs/pocketfft/metadata.xml
@@ -1,9 +1,9 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
 <pkgmetadata>
- <maintainer type="person">
-  <email>tupone@gentoo.org</email>
-  <name>Tupone Alfredo</name>
+ <maintainer type="project">
+  <email>sci@gentoo.org</email>
+  <name>Gentoo Science Project</name>
  </maintainer>
  
  <origin>gentoo-staging</origin>
diff --git a/dev-libs/poco/Manifest b/dev-libs/poco/Manifest
index 2ac1182521bb..c063933e32dd 100644
--- a/dev-libs/poco/Manifest
+++ b/dev-libs/poco/Manifest
@@ -1,2 +1,2 @@
-DIST poco-1.15.0.tar.gz 11214675 BLAKE2B f9a9b26cff7f7d9086475fc2e6ace4a82bd40d847c03459482717cfd1d08d269238a0166aaf14b69b4d94e4ab77a92f21a578859432ecb96fe746b89180d9acd SHA512 97aef122d28157cbf0990400290bbb6667cfac3207fa6144239a6c1868427e5531895a333d95eeec968b2cc55168dad977b74f76d5b80f9cd75a16b6f2d50552
 DIST poco-1.15.1.tar.gz 11287610 BLAKE2B 9d4c71a5a0d3d91ed0ade57196e157a99bc8231ea759e661bd5e26012249543a297cceadf5ebe8b530f7d5891850ba276c6e237f72cf78805651d64e00f22344 SHA512 03daecfb9f6baa25eac327ccaa2e2cf51aa1520d3d8c6c0399bc0c4be15cf71585ee0a8bca612ad26e5d79edf9367c1687060684632e0cab4dabb0f8d6aed1a8
+DIST poco-1.15.2.tar.gz 11350236 BLAKE2B 60254d34c598f12ae5d0f6744fa2b011958d61e2975771e09729f3d170c8249610b5a7ef055b669573acb7947c54d8b1b1fdb66ed97530346a468c17536e7ae7 SHA512 3c0c65ef6886e40283c764b52df8aa1aaed9359d659537abf72c0a86d7b61bfc0b67a3a9bb68f940d62bf40bedcf9fcba29b1994c2cbdcb5c90e89c853401269
diff --git a/dev-libs/poco/files/poco-1.15.2-NetSSL_OpenSSL_src_Context.patch b/dev-libs/poco/files/poco-1.15.2-NetSSL_OpenSSL_src_Context.patch
new file mode 100644
index 000000000000..75d53e1694c5
--- /dev/null
+++ b/dev-libs/poco/files/poco-1.15.2-NetSSL_OpenSSL_src_Context.patch
@@ -0,0 +1,46 @@
+diff '--color=auto' -urN poco-poco-1.15.2-release.orig/NetSSL_OpenSSL/src/Context.cpp poco-poco-1.15.2-release/NetSSL_OpenSSL/src/Context.cpp
+--- poco-poco-1.15.2-release.orig/NetSSL_OpenSSL/src/Context.cpp	2026-04-17 21:03:21.129824935 +0200
++++ poco-poco-1.15.2-release/NetSSL_OpenSSL/src/Context.cpp	2026-04-17 21:04:24.835430157 +0200
+@@ -857,8 +857,6 @@
+ 			throw SSLContextException("Error creating Diffie-Hellman parameters", msg);
+ 		}
+ 
+-#if !defined(LIBRESSL_VERSION_NUMBER)
+-
+ 		BIGNUM* p = nullptr;
+ 		BIGNUM* g = nullptr;
+ 		if (keyDHGroup == KEY_DH_GROUP_2048)
+@@ -886,33 +884,6 @@
+ 			throw SSLContextException("Error creating Diffie-Hellman parameters");
+ 		}
+ 
+-#else // LIBRESSL_VERSION_NUMBER
+-
+-		if (keyDHGroup == KEY_DH_GROUP_2048)
+-		{
+-			dh->p = BN_bin2bn(dh2048_p, sizeof(dh2048_p), 0);
+-			dh->g = BN_bin2bn(dh2048_g, sizeof(dh2048_g), 0);
+-			dh->length = 256;
+-		}
+-		else if (keyDHGroup == KEY_DH_GROUP_1024)
+-		{
+-			dh->p = BN_bin2bn(dh1024_p, sizeof(dh1024_p), 0);
+-			dh->g = BN_bin2bn(dh1024_g, sizeof(dh1024_g), 0);
+-			dh->length = 160;
+-		}
+-		else
+-		{
+-			throw Poco::NotImplementedException(Poco::format(
+-				"DH Group: %d", static_cast<int>(keyDHGroup)));
+-		}
+-		if ((!dh->p) || (!dh->g))
+-		{
+-			DH_free(dh);
+-			throw SSLContextException("Error creating Diffie-Hellman parameters");
+-		}
+-
+-#endif // !defined(LIBRESSL_VERSION_NUMBER)
+-
+ 	}
+ 	SSL_CTX_set_tmp_dh(_pSSLContext, dh);
+ 	SSL_CTX_set_options(_pSSLContext, SSL_OP_SINGLE_DH_USE);
diff --git a/dev-libs/poco/poco-1.15.0.ebuild b/dev-libs/poco/poco-1.15.2.ebuild
index e6ccbcdffbf6..686d9bffb323 100644
--- a/dev-libs/poco/poco-1.15.0.ebuild
+++ b/dev-libs/poco/poco-1.15.2.ebuild
@@ -78,7 +78,10 @@ src_prepare() {
 
 	# Add missing directory that breaks the build
 	mkdir -p Encodings/testsuite/data || die
-	eapply -p1 ${FILESDIR}/poco-1.12.1-NetSSL_OpenSSL_src_Context.patch
+
+	if use libressl; then
+		eapply -p1 ${FILESDIR}/poco-1.15.2-NetSSL_OpenSSL_src_Context.patch
+	fi
 }
 
 src_configure() {
diff --git a/dev-libs/xmlsec/xmlsec-1.3.9.ebuild b/dev-libs/xmlsec/xmlsec-1.3.9.ebuild
index c035d93176c2..44937080fa09 100644
--- a/dev-libs/xmlsec/xmlsec-1.3.9.ebuild
+++ b/dev-libs/xmlsec/xmlsec-1.3.9.ebuild
@@ -17,7 +17,7 @@ S="${WORKDIR}/${PN}1-${PV}"
 LICENSE="MIT"
 # Upstream consider major version bumps to be changes in either X or Y in X.Y.Z
 SLOT="0/$(ver_cut 1-2)"
-KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+KEYWORDS="amd64 ~arm arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
 IUSE="doc gcrypt gnutls http nss +openssl static-libs test"
 RESTRICT="!test? ( test )"
 REQUIRED_USE="