Adding metadata

12 files changed, 312 insertions, 3 deletions

diff --git a/dev-java/bnd/bnd-7.1.0.ebuild b/dev-java/bnd/bnd-7.1.0-r1.ebuild
index 23e53796649e..b7a5ea224d45 100644
--- a/dev-java/bnd/bnd-7.1.0.ebuild
+++ b/dev-java/bnd/bnd-7.1.0-r1.ebuild
@@ -23,7 +23,7 @@ CP_DEPEND="
 	~dev-java/bndlib-${PV}:0
 	dev-java/felix-resolver:0
 	dev-java/guava:0
-	dev-java/javaparser-core:0
+	<=dev-java/javaparser-core-3.13.10:0
 	dev-java/jline:2
 	dev-java/jtwig-core:0
 	dev-java/osgi-annotation:0
diff --git a/dev-java/javaparser-core/Manifest b/dev-java/javaparser-core/Manifest
index 44d5620a8988..6fb603dab526 100644
--- a/dev-java/javaparser-core/Manifest
+++ b/dev-java/javaparser-core/Manifest
@@ -1 +1,2 @@
 DIST javaparser-3.13.10.tar.gz 7043664 BLAKE2B 5d2e35cfa22dbcb425365e2e7806c46b989b92a84472fbd80d42716fbb2a5ddcad2daec6214be689b1dcc6541890527e422953c083e713e9f1d22ce5b3035e90 SHA512 b90a6b7b2fbb6a13cc36cdd17acd09a22adb9e62311862c2a67a9ea339b98e245c93ba371645e3c695e76966b21e3bc01accf040482e30b2b6882a5569db5806
+DIST javaparser-3.26.3.tar.gz 18493336 BLAKE2B a3a01239caf9f215bb470c060eff82b8db607fab6cffa637b06937f4e80f1fd530f1991e750aa5c91b9b0b5a173e77eb84c104a14d1353b7de233a56cd8284dc SHA512 8e109eec868e5aeceb2c91e09f04286f4e9944601359febe80bc29074b6eb306fd058a93e41cf7824ce88a392026321cca637a8cf601e6100b74b06a4fe39b80
diff --git a/dev-java/javaparser-core/javaparser-core-3.26.3.ebuild b/dev-java/javaparser-core/javaparser-core-3.26.3.ebuild
new file mode 100644
index 000000000000..d623f5d390b8
--- /dev/null
+++ b/dev-java/javaparser-core/javaparser-core-3.26.3.ebuild
@@ -0,0 +1,59 @@
+# Copyright 2023-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+JAVA_PKG_IUSE="doc source"
+MAVEN_ID="com.github.javaparser:javaparser-core:${PV}"
+
+inherit java-pkg-2 java-pkg-simple
+
+DESCRIPTION="Java 1-21 Parser and Abstract Syntax Tree for Java"
+HOMEPAGE="https://javaparser.org/"
+SRC_URI="https://github.com/javaparser/javaparser/archive/${P/core/parent}.tar.gz -> javaparser-${PV}.tar.gz"
+S="${WORKDIR}/javaparser-${P/core/parent}"
+
+LICENSE="Apache-2.0 LGPL-3"
+# dev-java/bnd-7.1.0 seems not to like this version.
+# biz.aQute.bnd.reporter/src/biz/aQute/bnd/reporter/codesnippet/JavaSnippetReader.java:20: error: cannot find symbol
+# import com.github.javaparser.printer.PrettyPrinterConfiguration;
+#                                     ^
+#   symbol:   class PrettyPrinterConfiguration
+#   location: package com.github.javaparser.printer
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+JAVACC_SLOT="7.0.13"
+BDEPEND="dev-java/javacc:${JAVACC_SLOT}"
+
+# Does not compile with >=jdk:21 (not even with 'mvn clean compile'):
+# javaparser-core/src/main/java/com/github/javaparser/ast/NodeList.java:243:
+# error: getLast() in NodeList cannot implement getLast() in List
+#     public Optional<N> getLast() {
+#                        ^
+#   return type Optional<N> is not compatible with N
+#   where N,E are type-variables:
+#     N extends Node declared in class NodeList
+#     E extends Object declared in interface List
+DEPEND="<virtual/jdk-21:*"
+RDEPEND=">=virtual/jre-1.8:*"
+
+DOCS=( CONTRIBUTING.md changelog.md readme.md )
+
+JAVA_AUTOMATIC_MODULE_NAME="com.github.javaparser.core"
+JAVA_SRC_DIR=(
+	"${PN}/src/main/java"
+	"${PN}/src/main/java-templates"
+	"${PN}/src/main/javacc-support"
+)
+
+src_prepare() {
+	java-pkg-2_src_prepare
+
+	mkdir -p "${PN}/src/main/java/com/github/javaparser"
+	javacc-${JAVACC_SLOT} -GRAMMAR_ENCODING=UTF-8 \
+		-JDK_VERSION=1.8 \
+		-OUTPUT_DIRECTORY="${PN}/src/main/java/com/github/javaparser" \
+		"javaparser-core/src/main/javacc/java.jj" \
+		|| die "Code generation with java.jj failed"
+}
diff --git a/dev-java/json-simple/Manifest b/dev-java/json-simple/Manifest
index ca0205d6e68a..62ded9a54c51 100644
--- a/dev-java/json-simple/Manifest
+++ b/dev-java/json-simple/Manifest
@@ -1 +1,2 @@
 DIST json-simple-2.3.1.tar.gz 56230 BLAKE2B c4a196ffa67a729a1964db8c30b95ccb0bef0c213a76e37e463153a895a5fdb8c6f02f6d188d28f0b56665bf24c75dbdeeb42d88297c8df5e1b409606b0f04f2 SHA512 b80ea33480f8b32511ee2db5cfacc9c02cb5dbf0765b41fb76e099f41ac6c0ea69d75fdf0a5f783e3bfb7b4f200c49ca192a3321e0d8480b3a8b67ada469dbb1
+DIST json-simple-4.0.1.tar.gz 47731 BLAKE2B 59092065dcad7488e61e19f5af0ff823b76099d035dace4e0a41d7002fff0e35541956b137c84b68e8bf8d116fd997a6384b7397bce99eb0fe23f4cbec4b351c SHA512 a55919c90589276fcf6105f782faef42b08770e831f404f6e58450e3b24b6dfaeb9165abdd5323e64eb9d28c5e2c2e61de8fb2aa51d184f58b0362a240f4c19a
diff --git a/dev-java/json-simple/json-simple-4.0.1.ebuild b/dev-java/json-simple/json-simple-4.0.1.ebuild
new file mode 100644
index 000000000000..71a9c542fde0
--- /dev/null
+++ b/dev-java/json-simple/json-simple-4.0.1.ebuild
@@ -0,0 +1,26 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+JAVA_PKG_IUSE="source doc test"
+MAVEN_ID="com.github.cliftonlabs:json-simple:4.0.1"
+JAVA_TESTING_FRAMEWORKS="junit-4"
+
+inherit java-pkg-2 java-pkg-simple
+
+DESCRIPTION="Java 7+ toolkit to quickly develop RFC 4627 JSON compatible applications"
+HOMEPAGE="https://www.json.org"
+SRC_URI="https://github.com/cliftonlabs/json-simple/archive/json-simple-${PV}.tar.gz"
+S="${WORKDIR}/${PN}-${P}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64"
+
+DEPEND=">=virtual/jdk-1.8:*"
+RDEPEND=">=virtual/jre-1.8:*"
+
+JAVA_SRC_DIR="src/main/java"
+JAVA_TEST_GENTOO_CLASSPATH="junit-4"
+JAVA_TEST_SRC_DIR="src/test/java"
diff --git a/dev-java/json-smart/Manifest b/dev-java/json-smart/Manifest
index 08a0756cd16f..f45dcc2bb20b 100644
--- a/dev-java/json-smart/Manifest
+++ b/dev-java/json-smart/Manifest
@@ -1,2 +1,3 @@
 DIST json-smart-1.3.3.tar.gz 49430 BLAKE2B 805e16e0de5321a2e8164468757e9b722849f0fe90fd6822cc99f7afffd9f4e480fc4e14c2bbd12b325a27abc8ca7e93b4a17ce56ac352117cef336e1ebb3fe9 SHA512 c6006c6a00a085ea8810e18889450d11240dc3671351f20602214db418107808df1f413fe67c199d6529e4c0087f2533601826666ac4fa493bcaf72d2c18ed83
 DIST json-smart-2.5.0.tar.gz 88839 BLAKE2B 25760bd9c9ddecfef2fc3e60fc28b83def2223c7fc1e52ef39b3e6d01e5f2f29f36a35bfd43fc4d6ce6d5df5fcb25f59b1c86e1864a3044c69a6d0010335280b SHA512 4bffadf68998da4b63b34bcc9dbf804fd2b21b8d9514de4e155127d5a2eb3db74c7e396959b54c61c08e169eeed85dff3ad2f1d899cfddca53e501c45cebae21
+DIST json-smart-2.5.1.tar.gz 91171 BLAKE2B 21e83eadb15dbaa43ebe1fc9a5fd9500d4d233571dc4b65f417d7179630fde8a47e44cb652b2f598a2a6f46569876e8cac4769752dd4db179dc01b274514ef02 SHA512 00454e1debcebe009300a8f5d53b24b5c1917d173c9f3b98278236b52584631ab0e8bbf18c193f181e77537fb335b5bb31c1978918dc4f6e0ca82c44adb6797b
diff --git a/dev-java/json-smart/json-smart-2.5.1.ebuild b/dev-java/json-smart/json-smart-2.5.1.ebuild
new file mode 100644
index 000000000000..cb994b59522c
--- /dev/null
+++ b/dev-java/json-smart/json-smart-2.5.1.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+JAVA_PKG_IUSE="doc source test"
+MAVEN_PROVIDES="
+	net.minidev:accessors-smart:${PV}
+	net.minidev:json-smart:${PV}
+"
+JAVA_TESTING_FRAMEWORKS="junit-4"
+
+inherit java-pkg-2 java-pkg-simple
+
+DESCRIPTION="JSON Small and Fast Parser"
+HOMEPAGE="https://urielch.github.io"
+SRC_URI="https://github.com/netplex/json-smart-v2/archive/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-v2-${PV}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+RESTRICT="test" #839681
+
+DEPEND="
+	dev-java/asm:0
+	>=virtual/jdk-1.8:*
+"
+
+RDEPEND=">=virtual/jre-1.8:*"
+
+JAVADOC_CLASSPATH="asm"
+JAVADOC_SRC_DIRS=(
+	accessors-smart/src/main/java
+	json-smart/src/main/java
+)
+
+src_compile() {
+	einfo "Compiling accessors-smart.jar"
+	JAVA_CLASSPATH_EXTRA="asm"
+	JAVA_JAR_FILENAME="accessors-smart.jar"
+	JAVA_SRC_DIR="accessors-smart/src/main/java"
+	java-pkg-simple_src_compile
+	JAVA_GENTOO_CLASSPATH_EXTRA+=":accessors-smart.jar"
+	rm -r target || die
+
+	einfo "Compiling json-smart.jar"
+	JAVA_JAR_FILENAME="json-smart.jar"
+	JAVA_SRC_DIR="json-smart/src/main/java"
+	java-pkg-simple_src_compile
+	JAVA_GENTOO_CLASSPATH_EXTRA+=":json-smart.jar"
+	rm -r target || die
+
+	use doc && ejavadoc
+}
+
+src_install() {
+	einstalldocs
+	java-pkg_dojar "accessors-smart.jar"
+	java-pkg_dojar "json-smart.jar"
+
+	if use doc; then
+		java-pkg_dojavadoc target/api
+	fi
+
+	if use source; then
+		java-pkg_dosrc "accessors-smart/src/main/java/*"
+		java-pkg_dosrc "json-smart/src/main/java/*"
+	fi
+}
diff --git a/dev-java/json/Manifest b/dev-java/json/Manifest
index b2d756b94a7f..49cfea20357d 100644
--- a/dev-java/json/Manifest
+++ b/dev-java/json/Manifest
@@ -1,2 +1,3 @@
 DIST json-20240303.tar.gz 245665 BLAKE2B 3462398895ab6da9610dac8851f2aa4528359e255015fd59a160fe99443819fa5bb57eb30ce177238d06abe95aaae9847cc85e4eee59c90edf7732bd823d9b89 SHA512 22465216eca7e4721aacca7b519d0bf1b0fe20b2de68ef0b6c62feae811e11203bfc733d8e9c97e2aa5b6ed30c74eefc601025b31807e51d496666412516afc9
+DIST json-20241224.tar.gz 260438 BLAKE2B a531f8009cada5bbb9cd7207ce20ed1b1d358bc6533b9678a7845c31714351bac3406fd85663bf7e3fcc9cf4249221a6a5599b1d841a82e924f594ae6a46e848 SHA512 d487201c20c4c36714a944297fd0a175006ddc742e077bbb2a0e541c8b52fafc0169bc984e5a5f085e580e5a770fa30f0588c2f15ad761f6afae22134b544797
 DIST json-path-2.9.0.jar 276633 BLAKE2B bb83d6c6d972ea05dce3ef9878c0db0b93d6168cb796b63365a4615434c24edaad86bf021d6bf8736d67504ed8803c423efe01a323e094a59854cd9e73eb6862 SHA512 9a9dbb2cd36662c8049419ed891290602baeca2549eb7df62122cb20c91e66bc8c2c0e5e13199c4a70bf0b6e62ea4c2601f84e4c79d2af25ff1704481c86740a
diff --git a/dev-java/json/json-20241224.ebuild b/dev-java/json/json-20241224.ebuild
new file mode 100644
index 000000000000..f8e8b002e74a
--- /dev/null
+++ b/dev-java/json/json-20241224.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+JAVA_PKG_IUSE="doc source test"
+MAVEN_ID="org.json:json:${PV}"
+JAVA_TESTING_FRAMEWORKS="junit-4"
+
+inherit java-pkg-2 java-pkg-simple check-reqs
+
+DESCRIPTION="A reference implementation of a JSON package in Java"
+HOMEPAGE="https://github.com/stleary/JSON-java"
+JPV="2.9.0"
+SRC_URI="https://github.com/stleary/JSON-java/archive/${PV}.tar.gz -> ${P}.tar.gz
+	test? (
+		https://repo1.maven.org/maven2/com/jayway/jsonpath/json-path/${JPV}/json-path-${JPV}.jar
+	)"
+S="${WORKDIR}/JSON-java-${PV}"
+
+LICENSE="JSON"
+SLOT="0"
+KEYWORDS="~amd64"
+
+DEPEND="
+	>=virtual/jdk-1.8:*
+	test? (
+		dev-java/asm:0
+		dev-java/json-smart:0
+		dev-java/mockito:4
+		dev-java/slf4j-api:0
+	)
+"
+
+RDEPEND=">=virtual/jre-1.8:*"
+
+DOCS=( {CONTRIBUTING,README,SECURITY}.md )
+
+JAVA_AUTOMATIC_MODULE_NAME="org.json"
+JAVA_SRC_DIR="src/main/java"
+
+JAVA_TEST_GENTOO_CLASSPATH="
+	asm
+	json-smart
+	junit-4
+	mockito-4
+	slf4j-api
+"
+JAVA_TEST_RESOURCE_DIRS="src/test/resources"
+JAVA_TEST_SRC_DIR="src/test/java"
+
+check_env() {
+	if use test; then
+		# this is needed only for tests
+		CHECKREQS_MEMORY="2048M"
+		check-reqs_pkg_pretend
+	fi
+}
+
+pkg_pretend() {
+	check_env
+}
+
+pkg_setup() {
+	check_env
+	java-pkg-2_pkg_setup
+}
+
+src_test() {
+	# setting Xms for bug #930723
+	# gradlew: DEFAULT_JVM_OPTS='"-Xmx64m" "-Xms64m"
+	JAVA_TEST_EXTRA_ARGS=" -Xmx${CHECKREQS_MEMORY}"
+	JAVA_GENTOO_CLASSPATH_EXTRA="${DISTDIR}/json-path-${JPV}.jar" # Test compile dependency
+
+	local vm_version="$(java-config -g PROVIDES_VERSION)"
+	if ver_test "${vm_version}" -ge 17; then
+		JAVA_TEST_EXTRA_ARGS+=( --add-opens=java.base/java.lang=ALL-UNNAMED )
+		JAVA_TEST_EXTRA_ARGS+=( --add-opens=java.base/java.io=ALL-UNNAMED )
+	fi
+	java-pkg-simple_src_test
+}
diff --git a/dev-java/junit/junit-5.10.3.ebuild b/dev-java/junit/junit-5.10.3-r1.ebuild
index 81a4571700d9..ecdba73eeb83 100644
--- a/dev-java/junit/junit-5.10.3.ebuild
+++ b/dev-java/junit/junit-5.10.3-r1.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2024 Gentoo Authors
+# Copyright 1999-2025 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -28,7 +28,7 @@ IUSE="doc migration-support suite vintage"
 CP_DEPEND="
 	dev-java/apiguardian-api:0
 	dev-java/opentest4j:0
-	dev-java/open-test-reporting-events:0
+	<=dev-java/open-test-reporting-events-0.1.0_pre1:0
 	dev-java/picocli:0
 	dev-java/univocity-parsers:0
 "
diff --git a/dev-java/open-test-reporting-events/Manifest b/dev-java/open-test-reporting-events/Manifest
index 9ca788989fa9..32e628468570 100644
--- a/dev-java/open-test-reporting-events/Manifest
+++ b/dev-java/open-test-reporting-events/Manifest
@@ -1 +1,2 @@
 DIST open-test-reporting-0.1.0-M1.tar.gz 98076 BLAKE2B 1780f24776ddbb31752044c7ebee85cd852425b295b2c61d25e36856123e0d9cd4420ecb4f88e17bba52746dd209a5160bfe3bf0c05ac544a0a94e74c49ce1b2 SHA512 75523de2342b1b1027e68eb738ffef8571d6bb81b2cb0d87c26b097d8aac98f52728a6a5f46420ce8bb051d60b226646aef47ec00eee5876b833ba4e1121f5c7
+DIST open-test-reporting-0.2.0-M1.tar.gz 1055220 BLAKE2B 9e0431e607ec9e4b4584d0a4508f4522724df851c3fcda4ddfbdd3b7202569c414de19bd45cb1093fd38dc7d4c7c982ee38b20cbec5d61b5e7d7baf5869f7efe SHA512 89ea03cf4e4b46a781d081cf7191f82f89c32c33f79bdc9b16f6f9046dc6913621d4a67885932f6dba4915a4357d0e77fd9f6b48f81d13aa601d75faeef9f77c
diff --git a/dev-java/open-test-reporting-events/open-test-reporting-events-0.2.0_pre1.ebuild b/dev-java/open-test-reporting-events/open-test-reporting-events-0.2.0_pre1.ebuild
new file mode 100644
index 000000000000..730a117287bf
--- /dev/null
+++ b/dev-java/open-test-reporting-events/open-test-reporting-events-0.2.0_pre1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 2023-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+JAVA_PKG_IUSE="doc source"
+MAVEN_PROVIDES=(
+	"org.opentest4j.reporting:open-test-reporting-schema:${PV}-M1"
+	"org.opentest4j.reporting:open-test-reporting-events:${PV}-M1"
+)
+
+inherit java-pkg-2 java-pkg-simple
+
+DESCRIPTION="Language-agnostic test reporting format and tooling"
+HOMEPAGE="https://github.com/ota4j-team/open-test-reporting"
+MY_PV="${PV/_pre/-M}"
+SRC_URI="https://github.com/ota4j-team/open-test-reporting/archive/r${MY_PV}.tar.gz -> open-test-reporting-${MY_PV}.tar.gz"
+S="${WORKDIR}/open-test-reporting-r${MY_PV}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64"
+
+DEPEND="
+	dev-java/apiguardian-api:0
+	>=virtual/jdk-1.8:*
+"
+
+RDEPEND=">=virtual/jre-1.8:*"
+
+JAVA_CLASSPATH_EXTRA="apiguardian-api"
+JAVADOC_CLASSPATH="${JAVA_CLASSPATH_EXTRA}"
+JAVADOC_SRC_DIRS=(
+	"schema/src/main/java"
+	"events/src/main/java"
+)
+
+src_compile() {
+	einfo "open-test-reporting-schema.jar"
+	JAVA_AUTOMATIC_MODULE_NAME="org.opentest4j.reporting.schema"
+	JAVA_JAR_FILENAME="open-test-reporting-schema.jar"
+	JAVA_RESOURCE_DIRS="schema/src/main/resources"
+	JAVA_SRC_DIR="schema/src/main/java"
+	java-pkg-simple_src_compile
+	JAVA_GENTOO_CLASSPATH_EXTRA+=":open-test-reporting-schema.jar"
+	rm -r target || die
+
+	einfo "open-test-reporting-events.jar"
+	JAVA_AUTOMATIC_MODULE_NAME="org.opentest4j.reporting.events"
+	JAVA_JAR_FILENAME="open-test-reporting-events.jar"
+	JAVA_RESOURCE_DIRS=()
+	JAVA_SRC_DIR="events/src/main/java"
+	java-pkg-simple_src_compile
+	JAVA_GENTOO_CLASSPATH_EXTRA+=":open-test-reporting-events.jar"
+	rm -r target || die
+
+	use doc && ejavadoc
+}
+
+src_install() {
+	java-pkg_dojar "open-test-reporting-schema.jar"
+	java-pkg-simple_src_install
+
+	if use source; then
+		java-pkg_dosrc "schema/src/main/java/*"
+		java-pkg_dosrc "events/src/main/java/*"
+	fi
+}