Adding metadata

3 files changed, 73 insertions, 2 deletions

diff --git a/dev-java/ant-apache-bsf/ant-apache-bsf-1.10.9.ebuild b/dev-java/ant-apache-bsf/ant-apache-bsf-1.10.9-r1.ebuild
index f6ba1618b0fe..04cdcf48579c 100644
--- a/dev-java/ant-apache-bsf/ant-apache-bsf-1.10.9.ebuild
+++ b/dev-java/ant-apache-bsf/ant-apache-bsf-1.10.9-r1.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -12,7 +12,7 @@ inherit ant-tasks
 KEYWORDS="amd64 ppc64 x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
 IUSE="python javascript tcl"
 
-DEPEND=">=dev-java/bsf-2.4.0-r1:2.3[python?,javascript?,tcl?]"
+DEPEND=">=dev-java/bsf-2.4.0-r1:2.3[javascript?,tcl?]"
 RDEPEND="${DEPEND}"
 
 pkg_postinst() {
diff --git a/dev-java/bsf/Manifest b/dev-java/bsf/Manifest
index aeacf27f9b5a..4add2dfdfd39 100644
--- a/dev-java/bsf/Manifest
+++ b/dev-java/bsf/Manifest
@@ -1 +1,2 @@
 DIST bsf-src-2.4.0.tar.gz 299749 BLAKE2B 41f3cfe77b1ccf6b78493df7f5f288b397234b3236977c4b7d2e6c85b330e40319474419f560eefa1632da4d0524593b8c3e0c66cd27b852749b1405c20df5a6 SHA512 a1e7564fd14abbf725fee75c4b0ba5f92d7eada0e242ad05897753bb4afe639d859c42cae1d684e8dd9151409d4cc68e1a422a70bc74d8016144cc30d03a2d43
+DIST bsf-src-2.4.0.tar.gz.asc 191 BLAKE2B c4d17ee6df06aa2da70b9e733cb9890cef2f0f22124d8699400494496c4045851feb006e53ee4f4d09e926d982afd4057c08caf791fd4ea8a8bef5f576d6d8a1 SHA512 b82d1f9e6cd6bc3b3228ceb8f5f0679e8dd95c2200328accafa0ee9fd4b4065367e071d0fa718ecdc34e11c6b14456a671d4e8e74d2b56dea4e8fc3db73c4392
diff --git a/dev-java/bsf/bsf-2.4.0-r4.ebuild b/dev-java/bsf/bsf-2.4.0-r4.ebuild
new file mode 100644
index 000000000000..392c3e6152ec
--- /dev/null
+++ b/dev-java/bsf/bsf-2.4.0-r4.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+JAVA_PKG_IUSE="doc source"
+
+inherit java-pkg-2 java-pkg-simple verify-sig
+
+DESCRIPTION="Bean Script Framework"
+HOMEPAGE="https://commons.apache.org/proper/commons-bsf/"
+SRC_URI="mirror://apache/commons/bsf/source/bsf-src-${PV}.tar.gz
+	verify-sig? ( https://downloads.apache.org/commons/bsf/source/bsf-src-${PV}.tar.gz.asc )"
+S="${WORKDIR}/${P}"
+
+LICENSE="Apache-2.0"
+SLOT="2.3"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+
+# If you add new ones, add them to ant-apache-bsf too for use dependencies
+IUSE="javascript tcl"
+
+VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/commons.apache.org.asc"
+BDEPEND="verify-sig? ( sec-keys/openpgp-keys-apache-commons )"
+CDEPEND="
+	dev-java/commons-logging:0
+	dev-java/xalan:0
+	javascript? ( dev-java/rhino:1.6 )
+	tcl? ( dev-java/jacl:0 )
+"
+DEPEND="${CDEPEND}
+	>=virtual/jdk-1.8:*"
+RDEPEND="${CDEPEND}
+	>=virtual/jre-1.8:*"
+
+DOCS=( CHANGES.txt NOTICE.txt README.txt RELEASE-NOTE.txt TODO.txt )
+
+JAVA_CLASSPATH_EXTRA="
+	commons-logging
+	xalan
+"
+JAVA_MAIN_CLASS="org.apache.bsf.Main"
+JAVA_SRC_DIR="src"
+
+src_prepare() {
+	java-pkg-2_src_prepare
+	rm -r src/org/apache/bsf/engines/{netrexx,jython} || die
+	if use javascript; then
+		JAVA_GENTOO_CLASSPATH+=" rhino-1.6"
+	else
+		rm -r src/org/apache/bsf/engines/javascript || die
+	fi
+	if use tcl; then
+		JAVA_GENTOO_CLASSPATH+=" jacl"
+	else
+		rm -r src/org/apache/bsf/engines/jacl || die
+	fi
+}
+
+src_install() {
+	java-pkg-simple_src_install
+#	java-pkg_register-optional-dependency bsh,groovy-1,jruby
+}
+
+pkg_postinst() {
+	elog "Support for javascript and tcl is controlled via USE flags."
+	elog "Also, following languages can be supported just by installing"
+	elog "respective package with USE=\"bsf\": BeanShell (dev-java/bsh),"
+	elog "Groovy (dev-java/groovy) and JRuby (dev-java/jruby)"
+}