Adding metadata

10 files changed, 293 insertions, 8 deletions

diff --git a/dev-java/aopalliance/aopalliance-1.0-r3.ebuild b/dev-java/aopalliance/aopalliance-1.0-r3.ebuild
new file mode 100644
index 000000000000..bff2fa46d712
--- /dev/null
+++ b/dev-java/aopalliance/aopalliance-1.0-r3.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+JAVA_PKG_IUSE="doc source"
+
+inherit java-pkg-2 java-pkg-simple
+
+DESCRIPTION="Aspect-Oriented Programming (AOP) Alliance classes"
+SRC_URI="mirror://gentoo/${P}-gentoo.tar.bz2"
+#SRC_URI="mirror://gentoo/${P}.tar.bz2"
+# Tarball creation:
+# cvs -d:pserver:anonymous@aopalliance.cvs.sourceforge.net:/cvsroot/aopalliance login
+# cvs -z3 -d:pserver:anonymous@aopalliance.cvs.sourceforge.net:/cvsroot/aopalliance export -r interception_1_0 aopalliance
+# tar cjvf aopalliance-1.0-gentoo.tar.bz2 aopalliance
+HOMEPAGE="http://aopalliance.sourceforge.net/"
+LICENSE="public-domain"
+SLOT="1"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86 ~amd64-linux"
+
+IUSE=""
+
+DEPEND=">=virtual/jdk-1.8:*"
+RDEPEND=">=virtual/jre-1.8:*"
+
+S="${WORKDIR}/${P}"
+
+JAVA_SRC_DIR="src/main"
+
+src_prepare() {
+	default
+
+	rm build.xml || die
+}
diff --git a/dev-java/jackrabbit-webdav/files/jackrabbit-webdav-2.10.1-CSRFUtilTest.java.patch b/dev-java/jackrabbit-webdav/files/jackrabbit-webdav-2.10.1-CSRFUtilTest.java.patch
index 4c1f286339b8..8417f31cfceb 100644
--- a/dev-java/jackrabbit-webdav/files/jackrabbit-webdav-2.10.1-CSRFUtilTest.java.patch
+++ b/dev-java/jackrabbit-webdav/files/jackrabbit-webdav-2.10.1-CSRFUtilTest.java.patch
@@ -1,5 +1,5 @@
---- src/test/java/org/apache/jackrabbit/webdav/util/CSRFUtilTest.java.orig	2015-07-03 09:36:45.804000000 +0000
-+++ src/test/java/org/apache/jackrabbit/webdav/util/CSRFUtilTest.java	2015-07-03 09:36:59.498000000 +0000
+--- a/src/test/java/org/apache/jackrabbit/webdav/util/CSRFUtilTest.java.orig	2015-07-03 09:36:45.804000000 +0000
++++ b/src/test/java/org/apache/jackrabbit/webdav/util/CSRFUtilTest.java	2015-07-03 09:36:59.498000000 +0000
 @@ -281,6 +281,18 @@
          public void removeAttribute(String name) {
  
diff --git a/dev-java/jackrabbit-webdav/files/jackrabbit-webdav-2.10.1-OutputContextImplTest.java.patch b/dev-java/jackrabbit-webdav/files/jackrabbit-webdav-2.10.1-OutputContextImplTest.java.patch
index d9a2315f19a1..9f132b817a12 100644
--- a/dev-java/jackrabbit-webdav/files/jackrabbit-webdav-2.10.1-OutputContextImplTest.java.patch
+++ b/dev-java/jackrabbit-webdav/files/jackrabbit-webdav-2.10.1-OutputContextImplTest.java.patch
@@ -1,5 +1,5 @@
---- src/test/java/org/apache/jackrabbit/webdav/io/OutputContextImplTest.java.orig	2015-07-03 09:26:48.578000000 +0000
-+++ src/test/java/org/apache/jackrabbit/webdav/io/OutputContextImplTest.java	2015-07-03 09:27:34.109000000 +0000
+--- a/src/test/java/org/apache/jackrabbit/webdav/io/OutputContextImplTest.java.orig	2015-07-03 09:26:48.578000000 +0000
++++ b/src/test/java/org/apache/jackrabbit/webdav/io/OutputContextImplTest.java	2015-07-03 09:27:34.109000000 +0000
 @@ -40,6 +40,13 @@
              public void setHeader(String name, String value) {
                  assertTrue(Long.parseLong(value) > Integer.MAX_VALUE);
diff --git a/dev-java/jackrabbit-webdav/jackrabbit-webdav-2.10.1-r1.ebuild b/dev-java/jackrabbit-webdav/jackrabbit-webdav-2.10.1-r1.ebuild
new file mode 100644
index 000000000000..e516aeb4f488
--- /dev/null
+++ b/dev-java/jackrabbit-webdav/jackrabbit-webdav-2.10.1-r1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+JAVA_PKG_IUSE="doc test"
+
+inherit java-pkg-2 java-ant-2
+
+MY_PN="${PN/-*/}"
+
+DESCRIPTION="Fully conforming implementation of the JRC API (specified in JSR 170 and 283)"
+HOMEPAGE="http://jackrabbit.apache.org/"
+SRC_URI="mirror://apache/${MY_PN}/${PV}/${MY_PN}-${PV}-src.zip"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+
+S="${WORKDIR}/${MY_PN}-${PV}/${PN}"
+
+CDEPEND="dev-java/bndlib:0
+	dev-java/slf4j-api:0
+	dev-java/slf4j-nop:0
+	dev-java/commons-httpclient:3
+	java-virtuals/servlet-api:2.3"
+
+DEPEND=">=virtual/jdk-1.8:*
+	${CDEPEND}
+	test? ( dev-java/ant-junit:0 )"
+
+RDEPEND=">=virtual/jre-1.8:*
+	${CDEPEND}"
+
+BDEPEND="app-arch/unzip"
+
+JAVA_ANT_REWRITE_CLASSPATH="true"
+EANT_GENTOO_CLASSPATH="
+	bndlib
+	commons-httpclient-3
+	servlet-api-2.3
+	slf4j-api
+"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-OutputContextImplTest.java.patch
+	"${FILESDIR}"/${P}-CSRFUtilTest.java.patch
+)
+
+src_prepare() {
+	default
+
+	cp "${FILESDIR}"/${P}-build.xml build.xml || die
+}
+
+EANT_TEST_GENTOO_CLASSPATH="
+	${EANT_GENTOO_CLASSPATH}
+	slf4j-nop
+"
+src_test() {
+	java-pkg-2_src_test
+}
+
+src_install() {
+	java-pkg_newjar target/${P}.jar
+
+	use doc && java-pkg_dojavadoc target/site/apidocs
+}
diff --git a/dev-java/jackrabbit-webdav/jackrabbit-webdav-2.10.1.ebuild b/dev-java/jackrabbit-webdav/jackrabbit-webdav-2.10.1.ebuild
index 1c182599a97d..2f95946aa570 100644
--- a/dev-java/jackrabbit-webdav/jackrabbit-webdav-2.10.1.ebuild
+++ b/dev-java/jackrabbit-webdav/jackrabbit-webdav-2.10.1.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI="5"
@@ -25,7 +25,8 @@ CDEPEND="dev-java/bndlib:0
 	dev-java/commons-httpclient:3
 	java-virtuals/servlet-api:2.3"
 
-DEPEND=">=virtual/jdk-1.6
+DEPEND="app-arch/unzip
+	>=virtual/jdk-1.6
 	${CDEPEND}
 	test? ( dev-java/ant-junit:0 )"
 
diff --git a/dev-java/javacc/javacc-5.0-r4.ebuild b/dev-java/javacc/javacc-5.0-r4.ebuild
new file mode 100644
index 000000000000..dac3ebd544ec
--- /dev/null
+++ b/dev-java/javacc/javacc-5.0-r4.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+JAVA_PKG_IUSE="doc examples source test"
+
+inherit java-pkg-2 java-ant-2
+
+DESCRIPTION="Java Compiler Compiler - The Java Parser Generator"
+HOMEPAGE="https://javacc.java.net/"
+SRC_URI="http://java.net/projects/${PN}/downloads/download/${P}src.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+
+CDEPEND="dev-java/junit:0"
+
+RDEPEND="
+	${CDEPEND}
+	>=virtual/jre-1.8:*"
+
+DEPEND="
+	${CDEPEND}
+	>=virtual/jdk-1.8:*
+	test? (	dev-java/ant-junit:0 )"
+
+S="${WORKDIR}/${PN}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.0-javadoc.patch
+)
+
+JAVA_ANT_REWRITE_CLASSPATH="yes"
+JAVA_ANT_CLASSPATH_TAGS+=" javadoc"
+
+EANT_GENTOO_CLASSPATH="junit"
+
+src_prepare() {
+	default
+
+	rm -v lib/junit*/*.jar || die
+}
+
+src_test() {
+	java-pkg-2_src_test
+}
+
+src_install() {
+	java-pkg_dojar "bin/lib/${PN}.jar"
+
+	if use doc; then
+		java-pkg_dohtml -r www/*
+		java-pkg_dojavadoc doc/api
+	fi
+
+	use examples && java-pkg_doexamples examples
+	use source && java-pkg_dosrc src/*
+
+	echo "JAVACC_HOME=${EPREFIX}/usr/share/javacc/" > "${T}"/22javacc || die
+	doenvd "${T}"/22javacc
+
+	echo "export VERSION=${PV}" > "${T}"/pre || die
+
+	local launcher
+	for launcher in javacc jjdoc jjtree; do
+		java-pkg_dolauncher ${launcher} -pre "${T}"/pre --main ${launcher}
+	done
+
+	einstalldocs
+}
diff --git a/dev-java/javax-inject/javax-inject-1-r4.ebuild b/dev-java/javax-inject/javax-inject-1-r4.ebuild
new file mode 100644
index 000000000000..ca8a987e59c9
--- /dev/null
+++ b/dev-java/javax-inject/javax-inject-1-r4.ebuild
@@ -0,0 +1,22 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+JAVA_PKG_IUSE="doc source"
+
+inherit java-pkg-2 java-pkg-simple
+
+MY_PN="${PN/-/.}"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Dependency injection for Java (JSR-330)"
+HOMEPAGE="https://github.com/matlach/atinject"
+SRC_URI="http://central.maven.org/maven2/javax/inject/${MY_PN}/${PV}/${MY_P}-sources.jar -> ${P}.jar"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86 ~amd64-linux"
+
+RDEPEND=">=virtual/jre-1.8:*"
+DEPEND=">=virtual/jdk-1.8:*"
diff --git a/dev-java/jcommander/jcommander-1.48-r1.ebuild b/dev-java/jcommander/jcommander-1.48-r1.ebuild
new file mode 100644
index 000000000000..a6f99b1114f2
--- /dev/null
+++ b/dev-java/jcommander/jcommander-1.48-r1.ebuild
@@ -0,0 +1,29 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+JAVA_PKG_IUSE="doc source"
+
+inherit java-pkg-2 java-pkg-simple
+
+DESCRIPTION="Command line parsing framework for Java"
+HOMEPAGE="https://github.com/cbeust/jcommander"
+SRC_URI="https://github.com/cbeust/${PN}/archive/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+
+DEPEND=">=virtual/jdk-1.8:*"
+RDEPEND=">=virtual/jre-1.8:*"
+
+S="${WORKDIR}/${PN}-${P}"
+
+RESTRICT="test"
+
+src_prepare() {
+	default
+
+	rm -rf src/test || die
+}
diff --git a/dev-java/jsch/jsch-0.1.54-r1.ebuild b/dev-java/jsch/jsch-0.1.54-r1.ebuild
new file mode 100644
index 000000000000..dbfdef7fbabc
--- /dev/null
+++ b/dev-java/jsch/jsch-0.1.54-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+JAVA_PKG_IUSE="doc source examples"
+MAVEN_ID="com.jcraft:jsch:0.1.55"
+
+inherit java-pkg-2 java-ant-2 java-osgi
+
+DESCRIPTION="JSch is a pure Java implementation of SSH2"
+HOMEPAGE="http://www.jcraft.com/jsch/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.zip"
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="zlib"
+
+CDEPEND="
+	zlib? ( dev-java/jzlib:0 )"
+
+RDEPEND="
+	${CDEPEND}
+	>=virtual/jre-1.8:*"
+
+DEPEND="
+	${CDEPEND}
+	>=virtual/jdk-1.8:*"
+
+BDEPEND="
+	app-arch/unzip
+"
+
+EANT_BUILD_TARGET="dist"
+JAVA_ANT_REWRITE_CLASSPATH="true"
+
+src_compile() {
+	if use zlib; then
+		EANT_EXTRA_ARGS="-Djzlib.available=true"
+		EANT_GENTOO_CLASSPATH="jzlib"
+	fi
+
+	java-pkg-2_src_compile
+}
+
+src_install() {
+	java-osgi_newjar dist/lib/jsch*.jar \
+		"com.jcraft.jsch" "JSch" \
+		"com.jcraft.jsch, com.jcraft.jsch.jce;x-internal:=true, \
+		com.jcraft.jsch.jcraft;x-internal:=true"
+
+	einstalldocs
+	use doc && java-pkg_dojavadoc javadoc
+	use source && java-pkg_dosrc src/*
+	use examples && java-pkg_doexamples examples
+}
diff --git a/dev-java/mill-bin/mill-bin-0.9.10.ebuild b/dev-java/mill-bin/mill-bin-0.9.10.ebuild
index abd33534fe99..bface58632d1 100644
--- a/dev-java/mill-bin/mill-bin-0.9.10.ebuild
+++ b/dev-java/mill-bin/mill-bin-0.9.10.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -8,7 +8,7 @@ MY_PN=${PN%-bin}
 DESCRIPTION="A Java/Scala build tool"
 HOMEPAGE="https://com-lihaoyi.github.io/mill/"
 SRC_URI="https://github.com/com-lihaoyi/${MY_PN}/releases/download/${PV}/${PV}-assembly"
-KEYWORDS="~amd64 ~x86"
+KEYWORDS="amd64 ~x86"
 
 LICENSE="MIT"
 SLOT="0"