Adding metadata

1 files changed, 40 insertions, 0 deletions

diff --git a/dev-lang/python-exec-conf/python-exec-conf-2.4.6.ebuild b/dev-lang/python-exec-conf/python-exec-conf-2.4.6.ebuild
new file mode 100644
index 000000000000..f5097e76d720
--- /dev/null
+++ b/dev-lang/python-exec-conf/python-exec-conf-2.4.6.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit python-utils-r1
+
+MY_P=${P/-conf}
+DESCRIPTION="Configuration file for dev-lang/python-exec"
+HOMEPAGE="https://github.com/mgorny/python-exec/"
+SRC_URI="https://github.com/mgorny/python-exec/releases/download/v${PV}/${MY_P}.tar.bz2"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD-2"
+SLOT="2"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~arm64-macos ~x64-macos ~x64-solaris"
+# Internal Python project hack.  Do not copy it.  Ever.
+IUSE="${_PYTHON_ALL_IMPLS[@]/#/python_targets_}"
+
+RDEPEND="!<dev-lang/python-exec-2.4.6-r4"
+
+src_configure() {
+	:
+}
+
+src_install() {
+	local pyimpls=() i EPYTHON
+	for i in "${_PYTHON_ALL_IMPLS[@]}"; do
+		if use "python_targets_${i}"; then
+			_python_export "${i}" EPYTHON
+			pyimpls+=( "${EPYTHON}" )
+		fi
+	done
+
+	# Prepare and own the template
+	insinto /etc/python-exec
+	newins - python-exec.conf \
+		< <(sed -n -e '/^#/p' config/python-exec.conf.example &&
+			printf '%s\n' "${pyimpls[@]}" | tac)
+}