Adding metadata

5 files changed, 114 insertions, 2 deletions

diff --git a/dev-java/java-config/java-config-2.3.1.ebuild b/dev-java/java-config/java-config-2.3.1.ebuild
index 20b05809077f..bdcbfa7d2263 100644
--- a/dev-java/java-config/java-config-2.3.1.ebuild
+++ b/dev-java/java-config/java-config-2.3.1.ebuild
@@ -23,7 +23,6 @@ DEPEND="test? ( sys-apps/portage[${PYTHON_USEDEP}] )"
 
 # baselayout-java is added as a dep till it can be added to eclass.
 RDEPEND="
-	!dev-java/java-config-wrapper
 	sys-apps/baselayout-java
 	sys-apps/portage[${PYTHON_USEDEP}]"
 
diff --git a/dev-java/java-config/java-config-9999.ebuild b/dev-java/java-config/java-config-9999.ebuild
index d33d41ecd0b7..f19d7e9ae202 100644
--- a/dev-java/java-config/java-config-9999.ebuild
+++ b/dev-java/java-config/java-config-9999.ebuild
@@ -29,7 +29,6 @@ DEPEND="test? ( sys-apps/portage[${PYTHON_USEDEP}] )"
 
 # baselayout-java is added as a dep till it can be added to eclass.
 RDEPEND="
-	!dev-java/java-config-wrapper
 	sys-apps/baselayout-java
 	sys-apps/portage[${PYTHON_USEDEP}]"
 
diff --git a/dev-java/miglayout/miglayout-4.0-r2.ebuild b/dev-java/miglayout/miglayout-4.0-r2.ebuild
new file mode 100644
index 000000000000..863e44285ea3
--- /dev/null
+++ b/dev-java/miglayout/miglayout-4.0-r2.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+JAVA_PKG_IUSE="doc examples source"
+
+inherit java-pkg-2
+
+DESCRIPTION="Easy to use yet very powerful Java Swing layout manager"
+HOMEPAGE="http://www.miglayout.com/"
+SRC_URI="http://www.migcalendar.com/miglayout/versions/${PV}/${P}-sources.jar"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="swt"
+
+COMMON_DEPEND="swt? ( dev-java/swt:4.10 )"
+BDEPEND="app-arch/unzip"
+RDEPEND="
+	${COMMON_DEPEND}
+	>=virtual/jre-1.8:*
+"
+DEPEND="
+	${COMMON_DEPEND}
+	>=virtual/jdk-1.8:*
+"
+
+S="${WORKDIR}"
+
+src_prepare() {
+	default
+
+	mv net/miginfocom/{demo,examples} . || die
+	mv demo/* examples || die
+
+	if ! use swt; then
+		rm -r net/miginfocom/swt || die
+	fi
+
+	find net -name '*.java' > sources.lst
+}
+
+src_compile() {
+	local classpath
+	use swt && classpath=( -classpath "$(java-pkg_getjars swt-4.10)" )
+
+	mkdir classes || die
+	ejavac "${classpath[@]}" -d classes @sources.lst || die
+	jar -cf ${PN}.jar -C classes . || die
+
+	if use doc; then
+		javadoc "${classpath[@]}" -author -version -d api @sources.lst || die
+	fi
+}
+
+src_install() {
+	java-pkg_dojar ${PN}.jar
+
+	use doc && java-pkg_dojavadoc api
+	use examples && java-pkg_doexamples examples
+	use source && java-pkg_dosrc net
+}
diff --git a/dev-java/piccolo2d/Manifest b/dev-java/piccolo2d/Manifest
index 76ae19e81211..a24cdbd7c25e 100644
--- a/dev-java/piccolo2d/Manifest
+++ b/dev-java/piccolo2d/Manifest
@@ -1 +1,2 @@
+DIST piccolo2d-3.0.tar.gz 402866 BLAKE2B b78b93084e13c738126ab04babab4ee502deca869dc28a5bd066c13b46f455af55cf76531270d546d6cf56d56c0e48f2edbbda40944479cb9762db56421fb021 SHA512 609b38e27386ea0dac821f8d0a23bbf57afa056ed928944d63c2c8d1572c4f8b6541d27f5d26ab167948724c9f1198069fb6e0b76ce2770fe795662c76151100
 DIST piccolo2d-3.0.zip 786064 BLAKE2B f550bc7d39811998616000833543e048c879eeaf5006ba3d1cd19c7ac3c3c588fdf1c9b66986e5232dea49c1081082716e16542918319c18207cc2177d38ff10 SHA512 c57d0e86ea36e662027559c63c8e300629361849d4526d9271ea1ed3c8d55296ab1fab846c7a475c5d831fc6330052fa897ba8d3f89a196bca752a7ae802aa2a
diff --git a/dev-java/piccolo2d/piccolo2d-3.0-r2.ebuild b/dev-java/piccolo2d/piccolo2d-3.0-r2.ebuild
new file mode 100644
index 000000000000..bfe1cbbc3322
--- /dev/null
+++ b/dev-java/piccolo2d/piccolo2d-3.0-r2.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+JAVA_PKG_IUSE="doc source examples"
+
+inherit java-pkg-2 java-pkg-simple
+
+DESCRIPTION="A Structured 2D Graphics Framework"
+HOMEPAGE="https://github.com/piccolo2d/piccolo2d.java"
+SRC_URI="https://github.com/${PN}/${PN}.java/archive/${PN}-complete-${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64"
+
+CDEPEND="dev-java/swt:4.10"
+
+DEPEND="
+	${CDEPEND}
+	>=virtual/jdk-1.8:*"
+RDEPEND="
+	${CDEPEND}
+	>=virtual/jre-1.8:*"
+BDEPEND="app-arch/unzip"
+
+S="${WORKDIR}/${PN}.java-${PN}-complete-${PV}"
+
+JAVA_GENTOO_CLASSPATH="swt-4.10"
+JAVA_SRC_DIR=( "core" "extras" "swt" )
+
+src_prepare() {
+	default
+	rm -rf core/src/test extras/src/test swt/src/test || die
+}
+
+src_install() {
+	java-pkg-simple_src_install
+	dodoc Readme.txt ReleaseNotes.txt
+
+	if use examples; then
+		docinto examples
+		dodoc -r examples/src/main/java/org/piccolo2d/examples/*
+		dodoc -r examples/src/main/java/org/piccolo2d/tutorial
+		dodoc -r swt-examples/src/main/java/org/piccolo2d/extras
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}