Adding metadata

3 files changed, 0 insertions, 105 deletions

diff --git a/dev-libs/amdgpu-pro-opencl/Manifest b/dev-libs/amdgpu-pro-opencl/Manifest
deleted file mode 100644
index bb125b081adf..000000000000
--- a/dev-libs/amdgpu-pro-opencl/Manifest
+++ /dev/null
@@ -1 +0,0 @@
-DIST amdgpu-pro-20.40-1147286-ubuntu-20.04.tar.xz 333011308 BLAKE2B 82d0b728ee06bbc1a3dde579215a23397abb223caf7e2922b71dda9f31bebf13eaf5b1c5c7f25146dc2cfb31b57d16e848b0f902e599ed361e9285998cdb99fd SHA512 9b064a3b02d2a1ec18fdd6c098b70f4a8c6f93e4bfdc4e9a032ca387bdf7223278622c19d5bd55e493555c5f734168c3f2768cb743f9e00dcf5f96cbc399c7b3
diff --git a/dev-libs/amdgpu-pro-opencl/amdgpu-pro-opencl-20.40.1147286.ebuild b/dev-libs/amdgpu-pro-opencl/amdgpu-pro-opencl-20.40.1147286.ebuild
deleted file mode 100644
index 4c69674212fb..000000000000
--- a/dev-libs/amdgpu-pro-opencl/amdgpu-pro-opencl-20.40.1147286.ebuild
+++ /dev/null
@@ -1,99 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-MULTILIB_COMPAT=( abi_x86_{32,64} )
-
-inherit unpacker multilib-minimal
-
-SUPER_PN='amdgpu-pro'
-MY_PV=$(ver_rs 2 '-')
-
-DESCRIPTION="Proprietary OpenCL implementation for AMD GPUs"
-HOMEPAGE="https://www.amd.com/en/support/kb/release-notes/rn-amdgpu-unified-linux-20-40"
-SRC_URI="${SUPER_PN}-${MY_PV}-ubuntu-20.04.tar.xz"
-
-LICENSE="AMD-GPU-PRO-EULA"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-
-RESTRICT="bindist mirror fetch strip"
-
-BDEPEND="dev-util/patchelf"
-COMMON=">=virtual/opencl-3"
-DEPEND="${COMMON}"
-RDEPEND="${COMMON}
-	!media-libs/mesa[opencl]" # Bug #686790
-
-QA_PREBUILT="/opt/amdgpu/lib*/*"
-
-S="${WORKDIR}/${SUPER_PN}-${MY_PV}-ubuntu-20.04"
-
-pkg_nofetch() {
-	local pkgver=$(ver_cut 1-2)
-	einfo "Please download Radeon Software for Linux version ${pkgver} for Ubuntu 20.04.1 from"
-	einfo "    ${HOMEPAGE}"
-	einfo "The archive should then be placed into your distfiles directory."
-}
-
-src_unpack() {
-	default
-
-	local ids_ver="1.0.0"
-	local patchlevel=$(ver_cut 3)
-	cd "${S}" || die
-	unpack_deb "${S}/libdrm-amdgpu-common_${ids_ver}-${patchlevel}_all.deb"
-	multilib_parallel_foreach_abi multilib_src_unpack
-}
-
-multilib_src_unpack() {
-	local libdrm_ver="2.4.100"
-	local patchlevel=$(ver_cut 3)
-	local deb_abi
-	[[ ${ABI} == x86 ]] && deb_abi=i386
-
-	mkdir -p "${BUILD_DIR}" || die
-	pushd "${BUILD_DIR}" >/dev/null || die
-	unpack_deb "${S}/opencl-orca-amdgpu-pro-icd_${MY_PV}_${deb_abi:-${ABI}}.deb"
-	unpack_deb "${S}/libdrm-amdgpu-amdgpu1_${libdrm_ver}-${patchlevel}_${deb_abi:-${ABI}}.deb"
-	popd >/dev/null || die
-}
-
-multilib_src_install() {
-	local dir_abi short_abi
-	[[ ${ABI} == x86 ]] && dir_abi=i386-linux-gnu && short_abi=32
-	[[ ${ABI} == amd64 ]] && dir_abi=x86_64-linux-gnu && short_abi=64
-
-	into "/opt/amdgpu"
-	patchelf --set-rpath '$ORIGIN' "opt/${SUPER_PN}/lib/${dir_abi}"/libamdocl-orca${short_abi}.so || die "Failed to fix library rpath"
-	dolib.so "opt/${SUPER_PN}/lib/${dir_abi}"/*
-	dolib.so "opt/amdgpu/lib/${dir_abi}"/*
-
-	insinto /etc/OpenCL/vendors
-	echo "/opt/amdgpu/$(get_libdir)/libamdocl-orca${short_abi}.so" \
-		> "${T}/${SUPER_PN}-${ABI}.icd" || die "Failed to generate ICD file for ABI ${ABI}"
-	doins "${T}/${SUPER_PN}-${ABI}.icd"
-}
-
-multilib_src_install_all() {
-	insinto "/opt/amdgpu"
-	doins -r opt/amdgpu/share
-}
-
-pkg_postinst() {
-	if [[ -z "${REPLACING_VERSIONS}" ]]; then
-		ewarn "Please note that using proprietary OpenCL libraries together with the"
-		ewarn "Open Source amdgpu stack is not officially supported by AMD. Do not ask them"
-		ewarn "for support in case of problems with this package."
-		ewarn ""
-		ewarn "Furthermore, if you have the whole AMDGPU-Pro stack installed this package"
-		ewarn "will almost certainly conflict with it. This might change once AMDGPU-Pro"
-		ewarn "has become officially supported by Gentoo."
-	fi
-
-	elog ""
-	elog "This package is now DEPRECATED on amd64 in favour of dev-libs/rocm-opencl-runtime."
-	elog "Moreover, it only provides legacy AMDGPU-Pro OpenCL libraries which are not compatible with Vega 10 and newer GPUs."
-	elog ""
-}
diff --git a/dev-libs/amdgpu-pro-opencl/metadata.xml b/dev-libs/amdgpu-pro-opencl/metadata.xml
deleted file mode 100644
index 115e9d64a669..000000000000
--- a/dev-libs/amdgpu-pro-opencl/metadata.xml
+++ /dev/null
@@ -1,5 +0,0 @@
-<?xml version="1.0" encoding="UTF-8"?>
-<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
-<pkgmetadata>
-	<!-- maintainer-needed -->
-</pkgmetadata>