Adding metadata

1 files changed, 69 insertions, 0 deletions

diff --git a/dev-libs/libgit2/libgit2-1.9.4.ebuild b/dev-libs/libgit2/libgit2-1.9.4.ebuild
new file mode 100644
index 000000000000..1fefd75da135
--- /dev/null
+++ b/dev-libs/libgit2/libgit2-1.9.4.ebuild
@@ -0,0 +1,69 @@
+# Copyright 2021-2026 Liguros Authors
+# Distributed under the terms of the GNU General Public License v2
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..14} )
+inherit cmake python-any-r1
+
+DESCRIPTION="A linkable library for Git"
+HOMEPAGE="https://libgit2.org"
+SRC_URI="https://github.com/libgit2/libgit2/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S=${WORKDIR}/${P/_/-}
+
+LICENSE="GPL-2-with-linking-exception"
+SLOT="0/$(ver_cut 1-2)"
+KEYWORDS="amd64 arm arm64 ppc ppc64 ~riscv x86 ~ppc-macos"
+IUSE="examples gssapi libressl +ssh test +threads trace"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/libpcre:=
+	net-libs/http-parser:=
+	sys-libs/zlib
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( >=dev-libs/libressl-3.5.0:0= )
+	gssapi? ( virtual/krb5 )
+	ssh? ( net-libs/libssh2 )
+"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_CLAR=$(usex test)
+		-DENABLE_TRACE=$(usex trace ON OFF)
+		-DUSE_GSSAPI=$(usex gssapi ON OFF)
+		-DUSE_SSH=$(usex ssh ON OFF)
+		-DTHREADSAFE=$(usex threads)
+		-DUSE_HTTP_PARSER=system
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	if [[ ${EUID} -eq 0 ]] ; then
+		# repo::iterator::fs_preserves_error fails if run as root
+		# since root can still access dirs with 0000 perms
+		ewarn "Skipping tests: non-root privileges are required for all tests to pass"
+	else
+		local TEST_VERBOSE=1
+		cmake_src_test -R offline
+	fi
+}
+
+src_install() {
+	cmake_src_install
+	dodoc docs/*.{md,txt}
+
+	if use examples ; then
+		find examples -name '.gitignore' -delete || die
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}