Adding metadata

7 files changed, 172 insertions, 86 deletions

diff --git a/dev-java/avalon-logkit/avalon-logkit-2.1-r12.ebuild b/dev-java/avalon-logkit/avalon-logkit-2.1-r12.ebuild
new file mode 100644
index 000000000000..fadec3b6862a
--- /dev/null
+++ b/dev-java/avalon-logkit/avalon-logkit-2.1-r12.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+JAVA_PKG_IUSE="doc source test"
+
+inherit java-pkg-2 java-ant-2
+
+# NB: this project is dead and we should look into removing it from the tree.
+# Take a look at the homepage.
+# As of February 2022, dev-java/commons-logging is the only consumer of this
+# package besides dev-java/avalon-framework.  However, commons-logging is still
+# used by many other consumers and does not have an updated version that do not
+# depend on this package.
+DESCRIPTION="Easy-to-use Java logging toolkit"
+HOMEPAGE="https://avalon.apache.org/closed.html"
+SRC_URI="https://archive.apache.org/dist/excalibur/avalon-logkit/source/avalon-logkit-${PV}-src.tar.gz"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~sparc-solaris ~x86-solaris"
+LICENSE="Apache-2.0"
+SLOT="2.0"
+
+CP_DEPEND="
+	dev-java/javax-mail:0
+	dev-java/jboss-jms-api:1.1
+	dev-java/log4j-12-api:2
+	java-virtuals/servlet-api:3.0"
+RDEPEND="${CP_DEPEND}
+	>=virtual/jre-1.8:*"
+DEPEND="${CP_DEPEND}
+	>=virtual/jdk-1.8:*
+	test? (
+		dev-java/ant-junit:0
+	)"
+
+src_prepare() {
+	default
+
+	# Unfortunately, LogFactor5 support is no longer provided by the Log4j 1.x
+	# bridge in Log4j 2.  But it seems that LogFactor5 merely consists of a
+	# Swing-based GUI that is neither checked by this package's tests nor used
+	# by reverse dependencies in ::gentoo.  If virtually nobody would use
+	# LogFactor5, components in this package pertaining to it could be simply
+	# removed to make the migration to Log4j 2 feasible.
+	# http://people.apache.org/~carnold/log4j/docs/x/logging-log4j-1.2.10/docs/lf5/overview.html
+	rm -rv src/java/org/apache/log/output/lf5 ||
+		die "Failed to remove support for stale LogFactor5 project"
+
+	# Doesn't like 1.6 / 1.7 changes to JDBC
+	eapply "${FILESDIR}/${P}-java7.patch"
+
+	java-ant_ignore-system-classes
+
+	java-ant_xml-rewrite \
+		-f build.xml \
+		-c -e available \
+		-a classpathref \
+		-v 'build.classpath' || die
+
+	java-pkg_filter-compiler jikes
+}
+
+JAVA_ANT_REWRITE_CLASSPATH="yes"
+JAVA_ANT_ENCODING="UTF-8"
+
+src_test() {
+	java-pkg-2_src_test
+}
+
+src_install() {
+	java-pkg_newjar "target/${P}.jar"
+	use doc && java-pkg_dojavadoc dist/docs/api
+	use source && java-pkg_dosrc src/java/*
+}
+
+pkg_postinst() {
+	# Display a message about LogFactor5 support drop upon first install
+	# or upgrade from a version before the drop
+	local changed_ver="2.1-r11"
+	local should_show_msg replaced_ver
+	[[ -z "${REPLACING_VERSIONS}" ]] && should_show_msg=1 # First install
+	for replaced_ver in ${REPLACING_VERSIONS}; do
+		if ver_test "${replaced_ver}" -lt "${changed_ver}"; then
+			should_show_msg=1
+			break
+		fi
+	done
+	[[ "${should_show_msg}" ]] || return
+	ewarn "Due to migration to Log4j 2, this package has to drop LogFactor5"
+	ewarn "support. As a result, the org.apache.log.output.lf5 Java package"
+	ewarn "is not available in the JAR installed by this package."
+}
diff --git a/dev-java/commons-logging/commons-logging-1.2-r4.ebuild b/dev-java/commons-logging/commons-logging-1.2-r5.ebuild
index d32f9e36c65e..f93740de50e1 100644
--- a/dev-java/commons-logging/commons-logging-1.2-r4.ebuild
+++ b/dev-java/commons-logging/commons-logging-1.2-r5.ebuild
@@ -14,7 +14,7 @@ SRC_URI="mirror://apache/commons/logging/source/${P}-src.tar.gz"
 
 LICENSE="Apache-2.0"
 SLOT="0"
-KEYWORDS="~amd64 ~arm ~ppc64 ~x86"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
 IUSE="avalon-framework avalon-logkit log4j servletapi test"
 REQUIRED_USE="doc? ( avalon-framework avalon-logkit log4j servletapi )"
 RESTRICT="!test? ( test ) !servletapi? ( test )"
@@ -22,7 +22,11 @@ RESTRICT="!test? ( test ) !servletapi? ( test )"
 CDEPEND="
 	avalon-logkit? ( dev-java/avalon-logkit:2.0 )
 	avalon-framework? ( dev-java/avalon-framework:4.2 )
-	log4j? ( dev-java/log4j-12-api:2 )
+	log4j? (
+		dev-java/log4j-12-api:2
+		dev-java/log4j-api:2
+		dev-java/log4j-core:2
+	)
 	servletapi? ( dev-java/tomcat-servlet-api:4.0 )"
 
 RDEPEND="
@@ -38,7 +42,6 @@ S="${WORKDIR}/${P}-src"
 
 EANT_BUILD_TARGET="compile"
 JAVA_ANT_REWRITE_CLASSPATH="yes"
-JAVA_ANT_CLASSPATH_TAGS="javac javadoc"
 JAVA_ANT_IGNORE_SYSTEM_CLASSES="yes"
 
 DOCS=( RELEASE-NOTES.txt PROPOSAL.html )
@@ -55,20 +58,41 @@ src_prepare() {
 
 	if use avalon-framework; then
 		echo "avalon-framework.jar=$(java-pkg_getjars avalon-framework-4.2)" >> build.properties || die
-		EANT_GENTOO_CLASSPATH+=" avalon-framework-4.2"
 	fi
 	if use avalon-logkit; then
 		echo "logkit.jar=$(java-pkg_getjars avalon-logkit-2.0)" >> build.properties || die
-		EANT_GENTOO_CLASSPATH+=" avalon-logkit-2.0"
 	fi
 	if use log4j; then
-		echo "log4j12.jar=$(java-pkg_getjars log4j-12-api-2,log4j-core-2)" >> build.properties || die
-		EANT_GENTOO_CLASSPATH+=" log4j-12-api-2 log4j-core-2"
+		# log4j12.jar can only contain path to one single file because
+		# build.xml decides whether the Log4JLogger should be built with
+		# <available file="${log4j12.jar}" property="log4j12.present"/>,
+		# and a value that contains multiple file paths will cause the
+		# test to return a negative result.  However, classes from multiple
+		# Log4j 2 JARs are needed to compile the sources.  So, we combine
+		# them into a single JAR on the go.
+		# https://bugs.gentoo.org/834036
+		mkdir -p "${T}/log4j-2" ||
+			die "Failed to create temporary directory for Log4j 2 classes"
+		pushd "${T}/log4j-2" > /dev/null ||
+			die "Failed to enter temporary directory for Log4j 2 classes"
+
+		local jar="$(java-config -j)"
+		local dep
+		for dep in log4j-{12-api,api,core}; do
+			# Assuming SLOT="2" for Log4j 2 dependencies
+			"${jar}" -xf "$(java-pkg_getjar "${dep}-2" "${dep}.jar")" ||
+				die "Failed to extract files from ${dep}-2 installed on system"
+		done
+		"${jar}" -cf log4j-2.jar . || die "Failed to create JAR for Log4j"
+
+		popd > /dev/null ||
+			die "Failed to leave temporary directory for Log4j 2 classes"
+
+		echo "log4j12.jar=${T}/log4j-2/log4j-2.jar" >> build.properties || die
 	fi
 
 	if use servletapi; then
 		echo "servletapi.jar=$(java-pkg_getjar tomcat-servlet-api-4.0 servlet-api.jar)" >> build.properties || die
-		EANT_GENTOO_CLASSPATH+=" tomcat-servlet-api-4.0"
 	fi
 }
 
@@ -84,5 +108,15 @@ src_install() {
 }
 
 src_test() {
+	# Do not run Log4j tests because these tests use an Appender to verify
+	# logging correctness.  The log4j-12-api bridge no longer supports using an
+	# Appender for verifications since the methods for adding an Appender in
+	# the bridge "are largely no-ops".  This means an Appender's state would
+	# never be changed by log4j-12-api after new messages are logged.  The test
+	# cases, however, expect changes to the Appender's state in such an event,
+	# so they would fail with log4j-12-api.
+	# https://logging.apache.org/log4j/log4j-2.8/log4j-1.2-api/index.html
+	sed -i -e "/^log4j12\.jar=/d" build.properties ||
+		die "Failed to skip Log4j tests by modifying build.properties"
 	java-pkg-2_src_test
 }
diff --git a/dev-java/jakarta-xml-soap-api/jakarta-xml-soap-api-1.4.2.ebuild b/dev-java/jakarta-xml-soap-api/jakarta-xml-soap-api-1.4.2.ebuild
index 0161ba9419d0..c93feda39bca 100644
--- a/dev-java/jakarta-xml-soap-api/jakarta-xml-soap-api-1.4.2.ebuild
+++ b/dev-java/jakarta-xml-soap-api/jakarta-xml-soap-api-1.4.2.ebuild
@@ -21,7 +21,7 @@ SRC_URI="https://github.com/eclipse-ee4j/saaj-api/archive/refs/tags/${PV}.tar.gz
 LICENSE="BSD"
 # Since version 2.0.0, the namespace has changed to jakarta.xml.soap
 SLOT="1"
-KEYWORDS="amd64 ~arm x86"
+KEYWORDS="amd64 ~arm ~arm64 ~ppc64 x86"
 
 CP_DEPEND="
 	dev-java/jakarta-activation-api:1
diff --git a/dev-java/netty-common/netty-common-4.0.36-r2.ebuild b/dev-java/netty-common/netty-common-4.0.36-r2.ebuild
index a2a67091ff28..9536f39175b8 100644
--- a/dev-java/netty-common/netty-common-4.0.36-r2.ebuild
+++ b/dev-java/netty-common/netty-common-4.0.36-r2.ebuild
@@ -15,7 +15,7 @@ SRC_URI="https://github.com/${MY_PN}/${MY_PN}/archive/${MY_P}.Final.tar.gz"
 
 LICENSE="Apache-2.0"
 SLOT="0"
-KEYWORDS="~amd64 ~arm ~ppc64 ~x86"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
 IUSE="test"
 
 # Same test failures as before the revbumps still occur. See https://bugs.gentoo.org/827221
diff --git a/dev-java/xmlgraphics-commons/Manifest b/dev-java/xmlgraphics-commons/Manifest
index d20afdb1919b..ee6793181490 100644
--- a/dev-java/xmlgraphics-commons/Manifest
+++ b/dev-java/xmlgraphics-commons/Manifest
@@ -1,2 +1 @@
-DIST xmlgraphics-commons-2.6-src.tar.gz 2718577 BLAKE2B 7be3565d2224adcb1a804a089f6f52810852117a7c13129822bd1a9f27f7c10abf186b5b7d703c0351ef76d50ddb741fae65094af35d2037044ad56220989dfe SHA512 bdf7fb21d076ba722648da016b0686ed3ea6f56b8ba1a8cea34b517095bf91ff900a937e45aba0977389ab736b1815a5733908ad4242911246555dce61cf4cfd
 DIST xmlgraphics-commons-2.7-src.tar.gz 2021218 BLAKE2B a16dda389662a38d5ebf6cbd015ac5bf8154b5e2df9e36fd3a33987b04a4de08cc1ebc71e940c05793ef045249c68e7dbb54c418a7c6888020a800e039b0a188 SHA512 7d3993fc920767512f94edef3342757f0ffc9c9dbad80695fe3d77b0ec162380d9b467682ae41238e7ee719601709edb41b2dab06c385dfd9fa898577d8d2c22
diff --git a/dev-java/xmlgraphics-commons/xmlgraphics-commons-2.6.ebuild b/dev-java/xmlgraphics-commons/xmlgraphics-commons-2.6.ebuild
deleted file mode 100644
index b0f4e8365620..000000000000
--- a/dev-java/xmlgraphics-commons/xmlgraphics-commons-2.6.ebuild
+++ /dev/null
@@ -1,75 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-# Skeleton command:
-# java-ebuilder --generate-ebuild --workdir . --pom /var/tmp/portage/dev-java/xmlgraphics-commons-2.6/work/xmlgraphics-commons-2.6/pom.xml --download-uri mirror://apache/xmlgraphics/commons/source/2.6-src.tar.gz --slot 2 --keywords "~amd64 ~arm64 ~ppc64 ~x86" --ebuild xmlgraphics-commons-2.6.ebuild
-
-EAPI=7
-
-JAVA_PKG_IUSE="doc source test"
-MAVEN_ID="org.apache.xmlgraphics:xmlgraphics-commons:2.6"
-JAVA_TESTING_FRAMEWORKS="junit-4"
-
-inherit java-pkg-2 java-pkg-simple
-
-DESCRIPTION="XML Graphics Commons"
-HOMEPAGE="https://xmlgraphics.apache.org/commons/"
-SRC_URI="mirror://apache/xmlgraphics/commons/source/${P}-src.tar.gz"
-
-LICENSE="Apache-2.0"
-SLOT="2"
-KEYWORDS="amd64 ~arm64 ppc64 x86"
-
-# Common dependencies
-# POM: /var/tmp/portage/dev-java/${P}/work/${P}/pom.xml
-# commons-io:commons-io:1.3.2 -> >=dev-java/commons-io-2.8.0:1
-# commons-logging:commons-logging:1.2 -> >=dev-java/commons-logging-1.2:0
-
-CDEPEND="
-	dev-java/commons-io:1
-	dev-java/commons-logging:0
-"
-
-# Compile dependencies
-# POM: /var/tmp/portage/dev-java/${P}/work/${P}/pom.xml
-# test? junit:junit:4.11 -> >=dev-java/junit-4.13.2:4
-# test? org.mockito:mockito-core:1.8.5 -> >=dev-java/mockito-1.9.5:0
-# test? xml-resolver:xml-resolver:1.2 -> >=dev-java/xml-commons-resolver-1.2:0
-
-DEPEND="${CDEPEND}
-	>=virtual/jdk-1.8:*
-	test? (
-		dev-java/mockito:0
-		dev-java/xml-commons-resolver:0
-	)
-"
-
-RDEPEND="${CDEPEND}
-	>=virtual/jre-1.8:*
-"
-
-DOCS=( LICENSE NOTICE README )
-
-S="${WORKDIR}/${P}"
-
-JAVA_GENTOO_CLASSPATH="commons-io-1,commons-logging"
-JAVA_SRC_DIR="src/main/java"
-JAVA_RESOURCE_DIRS="src/main/resources"
-
-JAVA_TEST_GENTOO_CLASSPATH="junit-4,mockito,xml-commons-resolver"
-JAVA_TEST_SRC_DIR="src/test/java"
-JAVA_TEST_RESOURCE_DIRS="src/test/resources"
-
-# Tests run: 189,  Failures: 12
-JAVA_TEST_EXCLUDES=(
-	"org.apache.xmlgraphics.xmp.XMPParserTestCase"
-	"org.apache.xmlgraphics.image.codec.tiff.TIFFImageEncoderTestCase"
-	"org.apache.xmlgraphics.image.loader.impl.ImageLoaderImageIOTestCase"
-	"org.apache.xmlgraphics.ps.dsc.ListenerTestCase"
-	"org.apache.xmlgraphics.io.XmlSourceUtilTestCase"
-)
-
-src_install() {
-	default
-	java-pkg-simple_src_install
-}
diff --git a/dev-java/xpp3/xpp3-1.1.4c-r6.ebuild b/dev-java/xpp3/xpp3-1.1.4c-r6.ebuild
new file mode 100644
index 000000000000..3b9eb1d77ff8
--- /dev/null
+++ b/dev-java/xpp3/xpp3-1.1.4c-r6.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+JAVA_PKG_IUSE="doc source"
+MAVEN_ID="xpp3:xpp3:1.1.4c"
+
+inherit java-pkg-2 java-pkg-simple
+
+DESCRIPTION="An implementation of XMLPULL V1 API"
+HOMEPAGE="https://www.extreme.indiana.edu/xgws/xsoap/xpp/mxp1/index.html"
+SRC_URI="https://repo1.maven.org/maven2/${PN}/${PN}/${PV}/${P}-sources.jar -> ${P}.jar"
+
+LICENSE="Apache-1.1 IBM JDOM LGPL-2.1+"
+SLOT="0"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+
+# Restriction to java 1.8
+# Otherwise jdk 11+ would fail to build javadoc:
+# ./javax/xml/namespace/QName.java:55: error: package exists in another module: java.xml
+# package javax.xml.namespace;
+# ^
+# 1 error
+RDEPEND=">=virtual/jre-1.8:*"
+DEPEND="virtual/jdk:1.8"
+
+JAVA_RESOURCE_DIRS="resources"
+
+src_prepare() {
+	default
+	mkdir "resources" || die
+	cp -r "META-INF" "resources" || die
+}