Adding metadata

3 files changed, 82 insertions, 0 deletions

diff --git a/dev-libs/libgdata/Manifest b/dev-libs/libgdata/Manifest
new file mode 100644
index 000000000000..89134be570cf
--- /dev/null
+++ b/dev-libs/libgdata/Manifest
@@ -0,0 +1 @@
+DIST libgdata-0.18.1.tar.xz 851584 BLAKE2B 860cc42c4d0bdbdd6ca1a1001ec7ea5acc26dd1339052365554123e6524fddce65704a11614c8a081eb3eef10395fb1b4d2dfd3cf942dd1ae3556507af4c7c52 SHA512 15ff708760ca5023b692fd565c26a7c3acf035073534c0cd3f1f90e46ee0c60d14dedf360d3ac146d37135e200d9c2bc4b657e81468d0efde4821a9219875b98
diff --git a/dev-libs/libgdata/libgdata-0.18.1-r2.ebuild b/dev-libs/libgdata/libgdata-0.18.1-r2.ebuild
new file mode 100644
index 000000000000..4b0e7e4f6d32
--- /dev/null
+++ b/dev-libs/libgdata/libgdata-0.18.1-r2.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome.org gnome2-utils meson vala xdg
+
+DESCRIPTION="GLib-based library for accessing online service APIs using the GData protocol"
+HOMEPAGE="https://wiki.gnome.org/Projects/libgdata"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/22" # subslot = libgdata soname version
+
+IUSE="+crypt gnome-online-accounts gtk-doc +introspection test vala"
+REQUIRED_USE="vala? ( introspection )"
+RESTRICT="!test? ( test )"
+
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ppc ppc64 ~riscv ~sparc x86"
+
+RDEPEND="
+	>=dev-libs/glib-2.44.0:2
+	>=dev-libs/json-glib-0.15[introspection?]
+	>=dev-libs/libxml2-2:2=
+	>=net-libs/libsoup-2.55.90:2.4[introspection?,vala?]
+	crypt? ( app-crypt/gcr:0= )
+	gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.8:=[introspection?,vala?] )
+	introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/glib-utils
+	gtk-doc? ( >=dev-util/gtk-doc-1.25
+		app-text/docbook-xml-dtd:4.3 )
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	test? (
+		>=net-libs/uhttpmock-0.5.0:0
+		>=x11-libs/gdk-pixbuf-2.14:2
+	)
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	default
+	use vala && vala_src_prepare
+	gnome2_environment_reset
+	# Don't waste time building a couple small demos that aren't installed
+	sed -i -e '/subdir.*demos/d' meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dgtk=disabled # only for demos
+		$(meson_feature crypt gnome)
+		$(meson_feature gnome-online-accounts goa)
+		-Doauth1=disabled
+		$(meson_use test always_build_tests)
+		-Dinstalled_tests=false
+		-Dman=true
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use introspection)
+		$(meson_use vala vapi)
+	)
+	meson_src_configure
+}
diff --git a/dev-libs/libgdata/metadata.xml b/dev-libs/libgdata/metadata.xml
new file mode 100644
index 000000000000..f452e3e41950
--- /dev/null
+++ b/dev-libs/libgdata/metadata.xml
@@ -0,0 +1,16 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>gnome@gentoo.org</email>
+    <name>Gentoo GNOME Desktop</name>
+  </maintainer>
+  <use>
+    <flag name="crypt">Use <pkg>app-crypt/gcr</pkg> for keeping tokens and passwords in non-pageable memory for improved security</flag>
+    <flag name="gnome-online-accounts">Enable <pkg>net-libs/gnome-online-accounts</pkg> support</flag>
+  </use>
+  <upstream>
+    <remote-id type="cpe">cpe:/a:gnome:libgdata</remote-id>
+  </upstream>
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>