Adding metadata

19 files changed, 488 insertions, 23 deletions

diff --git a/dev-java/ant-core/ant-core-1.10.9-r1.ebuild b/dev-java/ant-core/ant-core-1.10.9-r1.ebuild
new file mode 100644
index 000000000000..9c38f6a612b8
--- /dev/null
+++ b/dev-java/ant-core/ant-core-1.10.9-r1.ebuild
@@ -0,0 +1,161 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# Don't depend on itself.
+JAVA_ANT_DISABLE_ANT_CORE_DEP="true"
+
+# Rewriting build.xml files for the testcases has no use at the moment.
+JAVA_PKG_BSFIX_ALL="no"
+JAVA_PKG_IUSE="doc source"
+
+inherit java-pkg-2 java-ant-2 prefix
+
+MY_P="apache-ant-${PV}"
+
+DESCRIPTION="Java-based build tool similar to 'make' that uses XML configuration files"
+HOMEPAGE="https://ant.apache.org/"
+SRC_URI="https://archive.apache.org/dist/ant/source/${MY_P}-src.tar.bz2
+	https://dev.gentoo.org/~fordfrog/distfiles/ant-${PV}-gentoo.tar.bz2"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+# Some dependencies for building Javadoc are unavailable on these architectures
+REQUIRED_USE="doc? ( !arm !arm64 )"
+
+CDEPEND=">=virtual/jdk-1.8:*"
+DEPEND="${CDEPEND}
+	doc? ( !arm? ( !arm64? (
+		dev-java/bcel:0
+		dev-java/bsf:2.3
+		dev-java/commons-logging:0
+		dev-java/commons-net:0
+		dev-java/jakarta-activation-api:1
+		dev-java/jakarta-regexp:1.4
+		dev-java/jakarta-oro:2.0
+		dev-java/jdepend:0
+		dev-java/jsch:0
+		dev-java/log4j:0
+		dev-java/oracle-javamail:0
+		dev-java/sun-jai-bin:0
+		dev-java/xalan:0
+		dev-java/xml-commons-resolver:0
+		dev-java/xz-java:0
+	) ) )"
+RDEPEND="${CDEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+RESTRICT="test"
+
+PATCHES=(
+	"${WORKDIR}/${PV}-build.patch"
+	"${WORKDIR}/${PV}-launch.patch"
+)
+
+src_prepare() {
+	default
+
+	eprefixify "${S}/src/script/ant"
+
+	# Fixes bug 556008.
+	java-ant_xml-rewrite -f build.xml \
+		-c -e javadoc \
+		-a failonerror \
+		-v "false"
+
+	# See bug #196080 for more details.
+	java-ant_bsfix_one build.xml
+	java-pkg-2_src_prepare
+
+	# Remove JDK9+ stuff
+	einfo "Removing JDK9+ classes (Jmod and Link)"
+	rm "${S}"/src/main/org/apache/tools/ant/taskdefs/modules/{Jmod,Link}.java
+}
+
+src_compile() {
+	export ANT_HOME=""
+	# Avoid error message that package ant-core was not found
+	export ANT_TASKS="none"
+
+	local bsyscp
+
+	# This ensures that when building ant with bootstrapped ant,
+	# only the source is used for resolving references, and not
+	# the classes in bootstrapped ant but jikes in kaffe has issues with this...
+	if ! java-pkg_current-vm-matches kaffe; then
+		bsyscp="-Dbuild.sysclasspath=ignore"
+	fi
+
+	CLASSPATH="$(java-config -t)" ./build.sh ${bsyscp} jars dist-internal ||
+		die "build failed"
+
+	if use doc; then
+		# All Java packages imported by the source files need to present in
+		# the classpath, otherwise it would be https://bugs.gentoo.org/780531
+		local doc_deps=(
+			bcel
+			bsf-2.3
+			commons-logging
+			commons-net
+			jakarta-activation-api-1
+			jakarta-oro-2.0
+			jakarta-regexp-1.4
+			jdepend
+			jsch
+			log4j
+			oracle-javamail
+			sun-jai-bin
+			xalan
+			xml-commons-resolver
+			xz-java
+		)
+		for dep in "${doc_deps[@]}"; do
+			java-pkg_jar-from --build-only --into lib/optional/ "${dep}"
+		done
+		# This file imports netrexx.lang.Rexx, which is not available
+		# from ::gentoo.  Fortunately, there is not a dev-java/ant-*
+		# package for it, so even if we could generate documentation
+		# for it, it would be irrelevant
+		rm src/main/org/apache/tools/ant/taskdefs/optional/NetRexxC.java ||
+			die "Failed to remove Java source file blocking Javadoc generation"
+		./build.sh ${bsyscp} javadocs || die "Javadoc build failed"
+	fi
+}
+
+src_install() {
+	dodir /usr/share/ant/lib
+
+	for jar in ant.jar ant-bootstrap.jar ant-launcher.jar ; do
+		java-pkg_dojar build/lib/${jar}
+		dosym ../../${PN}/lib/${jar} /usr/share/ant/lib/${jar}
+	done
+
+	dobin src/script/ant
+
+	dodir /usr/share/${PN}/bin
+	for each in antRun antRun.pl runant.pl runant.py ; do
+		dobin "${S}/src/script/${each}"
+		dosym ../../../bin/${each} /usr/share/${PN}/bin/${each}
+	done
+	dosym ../${PN}/bin /usr/share/ant/bin
+
+	insinto /usr/share/${PN}
+	doins -r dist/etc
+	dosym ../${PN}/etc /usr/share/ant/etc
+
+	echo "ANT_HOME=\"${EPREFIX}/usr/share/ant\"" > "${T}/20ant"
+	doenvd "${T}/20ant"
+
+	dodoc NOTICE README WHATSNEW KEYS
+
+	if use doc; then
+		dodoc -r manual/*
+		java-pkg_dojavadoc --symlink manual/api build/javadocs
+	fi
+
+	use source && java-pkg_dosrc src/main/*
+}
diff --git a/dev-java/bcel/bcel-6.5.0-r2.ebuild b/dev-java/bcel/bcel-6.5.0-r2.ebuild
index 655c4ef3d8d2..7b3bf82feb05 100644
--- a/dev-java/bcel/bcel-6.5.0-r2.ebuild
+++ b/dev-java/bcel/bcel-6.5.0-r2.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 # Skeleton command:
@@ -13,7 +13,7 @@ JAVA_TESTING_FRAMEWORKS="junit-4"
 inherit java-pkg-2 java-pkg-simple
 
 DESCRIPTION="Apache Commons Bytecode Engineering Library"
-HOMEPAGE="https://commons.apache.org/proper/commons-bcel"
+HOMEPAGE="https://commons.apache.org/proper/commons-bcel/"
 SRC_URI="mirror://apache/commons/${PN}/source/${P}-src.tar.gz -> ${P}-sources.tar.gz"
 LICENSE="Apache-2.0"
 SLOT="0"
@@ -29,19 +29,13 @@ KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64
 
 DEPEND="
 	>=virtual/jdk-1.8:*
-	!arm? (
-		!arm64? (
-			!ppc64? (
-				test? (
-					dev-java/commons-collections:4
-					dev-java/commons-io:1
-					dev-java/commons-lang:3.6
-					dev-java/jna:4
-					dev-java/jmh-core:0
-					dev-java/oracle-javamail:0
-				)
-			)
-		)
+	test? (
+		dev-java/commons-collections:4
+		dev-java/commons-io:1
+		dev-java/commons-lang:3.6
+		dev-java/jna:4
+		dev-java/jmh-core:0
+		dev-java/oracle-javamail:0
 	)
 "
 
@@ -49,7 +43,7 @@ RDEPEND="
 	>=virtual/jre-1.8:*
 "
 
-RESTRICT="!test? ( test ) arm? ( test ) arm64? ( test ) ppc64? ( test )"
+RESTRICT="!test? ( test )"
 
 S="${WORKDIR}/${P}-src"
 
diff --git a/dev-java/commons-digester/Manifest b/dev-java/commons-digester/Manifest
index 4e92a56379d8..494d592f3dbf 100644
--- a/dev-java/commons-digester/Manifest
+++ b/dev-java/commons-digester/Manifest
@@ -1,3 +1,4 @@
 DIST commons-digester-1.8.1-src.tar.gz 303266 BLAKE2B 618885c812a9bf40c080bc5736b8b4be4e18fe4d2f732d2a44d39369ae6cf3beb3af0cf500da3d103d7aa8c18b41b84d06907b6fc90f7f10d30840d6cfc83012 SHA512 0a39069662b4792d4856b79b5cedc2b44cb70303a19045d21c233d45ae4dde9e80662bd242a381e759d7cdb5adaf0b9fa6206bb8397b53348fa9eac12e9a4e96
 DIST commons-digester-2.1-src.tar.gz 304060 BLAKE2B 2360f6f8ab77b20ad6b4058e0437aa792bf3886ddec2e09b6db259bc142c070965ce066ef224e92fb91614075631a2af1358ae4b4fc065fe9118e1d2559bb9bb SHA512 6bdb63431ed1e17f5e8ba24951762750a0e59b70c76eabecbf13f5fe6974864825456beed615c8f2c16f9a2f1404f2e56bdbc3ba335656c3661d5f368c708b88
+DIST commons-digester-3.2.tar.gz 324555 BLAKE2B 7b8bdaa70eeafb069e9ecbfe697ab86f5167ae3b9933e8aa306f0080de0ec99d12bd023067678b7b904329178f553fd6d4d98141ab329154a1c27385b33e449f SHA512 6d5ed9a1cc7612244747dcbd5c713349f27d63d1cef39fa368b4e91eaa3b1fe7043ab2fb498a73e8afde8081b8ff26a966e5b87b8b6dc68a3d907e9b25aa7cad
 DIST commons-digester3-3.2-src.tar.gz 324555 BLAKE2B 7b8bdaa70eeafb069e9ecbfe697ab86f5167ae3b9933e8aa306f0080de0ec99d12bd023067678b7b904329178f553fd6d4d98141ab329154a1c27385b33e449f SHA512 6d5ed9a1cc7612244747dcbd5c713349f27d63d1cef39fa368b4e91eaa3b1fe7043ab2fb498a73e8afde8081b8ff26a966e5b87b8b6dc68a3d907e9b25aa7cad
diff --git a/dev-java/commons-digester/commons-digester-3.2-r3.ebuild b/dev-java/commons-digester/commons-digester-3.2-r3.ebuild
new file mode 100644
index 000000000000..45e85fb373f2
--- /dev/null
+++ b/dev-java/commons-digester/commons-digester-3.2-r3.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# Skeleton command:
+# java-ebuilder --generate-ebuild --workdir . --pom pom.xml --download-uri mirror://apache/commons/digester/source/commons-digester3-3.2-src.tar.gz --slot 3.2 --keywords "~amd64 ~ppc64 ~x86" --ebuild commons-digester3.2-r3.ebuild
+
+EAPI=8
+
+JAVA_PKG_IUSE="doc source test"
+MAVEN_ID="org.apache.commons:commons-digester3:3.2"
+JAVA_TESTING_FRAMEWORKS="junit-4"
+
+inherit java-pkg-2 java-pkg-simple
+
+DESCRIPTION="Reads XML configuration files to provide initialization of various Java objects"
+HOMEPAGE="https://commons.apache.org/digester/"
+SRC_URI="mirror://apache/commons/digester/source/${PN}3-${PV}-src.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="3.2"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+
+# 1) atomWithNamespaceParse(org.apache.commons.digester3.xmlrules.SetNamespaceURITestCase)
+# java.net.UnknownHostException: commons.apache.org
+PROPERTIES="test_network"
+RESTRICT="test"
+
+# Common dependencies
+# POM: pom.xml
+# cglib:cglib:2.2.2 -> >=dev-java/cglib-3.3.0:3
+# commons-beanutils:commons-beanutils:1.8.3 -> >=dev-java/commons-beanutils-1.9.4:1.7
+# commons-logging:commons-logging:1.1.1 -> >=dev-java/commons-logging-1.2:0
+
+CP_DEPEND="
+	>=dev-java/cglib-3.3.0:3
+	>=dev-java/commons-beanutils-1.9.4:1.7
+	>=dev-java/commons-logging-1.2:0
+"
+
+DEPEND="${CP_DEPEND}
+	>=virtual/jdk-1.8:*"
+
+RDEPEND="${CP_DEPEND}
+	>=virtual/jre-1.8:*"
+
+DOCS=( {LICENSE,NOTICE,RELEASE-NOTES}.txt )
+
+S="${WORKDIR}/commons-digester3-${PV}-src"
+
+JAVA_ENCODING="iso-8859-1"
+
+JAVA_SRC_DIR="src/main/java"
+JAVA_RESOURCE_DIRS="src/main/resources"
+
+JAVA_TEST_GENTOO_CLASSPATH="junit-4"
+JAVA_TEST_SRC_DIR="src/test/java"
+JAVA_TEST_RESOURCE_DIRS="src/test/resources"
+
+src_test() {
+	pushd src/test/java || die
+		# Exclusions according to 226,229 pom.xml
+		local JAVA_TEST_RUN_ONLY=$(find * -name "*TestCase.java" ! -name "Abstract*.java" ! -name "TestBean.java" ! -name "TestRule.java" ! -name "TestRuleSet.java")
+		JAVA_TEST_RUN_ONLY="${JAVA_TEST_RUN_ONLY//.java}"
+		JAVA_TEST_RUN_ONLY="${JAVA_TEST_RUN_ONLY//\//.}"
+	popd
+
+	# Testing with java-17 throws too many test failures
+	local vm_version="$(java-config -g PROVIDES_VERSION)"
+	if [[ "${vm_version}" != "17" ]] ; then
+		java-pkg-simple_src_test
+	fi
+}
+
+src_install() {
+	default # https://bugs.gentoo.org/789582
+	java-pkg-simple_src_install
+}
diff --git a/dev-java/commons-digester/metadata.xml b/dev-java/commons-digester/metadata.xml
index e25b5c52aab3..8b75249cc7bf 100644
--- a/dev-java/commons-digester/metadata.xml
+++ b/dev-java/commons-digester/metadata.xml
@@ -5,6 +5,9 @@
   <email>java@gentoo.org</email>
   <name>Java</name>
  </maintainer>
+ <longdescription>
+		The Apache Commons Digester package lets you configure an XML to Java object mapping module which triggers certain actions called rules whenever a particular pattern of nested XML elements is recognized.
+	</longdescription>
  
  <origin>gentoo-staging</origin>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-java/cpptasks/cpptasks-1.0_beta5-r1.ebuild b/dev-java/cpptasks/cpptasks-1.0_beta5-r1.ebuild
index 0bb21854e881..d2302a4b865a 100644
--- a/dev-java/cpptasks/cpptasks-1.0_beta5-r1.ebuild
+++ b/dev-java/cpptasks/cpptasks-1.0_beta5-r1.ebuild
@@ -14,7 +14,7 @@ S="${WORKDIR}/${P/_beta/b}"
 
 LICENSE="Apache-2.0"
 SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
 
 CP_DEPEND="
 	dev-java/ant-core:0
diff --git a/dev-java/jakarta-regexp/jakarta-regexp-1.3-r5.ebuild b/dev-java/jakarta-regexp/jakarta-regexp-1.3-r5.ebuild
index 66acd6bea97c..f5a39f4ca7d2 100644
--- a/dev-java/jakarta-regexp/jakarta-regexp-1.3-r5.ebuild
+++ b/dev-java/jakarta-regexp/jakarta-regexp-1.3-r5.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=5
diff --git a/dev-java/jakarta-regexp/jakarta-regexp-1.3-r6.ebuild b/dev-java/jakarta-regexp/jakarta-regexp-1.3-r6.ebuild
new file mode 100644
index 000000000000..ab1d50e24403
--- /dev/null
+++ b/dev-java/jakarta-regexp/jakarta-regexp-1.3-r6.ebuild
@@ -0,0 +1,33 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+JAVA_PKG_IUSE="doc source"
+
+inherit java-pkg-2 java-pkg-simple
+
+DESCRIPTION="100% Pure Java Regular Expression package"
+SRC_URI="mirror://apache/jakarta/regexp/source/${P}.tar.gz"
+HOMEPAGE="https://jakarta.apache.org/"
+
+SLOT="${PV}"
+IUSE=""
+LICENSE="Apache-1.1"
+KEYWORDS="~amd64 ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-solaris"
+
+RDEPEND="
+	>=virtual/jre-1.8:*"
+
+DEPEND="
+	>=virtual/jdk-1.8:*"
+
+S="${WORKDIR}/${P}"
+
+JAVA_SRC_DIR="src/java"
+
+src_prepare() {
+	default
+
+	java-pkg_clean
+}
diff --git a/dev-java/jakarta-regexp/jakarta-regexp-1.4-r2.ebuild b/dev-java/jakarta-regexp/jakarta-regexp-1.4-r2.ebuild
index 66acd6bea97c..f5a39f4ca7d2 100644
--- a/dev-java/jakarta-regexp/jakarta-regexp-1.4-r2.ebuild
+++ b/dev-java/jakarta-regexp/jakarta-regexp-1.4-r2.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=5
diff --git a/dev-java/jakarta-regexp/jakarta-regexp-1.4-r3.ebuild b/dev-java/jakarta-regexp/jakarta-regexp-1.4-r3.ebuild
new file mode 100644
index 000000000000..db72332f033f
--- /dev/null
+++ b/dev-java/jakarta-regexp/jakarta-regexp-1.4-r3.ebuild
@@ -0,0 +1,32 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+JAVA_PKG_IUSE="doc source"
+
+inherit java-pkg-2 java-pkg-simple
+
+DESCRIPTION="100% Pure Java Regular Expression package"
+SRC_URI="mirror://apache/jakarta/regexp/source/${P}.tar.gz"
+HOMEPAGE="https://jakarta.apache.org/"
+
+SLOT="${PV}"
+IUSE=""
+LICENSE="Apache-1.1"
+KEYWORDS="~amd64 ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-solaris"
+
+RDEPEND="
+	>=virtual/jre-1.8:*"
+
+DEPEND="
+	>=virtual/jdk-1.8:*"
+
+S="${WORKDIR}/${P}"
+
+JAVA_SRC_DIR="src/java"
+
+src_prepare() {
+	default
+	java-pkg_clean
+}
diff --git a/dev-java/jakarta-regexp/jakarta-regexp-1.5-r1.ebuild b/dev-java/jakarta-regexp/jakarta-regexp-1.5-r1.ebuild
new file mode 100644
index 000000000000..db72332f033f
--- /dev/null
+++ b/dev-java/jakarta-regexp/jakarta-regexp-1.5-r1.ebuild
@@ -0,0 +1,32 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+JAVA_PKG_IUSE="doc source"
+
+inherit java-pkg-2 java-pkg-simple
+
+DESCRIPTION="100% Pure Java Regular Expression package"
+SRC_URI="mirror://apache/jakarta/regexp/source/${P}.tar.gz"
+HOMEPAGE="https://jakarta.apache.org/"
+
+SLOT="${PV}"
+IUSE=""
+LICENSE="Apache-1.1"
+KEYWORDS="~amd64 ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-solaris"
+
+RDEPEND="
+	>=virtual/jre-1.8:*"
+
+DEPEND="
+	>=virtual/jdk-1.8:*"
+
+S="${WORKDIR}/${P}"
+
+JAVA_SRC_DIR="src/java"
+
+src_prepare() {
+	default
+	java-pkg_clean
+}
diff --git a/dev-java/jakarta-regexp/jakarta-regexp-1.5.ebuild b/dev-java/jakarta-regexp/jakarta-regexp-1.5.ebuild
index 66acd6bea97c..f5a39f4ca7d2 100644
--- a/dev-java/jakarta-regexp/jakarta-regexp-1.5.ebuild
+++ b/dev-java/jakarta-regexp/jakarta-regexp-1.5.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=5
diff --git a/dev-java/jakarta-xml-soap-api/Manifest b/dev-java/jakarta-xml-soap-api/Manifest
new file mode 100644
index 000000000000..2ab2cfcfb034
--- /dev/null
+++ b/dev-java/jakarta-xml-soap-api/Manifest
@@ -0,0 +1 @@
+DIST jakarta-xml-soap-api-1.4.2.tar.gz 107226 BLAKE2B 4de5b994505d1964b6804010191b7b623322005d7bac6e9295062e821b5e0994a02d04f72d7f1bba9a8bf835ce42f455678af35c8cdf3e9e7208a2fde4151927 SHA512 9df8bb191fee0f6afa46f2d0c4bd5d1760324220be6862ff17df77d0dd4c9341360f18dd935233fdf6d9656d511c5378bd557e3dadd6570dfd3c9d7981179516
diff --git a/dev-java/jakarta-xml-soap-api/jakarta-xml-soap-api-1.4.2.ebuild b/dev-java/jakarta-xml-soap-api/jakarta-xml-soap-api-1.4.2.ebuild
new file mode 100644
index 000000000000..b22fd582fcc8
--- /dev/null
+++ b/dev-java/jakarta-xml-soap-api/jakarta-xml-soap-api-1.4.2.ebuild
@@ -0,0 +1,65 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# This version provides module java.xml.soap and package javax.xml.soap
+MAVEN_ID="jakarta.xml.soap:jakarta.xml.soap-api:1.4.2"
+
+JAVA_PKG_IUSE="doc source test"
+JAVA_TESTING_FRAMEWORKS="junit-4"
+
+inherit java-pkg-2 java-pkg-simple
+
+DESCRIPTION="SOAP with Attachments API for Java (SAAJ) API (Eclipse Project for JAX-WS)"
+HOMEPAGE="https://projects.eclipse.org/projects/ee4j.jaxws"
+SRC_URI="https://github.com/eclipse-ee4j/saaj-api/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+# EDL-1.0 equivalent to BSD
+# - 'SPDX-License-Identifier: BSD-3-Clause' in source files' headers
+# - https://www.eclipse.org/org/documents/edl-v10.php
+LICENSE="BSD"
+# Since version 2.0.0, the namespace has changed to jakarta.xml.soap
+SLOT="1"
+KEYWORDS="~amd64 ~x86"
+
+CP_DEPEND="
+	dev-java/jakarta-activation-api:1
+"
+
+DEPEND="
+	>=virtual/jdk-1.8:*
+	${CP_DEPEND}
+"
+
+RDEPEND="
+	>=virtual/jre-1.8:*
+	${CP_DEPEND}
+"
+
+S="${WORKDIR}/saaj-api-${PV}"
+
+JAVA_SRC_DIR="api/src/main/java"
+
+JAVA_TEST_GENTOO_CLASSPATH="junit-4"
+JAVA_TEST_SRC_DIR="api/src/test/java"
+JAVA_TEST_RESOURCE_DIRS=( "api/src/test/resources" )
+
+DOCS=( CONTRIBUTING.md NOTICE.md README.md )
+
+src_test() {
+	if ver_test "$(java-config -g PROVIDES_VERSION)" -lt 9; then
+		# https://github.com/javaee/javax.xml.soap/blob/1.4.0/pom.xml#L134-L143
+		JAVA_TEST_EXTRA_ARGS=( -Xbootclasspath/p:target/classes )
+	else
+		# '-Xbootclasspath/p' removed since JDK 9; '-Xbootclasspath/a' remains
+		# https://openjdk.java.net/jeps/261
+		JAVA_TEST_EXTRA_ARGS=( -Xbootclasspath/a:target/classes )
+	fi
+	java-pkg-simple_src_test
+}
+
+src_install() {
+	java-pkg-simple_src_install
+	einstalldocs # https://bugs.gentoo.org/789582
+}
diff --git a/dev-java/jakarta-xml-soap-api/metadata.xml b/dev-java/jakarta-xml-soap-api/metadata.xml
new file mode 100644
index 000000000000..e25b5c52aab3
--- /dev/null
+++ b/dev-java/jakarta-xml-soap-api/metadata.xml
@@ -0,0 +1,10 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
+<pkgmetadata>
+ <maintainer type="project">
+  <email>java@gentoo.org</email>
+  <name>Java</name>
+ </maintainer>
+ 
+ <origin>gentoo-staging</origin>
+</pkgmetadata>
\ No newline at end of file
diff --git a/dev-java/jansi/jansi-2.4.0.ebuild b/dev-java/jansi/jansi-2.4.0-r1.ebuild
index e93adc8efc55..75e764ffdbfd 100644
--- a/dev-java/jansi/jansi-2.4.0.ebuild
+++ b/dev-java/jansi/jansi-2.4.0-r1.ebuild
@@ -61,7 +61,7 @@ src_compile() {
 	# build native library.
 	local args=(
 		CCFLAGS="${CFLAGS} ${CXXFLAGS} -Os -fPIC -fvisibility=hidden"
-		LINKFLAGS="-shared"
+		LINKFLAGS="-shared ${LDFLAGS}"
 		CC="$(tc-getCC)"
 		STRIP="$(tc-getSTRIP)"
 		LIBNAME="libjansi-$(ver_cut 1-2).so"
diff --git a/dev-java/jmh-core/jmh-core-1.21.ebuild b/dev-java/jmh-core/jmh-core-1.21.ebuild
index 42c501e08dd6..9f129de1d64b 100644
--- a/dev-java/jmh-core/jmh-core-1.21.ebuild
+++ b/dev-java/jmh-core/jmh-core-1.21.ebuild
@@ -16,7 +16,7 @@ HOMEPAGE="https://openjdk.java.net/projects/code-tools/jmh"
 SRC_URI="https://hg.openjdk.java.net/code-tools/${MY_PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
 LICENSE="Apache-2.0"
 SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
 
 # jopt *must* be 4.6, see https://mail.openjdk.java.net/pipermail/jmh-dev/2016-October/002395.html
 CP_DEPEND="
diff --git a/dev-java/sac/sac-1.3-r4.ebuild b/dev-java/sac/sac-1.3-r4.ebuild
index 3ce936aea711..53e08b765c02 100644
--- a/dev-java/sac/sac-1.3-r4.ebuild
+++ b/dev-java/sac/sac-1.3-r4.ebuild
@@ -14,7 +14,7 @@ SRC_URI="https://www.w3.org/2002/06/sacjava-${PV}.zip -> ${P}.zip"
 
 LICENSE="W3C"
 SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
 
 DEPEND="
 	app-arch/zip
diff --git a/dev-java/xmlunit/xmlunit-1.6-r1.ebuild b/dev-java/xmlunit/xmlunit-1.6-r1.ebuild
new file mode 100644
index 000000000000..c285e2891c96
--- /dev/null
+++ b/dev-java/xmlunit/xmlunit-1.6-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+JAVA_PKG_IUSE="doc source test"
+MAVEN_ID="xmlunit:xmlunit:1.6"
+
+inherit java-pkg-2 java-ant-2
+
+DESCRIPTION="XMLUnit extends JUnit and NUnit to enable unit testing of XML"
+SRC_URI="mirror://sourceforge/${PN}/${P}-src.zip"
+HOMEPAGE="http://xmlunit.sourceforge.net/"
+
+LICENSE="BSD"
+SLOT="1"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+
+CDEPEND="dev-java/junit:0"
+
+DEPEND=">=virtual/jdk-1.8:*
+	app-arch/unzip:0
+	doc? ( app-text/docbook-xsl-stylesheets:0 )
+	test? (
+		dev-java/ant-junit:0
+		dev-java/ant-core:0
+	)
+	${CDEPEND}"
+
+RDEPEND=">=virtual/jre-1.8:*
+	${CDEPEND}"
+
+JAVA_ANT_REWRITE_CLASSPATH="true"
+EANT_GENTOO_CLASSPATH="junit"
+
+EANT_DOC_TARGET="users-guide-html javadocs"
+EANT_ANT_TASKS="ant-core"
+EANT_EXTRA_ARGS="-Ddb5.xsl=/usr/share/sgml/docbook/xsl-stylesheets"
+
+src_test() {
+	ANT_TASKS="ant-junit ant-core" eant test
+}
+
+src_install() {
+	java-pkg_newjar "build/lib/${P}.jar"
+
+	dodoc README.txt
+
+	if use doc; then
+		java-pkg_dojavadoc build/doc/api
+		docinto html
+		dodoc -r build/doc/userguide/html/
+	fi
+
+	use source && java-pkg_dosrc src/java/org
+}