Adding metadata

6 files changed, 180 insertions, 0 deletions

diff --git a/dev-java/antlr-runtime/Manifest b/dev-java/antlr-runtime/Manifest
index 9315d8cda071..f03a9fd655f6 100644
--- a/dev-java/antlr-runtime/Manifest
+++ b/dev-java/antlr-runtime/Manifest
@@ -1,2 +1,3 @@
 DIST antlr-4.9.3.tar.gz 4640242 BLAKE2B fb58f5e533051cb2c439c32f0462c1d463c99df862ba7e1a37a1c61378ab36a9edb9525c2a342de5b517da6f02d8291de5976c550932314f3464aad1a778afb9 SHA512 61452404c9639b5a0908cda16605f17c0fed0c9adfc3278c7408f9971420e9d1fe8f9e974e0826c2e3e780fdd83324094c0246cd5b28fa63f5686b094ea08127
 DIST antlr-runtime-3.5.2-sources.jar 206095 BLAKE2B 62b5ca08b13b80e1cdfe82d7354f75dcd3d82d7618bb2d20c4973c0b588d60cc034a8bc265d1cba6b3fc09f5583450a48948dc0beb86c4b13c6b9fdb32de37fd SHA512 fda8b0b1d6f779098c885360ea5f5e93eac5153f5bf761f3dbc954209b69b76edd21a8e4915bb9e567e5c095f1d173e19429bea34da9698bf241d17599858847
+DIST antlr-runtime-3.5.3-sources.jar 204572 BLAKE2B 8f4493497cbfef613028d4847d1a68a0fdd29f5bf80c3a72b33093aa048409fb740aa95e16e7ceb279b939fabf3a617ccc8046ef6b879eafdb4ae14599951799 SHA512 fbfb656b32aa40ce731996774c9a5df28e2dbf67d097a834b39ef137555ff618c26a881af599191fb75366dc3824e281e93a32dbed65d49cc39e2017d836ae95
diff --git a/dev-java/antlr-runtime/antlr-runtime-3.5.3.ebuild b/dev-java/antlr-runtime/antlr-runtime-3.5.3.ebuild
new file mode 100644
index 000000000000..7d9d8d21d52c
--- /dev/null
+++ b/dev-java/antlr-runtime/antlr-runtime-3.5.3.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# Skeleton command:
+# java-ebuilder --generate-ebuild --workdir . --pom antlr-runtime-3.5.3.pom --download-uri https://repo1.maven.org/maven2/org/antlr/antlr-runtime/3.5.3/antlr-runtime-3.5.3-sources.jar --slot 3.5 --keywords "~amd64 ~arm ~arm64~ppc64 ~x86" --ebuild antlr-runtime-3.5.3.ebuild
+
+EAPI=8
+
+JAVA_PKG_IUSE="doc source"
+MAVEN_ID="org.antlr:antlr-runtime:3.5.3"
+
+inherit java-pkg-2 java-pkg-simple
+
+DESCRIPTION="ANTLR 3 Runtime"
+HOMEPAGE="https://www.antlr3.org/"
+SRC_URI="https://repo1.maven.org/maven2/org/antlr/${PN}/${PV}/${P}-sources.jar"
+
+LICENSE="BSD"
+SLOT="3.5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+
+# Common dependencies
+# POM: ${P}.pom
+# org.antlr:stringtemplate:3.2.1 -> >=dev-java/stringtemplate-3.2.1:0
+
+CP_DEPEND="
+	>=dev-java/stringtemplate-3.2.1:0
+"
+
+DEPEND="${CP_DEPEND}
+	>=virtual/jdk-1.8:*"
+
+RDEPEND="${CP_DEPEND}
+	>=virtual/jre-1.8:*"
+
+BDEPEND="app-arch/unzip"
+
+S="${WORKDIR}"
diff --git a/dev-java/antlr-tool/Manifest b/dev-java/antlr-tool/Manifest
index 165df95f41e4..1a983d2d2972 100644
--- a/dev-java/antlr-tool/Manifest
+++ b/dev-java/antlr-tool/Manifest
@@ -1,4 +1,6 @@
 DIST antlr-3.5.2.tar.gz 6927126 BLAKE2B 1907229549434dfea6ef1fa915137a2f733bd61f0a40aacb131689df619d1c92e125453ec3d1febc5d92da1841ffbde060af196cff1ca8fb6f4684600375e161 SHA512 e2a0520093fb2a77dcd9d44f26a9fdd612dceaffb398c53b2b8cd29f4630830647ede29e8dd55b434cb2c165b0fd1d77968ec6e6de0798f14d9cdfd9e6fccd99
+DIST antlr-3.5.3.tar.gz 6752328 BLAKE2B 8ebd098c9475122cddcadd5991b9f882b7fda5868ad979b29c9f4dab97e39cd31e7fc943476c3a854f3e3aee9c1c56384b7fcc893f87548482af5d5d0839fd30 SHA512 c565e1ade7a62bb127df707015afded9a9cea54cbf5488730a327671c57e8718f93f76c4fa28edd856810cb9c7ccbcb27b53a7c8f7e3efc8169e64cfcc535a4c
 DIST antlr-4.9.3.tar.gz 4640242 BLAKE2B fb58f5e533051cb2c439c32f0462c1d463c99df862ba7e1a37a1c61378ab36a9edb9525c2a342de5b517da6f02d8291de5976c550932314f3464aad1a778afb9 SHA512 61452404c9639b5a0908cda16605f17c0fed0c9adfc3278c7408f9971420e9d1fe8f9e974e0826c2e3e780fdd83324094c0246cd5b28fa63f5686b094ea08127
 DIST antlr-tool-3.5.2-sources.jar 957096 BLAKE2B 39b75824e129c8111f302eb71407a683c59e91e79a3fa13c5386c4ba4aa322e706deb10b36df3591ab0843faff5702091d543272ee85d63cd92cb36cc72e1ceb SHA512 50fece361b69299be0c0941e6fe2bfacfc39c0b3dad3320126a9a80cd0f053fbaa6332612e2bab2872db122025d6abfe4b35a4636ef1c101e9131bbd2cdf5e28
+DIST antlr-tool-3.5.3-sources.jar 949247 BLAKE2B f7afa52faae8324093206b7e56dfda58a79815cc2c13baca1cb93b3424c8b310325885ca8c86f0ca8a016a73e30740c2fa5f34ce71ed3a6cfc5fdeb6f2c4a9a7 SHA512 cfbc612c0257c4f0e09451cd76fe904680b6af132596696f2ef9c4e21dcfc53d53501e4d4d2b1c1cf4391355fa3766cf8dabc718dc3580728d24db3ebc14e696
 DIST antlr-tool-4.9.3-sources.jar 961749 BLAKE2B 294c7ba6dff9a1039d3e570d7d49f46a564302d1e7a25ac9f662a2c293cbabadd6a5a4a94d026c4e5fcca37c407e104956badbd1cbbf71b957e464dc67cf823e SHA512 7d70e80714b673eb8301def5e66a7133b2ac477e3cc219e37877ef9df673e0599a1148a8c1929ca8eab081d4e7375c9079241765a1f38832b21cfe8608ef4429
diff --git a/dev-java/antlr-tool/antlr-tool-3.5.3.ebuild b/dev-java/antlr-tool/antlr-tool-3.5.3.ebuild
new file mode 100644
index 000000000000..622181ef1f45
--- /dev/null
+++ b/dev-java/antlr-tool/antlr-tool-3.5.3.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# Artifact ID for antlr-tool is 'antlr'
+# https://github.com/antlr/antlr3/blob/3.5.3/tool/pom.xml#L4
+MAVEN_ID="org.antlr:antlr:3.5.3"
+
+JAVA_PKG_IUSE="doc source test"
+JAVA_TESTING_FRAMEWORKS="junit-4"
+
+inherit java-pkg-2 java-pkg-simple
+
+MY_PN="${PN%-tool}"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="The ANTLR 3 tool"
+HOMEPAGE="https://www.antlr3.org/"
+# Maven Central sources JAR for *.java sources pre-generated from *.g files;
+# the source generation requires this package itself.
+# Tarball for resources, the test suite, and DOCS files
+SRC_URI="
+	https://repo1.maven.org/maven2/org/antlr/antlr/${PV}/${MY_P}-sources.jar -> ${P}-sources.jar
+	https://github.com/antlr/antlr3/archive/${PV}.tar.gz -> ${MY_P}.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="3.5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+CP_DEPEND="
+	~dev-java/antlr-runtime-${PV}:${SLOT}
+	dev-java/stringtemplate:4
+"
+
+BDEPEND="
+	app-arch/unzip
+"
+
+DEPEND="
+	>=virtual/jdk-1.8:*
+	${CP_DEPEND}
+"
+
+RDEPEND="
+	>=virtual/jre-1.8:*
+	${CP_DEPEND}
+"
+
+S="${WORKDIR}"
+TARBALL_S="${S}/${MY_PN}3-${PV}"
+
+JAVA_SRC_DIR="org"
+JAVA_RESOURCE_DIRS=( "${TARBALL_S}/tool/src/main/resources" )
+
+JAVA_TEST_GENTOO_CLASSPATH="junit-4"
+JAVA_TEST_SRC_DIR="${TARBALL_S}/tool/src/test/java"
+
+DOCS=( "${TARBALL_S}/tool/CHANGES.txt" )
+
+src_prepare() {
+	java-pkg_clean
+	java-pkg-2_src_prepare
+
+	# Some tests fail under Java 8 in ways that probably aren't limited
+	# to the tests. This is bad but upstream is never going to update
+	# 3.5. At the time of writing, we only use it to build 4 anyway.
+	rm -v "${JAVA_TEST_SRC_DIR}/org/antlr/test/"Test{DFAConversion,SemanticPredicates,TopologicalSort}.java || die
+}
+
+src_install() {
+	java-pkg-simple_src_install
+	einstalldocs # https://bugs.gentoo.org/789582
+}
diff --git a/dev-java/antlr/Manifest b/dev-java/antlr/Manifest
index 1de9662c4657..49def7a90a7c 100644
--- a/dev-java/antlr/Manifest
+++ b/dev-java/antlr/Manifest
@@ -2,4 +2,5 @@ DIST antlr-2.7.7.tar.gz 1816180 BLAKE2B 3a9a51070f8651befeb4d22be344b544e119db34
 DIST antlr-3.2.jar 1928009 BLAKE2B 9c56b0142abdb7d0caabebbae12618a665f91001e2f472519549a65b8601b81fcca485898c7420087a7b631351eb26e4b98589d7284960efcc3c65155919fd2a SHA512 25a61404c4b41e48eeaed49d41122f9400092248a10eb776d75ce3513295870eca1acc4b06c74925284a27cc64ca0506e34de39fb91996f09727cc5cc72dd9a6
 DIST antlr-3.2.tar.gz 837320 BLAKE2B 3addcfed45e67a7f8f3841a890be418626d93229dc326fe4670c6b145a457203a26f01723695573692c65bb6c376349a8d8cd852b339b1f6da7b71a52e14bb4f SHA512 8984221cd89253c033a4596dd56cd51b297393a53b4682f5ab401172745d343371bf0d45417fa286ce972add1b4e474f1f3091fa1345158dbfc040702d61607c
 DIST antlr-3.5.2.tar.gz 6927126 BLAKE2B 1907229549434dfea6ef1fa915137a2f733bd61f0a40aacb131689df619d1c92e125453ec3d1febc5d92da1841ffbde060af196cff1ca8fb6f4684600375e161 SHA512 e2a0520093fb2a77dcd9d44f26a9fdd612dceaffb398c53b2b8cd29f4630830647ede29e8dd55b434cb2c165b0fd1d77968ec6e6de0798f14d9cdfd9e6fccd99
+DIST antlr-3.5.3.tar.gz 6752328 BLAKE2B 8ebd098c9475122cddcadd5991b9f882b7fda5868ad979b29c9f4dab97e39cd31e7fc943476c3a854f3e3aee9c1c56384b7fcc893f87548482af5d5d0839fd30 SHA512 c565e1ade7a62bb127df707015afded9a9cea54cbf5488730a327671c57e8718f93f76c4fa28edd856810cb9c7ccbcb27b53a7c8f7e3efc8169e64cfcc535a4c
 DIST antlr-4.9.3.tar.gz 4640242 BLAKE2B fb58f5e533051cb2c439c32f0462c1d463c99df862ba7e1a37a1c61378ab36a9edb9525c2a342de5b517da6f02d8291de5976c550932314f3464aad1a778afb9 SHA512 61452404c9639b5a0908cda16605f17c0fed0c9adfc3278c7408f9971420e9d1fe8f9e974e0826c2e3e780fdd83324094c0246cd5b28fa63f5686b094ea08127
diff --git a/dev-java/antlr/antlr-3.5.3.ebuild b/dev-java/antlr/antlr-3.5.3.ebuild
new file mode 100644
index 000000000000..41ea8dc96c2b
--- /dev/null
+++ b/dev-java/antlr/antlr-3.5.3.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit java-pkg-2
+
+DESCRIPTION="A parser generator for many languages"
+HOMEPAGE="https://www.antlr3.org/"
+# Reuse tarball for DOCS
+SRC_URI="https://github.com/${PN}/${PN}3/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="3.5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+CP_DEPEND="
+	~dev-java/antlr-runtime-${PV}:${SLOT}
+	~dev-java/antlr-tool-${PV}:${SLOT}
+"
+
+DEPEND="
+	>=virtual/jdk-1.8:*
+	${CP_DEPEND}
+"
+
+RDEPEND="
+	>=virtual/jre-1.8:*
+	${CP_DEPEND}
+"
+
+S="${WORKDIR}/${PN}3-${PV}"
+
+DOCS=( contributors.txt README.txt )
+
+src_compile() {
+	:
+}
+
+src_install() {
+	java-pkg_regjar "$(java-pkg_getjar "antlr-runtime-${SLOT}" antlr-runtime.jar)"
+	java-pkg_regjar "$(java-pkg_getjar "antlr-tool-${SLOT}" antlr-tool.jar)"
+
+	java-pkg_dolauncher "${PN}${SLOT}" --main org.antlr.Tool
+	einstalldocs # https://bugs.gentoo.org/789582
+}
+
+pkg_postinst() {
+	# If upgrading from a version of this slot that installs JARs,
+	# display a message about submodule split
+	local changed_ver="3.5.2-r2"
+	local should_show_msg
+	for replaced_ver in ${REPLACING_VERSIONS}; do
+		if ver_test "${replaced_ver}" -lt "${changed_ver}"; then
+			should_show_msg=1
+			break
+		fi
+	done
+	[[ "${should_show_msg}" ]] || return
+	elog "Since version ${changed_ver}, ${PN}-${SLOT} no longer installs JARs."
+	elog "Please find the JARs from files installed by submodule packages"
+	elog "antlr-runtime-${SLOT} and antlr-tool-${SLOT}."
+}