Adding metadata

2 files changed, 114 insertions, 0 deletions

diff --git a/dev-libs/libical/Manifest b/dev-libs/libical/Manifest
index 76c3a0d8919e..30c63cdeb907 100644
--- a/dev-libs/libical/Manifest
+++ b/dev-libs/libical/Manifest
@@ -1 +1,2 @@
 DIST libical-3.0.19.tar.gz 973744 BLAKE2B d3a8bc71cbef7014db23358b523691de7f32c071d5d978c79e94b7f21c4776bc9f88bd39df5ba552ce6e8e0f86beda13bbd14a73a11f21b1f45e020d2a15bb53 SHA512 32e5cac219801b40d8691deae6efae6fdaa64ca0968a72af5b27647958d44d79626c26c4e3675cfb284c2f1039c237c61ba2dd6030e9b1ea6a9d69296424240d
+DIST libical-3.0.20.tar.gz 973928 BLAKE2B 3492efc8ace54b254a7079aa863394da0555a4c342b7c83a47991ecdf31fe06035bb8c196700ec6804bde2b1c074e5e3a2118c948fec26bdff90b92b9c5042e8 SHA512 2506320240ba0e4287b6ef1b90b653eacd51105d392b91f8c772f3b0745fecbf55eecfe81f89413cc56106b71ccca780754df31f5190ffce6c372126e27bf1da
diff --git a/dev-libs/libical/libical-3.0.20.ebuild b/dev-libs/libical/libical-3.0.20.ebuild
new file mode 100644
index 000000000000..26a82e3698b3
--- /dev/null
+++ b/dev-libs/libical/libical-3.0.20.ebuild
@@ -0,0 +1,113 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+VALA_USE_DEPEND="vapigen"
+inherit cmake python-any-r1 vala
+
+DESCRIPTION="Implementation of basic iCAL protocols"
+HOMEPAGE="https://github.com/libical/libical"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="|| ( MPL-2.0 LGPL-2.1 )"
+SLOT="0/3"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="doc examples +glib +introspection static-libs test vala"
+
+REQUIRED_USE="introspection? ( glib ) vala? ( introspection )"
+
+RESTRICT="!test? ( test )"
+
+COMMON_DEPEND="
+	dev-libs/icu:=
+	glib? ( dev-libs/glib:2 )
+"
+DEPEND="${COMMON_DEPEND}
+	glib? ( dev-libs/libxml2:2 )
+"
+RDEPEND="${COMMON_DEPEND}
+	sys-libs/timezone-data
+"
+BDEPEND="
+	dev-lang/perl
+	virtual/pkgconfig
+	doc? (
+		app-text/doxygen[dot]
+		glib? ( dev-util/gtk-doc )
+	)
+	introspection? ( dev-libs/gobject-introspection )
+	test? (
+		${PYTHON_DEPS}
+		glib? ( $(python_gen_any_dep 'dev-python/pygobject:3[${PYTHON_USEDEP}]') )
+	)
+	vala? ( $(vala_depend) )
+"
+
+DOCS=(
+	AUTHORS README.md ReleaseNotes.txt TEST THANKS TODO
+	doc/{AddingOrModifyingComponents.txt,UsingLibical.md}
+)
+
+PATCHES=( "${FILESDIR}/${PN}-3.0.11-pkgconfig-libdir.patch" )
+
+python_check_deps() {
+	python_has_version "dev-python/pygobject:3[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	cmake_src_prepare
+	use vala && vala_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_BerkeleyDB=ON
+		-DICAL_BUILD_DOCS=$(usex doc)
+		-DLIBICAL_BUILD_EXAMPLES=$(use examples)
+		-DICAL_GLIB=$(usex glib)
+		-DGOBJECT_INTROSPECTION=$(usex introspection)
+		-DSHARED_ONLY=$(usex !static-libs)
+		-DLIBICAL_BUILD_TESTING=$(usex test)
+		-DICAL_GLIB_VAPI=$(usex vala)
+	)
+	if use vala; then
+		mycmakeargs+=(
+			-DVALAC="${VALAC}"
+			-DVAPIGEN="${VAPIGEN}"
+		)
+	fi
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+
+	if use doc; then
+		cmake_src_compile docs
+
+		HTML_DOCS=( "${BUILD_DIR}"/apidocs/html/. )
+	fi
+}
+
+src_test() {
+	local myctestargs=(
+		-E "(icalrecurtest|icalrecurtest-r)" # bug 660282
+	)
+
+	cmake_src_test
+}
+
+src_install() {
+	cmake_src_install
+
+	if use examples; then
+		rm examples/CMakeLists.txt || die
+		dodoc -r examples
+	fi
+}