Adding metadata

13 files changed, 395 insertions, 1 deletions

diff --git a/dev-java/antlr-runtime/Manifest b/dev-java/antlr-runtime/Manifest
new file mode 100644
index 000000000000..ba679475bf46
--- /dev/null
+++ b/dev-java/antlr-runtime/Manifest
@@ -0,0 +1 @@
+DIST antlr-runtime-3.5.2-sources.jar 206095 BLAKE2B 62b5ca08b13b80e1cdfe82d7354f75dcd3d82d7618bb2d20c4973c0b588d60cc034a8bc265d1cba6b3fc09f5583450a48948dc0beb86c4b13c6b9fdb32de37fd SHA512 fda8b0b1d6f779098c885360ea5f5e93eac5153f5bf761f3dbc954209b69b76edd21a8e4915bb9e567e5c095f1d173e19429bea34da9698bf241d17599858847
diff --git a/dev-java/antlr-runtime/antlr-runtime-3.5.2.ebuild b/dev-java/antlr-runtime/antlr-runtime-3.5.2.ebuild
new file mode 100644
index 000000000000..27593c24d267
--- /dev/null
+++ b/dev-java/antlr-runtime/antlr-runtime-3.5.2.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# Skeleton command:
+# java-ebuilder --generate-ebuild --workdir . --pom antlr-runtime-3.5.2.pom --download-uri https://repo1.maven.org/maven2/org/antlr/antlr-runtime/3.5.2/antlr-runtime-3.5.2-sources.jar --slot 3.5 --keywords "~amd64 ~arm ~arm64~ppc64 ~x86" --ebuild antlr-runtime-3.5.2.ebuild
+
+EAPI=8
+
+JAVA_PKG_IUSE="doc source"
+MAVEN_ID="org.antlr:antlr-runtime:3.5.2"
+
+inherit java-pkg-2 java-pkg-simple
+
+DESCRIPTION="ANTLR 3 Runtime"
+HOMEPAGE="https://www.antlr3.org/"
+SRC_URI="https://repo1.maven.org/maven2/org/antlr/${PN}/${PV}/${P}-sources.jar"
+
+LICENSE="BSD"
+SLOT="3.5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+
+# Common dependencies
+# POM: ${P}.pom
+# org.antlr:stringtemplate:3.2.1 -> >=dev-java/stringtemplate-3.2.1:0
+
+CP_DEPEND="
+	>=dev-java/stringtemplate-3.2.1:0
+"
+
+DEPEND="${CP_DEPEND}
+	>=virtual/jdk-1.8:*"
+
+RDEPEND="${CP_DEPEND}
+	>=virtual/jre-1.8:*"
+
+BDEPEND="app-arch/unzip"
+
+S="${WORKDIR}"
diff --git a/dev-java/antlr-runtime/metadata.xml b/dev-java/antlr-runtime/metadata.xml
new file mode 100644
index 000000000000..ae2e32b25753
--- /dev/null
+++ b/dev-java/antlr-runtime/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
+<pkgmetadata>
+ <maintainer type="project">
+  <email>java@gentoo.org</email>
+ </maintainer>
+ <longdescription>
+		A framework for constructing recognizers, compilers, and translators from grammatical descriptions containing Java, C#, C++, or Python actions.
+	</longdescription>
+ 
+ <origin>gentoo-staging</origin>
+</pkgmetadata>
\ No newline at end of file
diff --git a/dev-java/antlr-tool/Manifest b/dev-java/antlr-tool/Manifest
new file mode 100644
index 000000000000..5af9733be86b
--- /dev/null
+++ b/dev-java/antlr-tool/Manifest
@@ -0,0 +1,2 @@
+DIST antlr-3.5.2.tar.gz 6927126 BLAKE2B 1907229549434dfea6ef1fa915137a2f733bd61f0a40aacb131689df619d1c92e125453ec3d1febc5d92da1841ffbde060af196cff1ca8fb6f4684600375e161 SHA512 e2a0520093fb2a77dcd9d44f26a9fdd612dceaffb398c53b2b8cd29f4630830647ede29e8dd55b434cb2c165b0fd1d77968ec6e6de0798f14d9cdfd9e6fccd99
+DIST antlr-tool-3.5.2-sources.jar 957096 BLAKE2B 39b75824e129c8111f302eb71407a683c59e91e79a3fa13c5386c4ba4aa322e706deb10b36df3591ab0843faff5702091d543272ee85d63cd92cb36cc72e1ceb SHA512 50fece361b69299be0c0941e6fe2bfacfc39c0b3dad3320126a9a80cd0f053fbaa6332612e2bab2872db122025d6abfe4b35a4636ef1c101e9131bbd2cdf5e28
diff --git a/dev-java/antlr-tool/antlr-tool-3.5.2.ebuild b/dev-java/antlr-tool/antlr-tool-3.5.2.ebuild
new file mode 100644
index 000000000000..214b8c4d199c
--- /dev/null
+++ b/dev-java/antlr-tool/antlr-tool-3.5.2.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# Artifact ID for antlr-tool is 'antlr'
+# https://github.com/antlr/antlr3/blob/3.5.2/tool/pom.xml#L4
+MAVEN_ID="org.antlr:antlr:3.5.2"
+
+JAVA_PKG_IUSE="doc source test"
+JAVA_TESTING_FRAMEWORKS="junit-4"
+
+inherit java-pkg-2 java-pkg-simple
+
+MY_PN="${PN%-tool}"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="The ANTLR 3 tool"
+HOMEPAGE="https://www.antlr3.org/"
+# Maven Central sources JAR for *.java sources pre-generated from *.g files;
+# the source generation requires this package itself.
+# Tarball for resources, the test suite, and DOCS files
+SRC_URI="
+	https://repo1.maven.org/maven2/org/antlr/antlr/${PV}/${MY_P}-sources.jar -> ${P}-sources.jar
+	https://github.com/antlr/antlr3/archive/${PV}.tar.gz -> ${MY_P}.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="3.5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+CP_DEPEND="
+	~dev-java/antlr-runtime-${PV}:${SLOT}
+	dev-java/stringtemplate:4
+"
+
+BDEPEND="
+	app-arch/unzip
+"
+
+DEPEND="
+	>=virtual/jdk-1.8:*
+	${CP_DEPEND}
+"
+
+RDEPEND="
+	>=virtual/jre-1.8:*
+	${CP_DEPEND}
+"
+
+S="${WORKDIR}"
+TARBALL_S="${S}/${MY_PN}3-${PV}"
+
+JAVA_SRC_DIR="org"
+JAVA_RESOURCE_DIRS=( "${TARBALL_S}/tool/src/main/resources" )
+
+JAVA_TEST_GENTOO_CLASSPATH="junit-4"
+JAVA_TEST_SRC_DIR="${TARBALL_S}/tool/src/test/java"
+
+DOCS=( "${TARBALL_S}/tool/CHANGES.txt" )
+
+src_prepare() {
+	java-pkg_clean
+	eapply -p0 "${FILESDIR}/${PV}-test-fixes.patch"
+	java-pkg-2_src_prepare
+
+	# Some tests fail under Java 8 in ways that probably aren't limited
+	# to the tests. This is bad but upstream is never going to update
+	# 3.5. At the time of writing, we only use it to build 4 anyway.
+	rm -v "${JAVA_TEST_SRC_DIR}/org/antlr/test/"Test{DFAConversion,SemanticPredicates,TopologicalSort}.java || die
+}
+
+src_install() {
+	java-pkg-simple_src_install
+	einstalldocs # https://bugs.gentoo.org/789582
+}
diff --git a/dev-java/antlr-tool/files/3.5.2-test-fixes.patch b/dev-java/antlr-tool/files/3.5.2-test-fixes.patch
new file mode 100644
index 000000000000..f2609ac1f0b5
--- /dev/null
+++ b/dev-java/antlr-tool/files/3.5.2-test-fixes.patch
@@ -0,0 +1,36 @@
+diff -Naur antlr3-3.5.2.orig/tool/src/test/java/org/antlr/test/TestAttributes.java antlr3-3.5.2/tool/src/test/java/org/antlr/test/TestAttributes.java
+--- antlr3-3.5.2.orig/tool/src/test/java/org/antlr/test/TestAttributes.java	2014-03-25 11:47:54.000000000 +0000
++++ antlr3-3.5.2/tool/src/test/java/org/antlr/test/TestAttributes.java	2015-10-02 22:42:56.921263410 +0100
+@@ -2131,7 +2132,7 @@
+ 		assertEquals(expecting, found);
+ 	}
+ 
+-	@Test public void testRuleLabelOnTwoDifferentRulesTemplate() throws Exception {
++	@org.junit.Ignore @Test public void testRuleLabelOnTwoDifferentRulesTemplate() throws Exception {
+ 		String grammar =
+ 			"grammar T;\n"+
+ 				"options {output=template;}\n"+
+diff -Naur antlr3-3.5.2.orig/tool/src/test/java/org/antlr/test/TestSyntacticPredicateEvaluation.java antlr3-3.5.2/tool/src/test/java/org/antlr/test/TestSyntacticPredicateEvaluation.java
+--- antlr3-3.5.2.orig/tool/src/test/java/org/antlr/test/TestSyntacticPredicateEvaluation.java	2014-03-25 11:47:54.000000000 +0000
++++ antlr3-3.5.2/tool/src/test/java/org/antlr/test/TestSyntacticPredicateEvaluation.java	2015-10-02 22:43:07.303105023 +0100
+@@ -339,7 +340,7 @@
+ 		assertEquals("b:alt 2 a:alt 1\n", found);
+ 	}
+ 
+-	@Test public void testSynPredWithOutputTemplate() throws Exception {
++	@org.junit.Ignore @Test public void testSynPredWithOutputTemplate() throws Exception {
+ 		// really just seeing if it will compile
+ 		String grammar =
+ 			"grammar T;\n" +
+diff -Naur antlr3-3.5.2.orig/tool/src/test/java/org/antlr/test/TestTreeParsing.java antlr3-3.5.2/tool/src/test/java/org/antlr/test/TestTreeParsing.java
+--- antlr3-3.5.2.orig/tool/src/test/java/org/antlr/test/TestTreeParsing.java	2014-03-25 11:47:54.000000000 +0000
++++ antlr3-3.5.2/tool/src/test/java/org/antlr/test/TestTreeParsing.java	2015-10-02 22:41:32.235554776 +0100
+@@ -141,7 +142,7 @@
+ 		assertEquals("alt 1\n", found);
+ 	}
+ 
+-	@Test public void testTemplateOutput() throws Exception {
++	@org.junit.Ignore @Test public void testTemplateOutput() throws Exception {
+ 		String grammar =
+ 			"grammar T;\n" +
+ 			"options {output=AST;}\n" +
diff --git a/dev-java/antlr-tool/metadata.xml b/dev-java/antlr-tool/metadata.xml
new file mode 100644
index 000000000000..e25b5c52aab3
--- /dev/null
+++ b/dev-java/antlr-tool/metadata.xml
@@ -0,0 +1,10 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
+<pkgmetadata>
+ <maintainer type="project">
+  <email>java@gentoo.org</email>
+  <name>Java</name>
+ </maintainer>
+ 
+ <origin>gentoo-staging</origin>
+</pkgmetadata>
\ No newline at end of file
diff --git a/dev-java/antlr/antlr-3.5.2-r2.ebuild b/dev-java/antlr/antlr-3.5.2-r2.ebuild
new file mode 100644
index 000000000000..c085043de3e4
--- /dev/null
+++ b/dev-java/antlr/antlr-3.5.2-r2.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit java-pkg-2
+
+DESCRIPTION="A parser generator for many languages"
+HOMEPAGE="https://www.antlr3.org/"
+# Reuse tarball for DOCS files
+SRC_URI="https://github.com/${PN}/${PN}3/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="3.5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+CP_DEPEND="
+	~dev-java/antlr-runtime-${PV}:${SLOT}
+	~dev-java/antlr-tool-${PV}:${SLOT}
+"
+
+DEPEND="
+	>=virtual/jdk-1.8:*
+	${CP_DEPEND}
+"
+
+RDEPEND="
+	>=virtual/jre-1.8:*
+	${CP_DEPEND}
+"
+
+S="${WORKDIR}/${PN}3-${PV}"
+
+DOCS=( contributors.txt README.txt )
+
+src_compile() {
+	:
+}
+
+src_install() {
+	java-pkg_regjar "$(java-pkg_getjar antlr-runtime-3.5 antlr-runtime.jar)"
+	java-pkg_regjar "$(java-pkg_getjar antlr-tool-3.5 antlr-tool.jar)"
+
+	java-pkg_dolauncher ${PN}${SLOT} --main org.antlr.Tool
+	einstalldocs # https://bugs.gentoo.org/789582
+}
+
+pkg_postinst() {
+	# If upgrading from a version of this slot that installs JARs,
+	# display a message about submodule split
+	local changed_ver="3.5.2-r2"
+	local should_show_msg
+	for replaced_ver in ${REPLACING_VERSIONS}; do
+		if ver_test "${replaced_ver}" -lt "${changed_ver}"; then
+			should_show_msg=1
+			break
+		fi
+	done
+	[[ "${should_show_msg}" ]] || return
+	elog "Since version ${changed_ver}, ${PN}-${SLOT} no longer installs JARs."
+	elog "Please find the JARs from files installed by submodule packages"
+	elog "antlr-runtime-${SLOT} and antlr-tool-${SLOT}."
+}
diff --git a/dev-java/emma/emma-2.0.5312-r4.ebuild b/dev-java/emma/emma-2.0.5312-r4.ebuild
new file mode 100644
index 000000000000..5e00f2ec4a50
--- /dev/null
+++ b/dev-java/emma/emma-2.0.5312-r4.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+JAVA_PKG_IUSE="source"
+
+inherit java-pkg-2 java-ant-2
+
+DESCRIPTION="Free Java code coverage tool"
+HOMEPAGE="http://emma.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}-src.zip"
+
+LICENSE="CPL-1.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+
+IUSE="+launcher"
+
+CDEPEND="
+	dev-java/ant-core
+	launcher? ( !sci-biology/emboss )"
+
+RDEPEND="
+	${CDEPEND}
+	>=virtual/jre-1.8:*"
+
+DEPEND="
+	${CDEPEND}
+	>=virtual/jdk-1.8:*"
+
+BDEPEND="app-arch/unzip"
+
+EANT_BUILD_TARGET="build"
+
+src_prepare() {
+	default
+	eapply "${FILESDIR}/${P}-java15api.patch"
+	# bcp mangling unneccessary for 1.4+ and breaks with IBM 1.6 - bug #220463
+	sed -e '/bootclasspathref/d' -e '/extdirs/d' -i build.xml || die
+}
+
+src_install() {
+	java-pkg_dojar "dist/${PN}.jar"
+	java-pkg_dojar "dist/${PN}_ant.jar"
+	java-pkg_register-ant-task
+
+	use launcher && java-pkg_dolauncher ${PN} --main emmarun
+
+	# One of these does not have java sources
+	use source && java-pkg_dosrc */*/com 2> /dev/null
+}
diff --git a/dev-java/gson/gson-2.8.8.ebuild b/dev-java/gson/gson-2.8.8.ebuild
index ae03a8f412f6..7386f72f7761 100644
--- a/dev-java/gson/gson-2.8.8.ebuild
+++ b/dev-java/gson/gson-2.8.8.ebuild
@@ -18,7 +18,7 @@ SRC_URI="https://github.com/google/${PN}/archive/${PN}-parent-${PV}.tar.gz -> ${
 
 LICENSE="Apache-2.0"
 SLOT="2.6"
-KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+KEYWORDS="amd64 ~arm ~arm64 ~ppc64 x86"
 
 # Compile dependencies
 # POM: ${PN}/pom.xml
diff --git a/dev-java/stringtemplate/Manifest b/dev-java/stringtemplate/Manifest
index 7b192ce400f9..1466c75ff71b 100644
--- a/dev-java/stringtemplate/Manifest
+++ b/dev-java/stringtemplate/Manifest
@@ -1,3 +1,5 @@
+DIST ST4-4.3.1-sources.jar 198002 BLAKE2B d1bd78dac71800e342291920ba78ab39c9a43b1f3866e2afcb0e1d61d439592663a625efe2a5a215c6032469e7ebeeebb31267e1681536ca0cc524cc58781a3d SHA512 bd06940b629ab0378afd6342b6f5beef002023387843cefd866ebe6ae8e94996edc3f21a0c70ed3570d3fcb7194bf354d0e42d4eff32522b3c01c51369867be0
 DIST antlr-3.5.2-complete.jar 2456317 BLAKE2B d9afa08ad98dbff16d30425b97a0ddac7402055916e6a7dd290c3b9a2b26a4751c02f405d8d13c186333430c370c94bd73419b14c8e46df2971f68536cc484a0 SHA512 560f208e38759b5e626de56816e1fce9c191c526c04ca782513859d468ac444d1e8e62c03870a68f8f9d8daee0f45fca465150e2bbfc71b46e46b952519044b1
 DIST stringtemplate-3.2.1.tar.gz 107877 BLAKE2B e099aaef047de12706ca4c771f28742dc48ec14a577b2384b32850e304b29284436b3c850846136cbd37481ff48cfb2fd5935d2de3aafa5c817ae24f62579435 SHA512 76203182302d42a0f79de7e8a22f44c59ddc5604761034e420b6973894e0ca1e6154cbcb322ec6f9a064ee89cc5f6478b775a716692c80c7f0c77566aa8a0e25
 DIST stringtemplate-4.0.8.tar.gz 147305 BLAKE2B 0c09326f4eecfc86db8588a9b8db801bac8d8e128f8ef004a3691813d1dfcbd1e397acd5cad47e4c9d44d7ee8c17b8f6b66386fb897e4137df43dc46f46dc3f3 SHA512 21e4936356a6d374bf92645f09351a495a5900a408ead8dce1903ed81d7fc70eb4b44b206b587b05ed87edb2d4792c1cf72907a9cb527e18373ba2e5f31b5724
+DIST stringtemplate-4.3.1.tar.gz 432541 BLAKE2B c5b4124524e36a7104908dabf9ed258d2397095d8dc86eef401d0da1ac245629e88a1b2d0e35417ed7735ad6b8495fd2cc82970601a16ee856f5456fdc24b48f SHA512 afe62ca1cbc7572d05859c6fdaa1eb3221045da582bce5d88c328acae39128c904396f8ba1e10643a2757123297ba1924e046841cc8a667fbc724bdeca95680c
diff --git a/dev-java/stringtemplate/files/stringtemplate-4.3.1-BaseTest-javac-source-target.patch b/dev-java/stringtemplate/files/stringtemplate-4.3.1-BaseTest-javac-source-target.patch
new file mode 100644
index 000000000000..5824425ce35b
--- /dev/null
+++ b/dev-java/stringtemplate/files/stringtemplate-4.3.1-BaseTest-javac-source-target.patch
@@ -0,0 +1,28 @@
+From 4e12a210f2b933c92ded6ee141f6399144a866f5 Mon Sep 17 00:00:00 2001
+From: Yuan Liao <liaoyuan@gmail.com>
+Date: Mon, 24 Jan 2022 06:17:03 -0800
+Subject: [PATCH] BaseTest.java: Change javac source/target to 1.8 for JDK 17
+
+JDK 17 no longer supports 1.6 as the source or target version.
+
+Signed-off-by: Yuan Liao <liaoyuan@gmail.com>
+---
+ test/org/stringtemplate/v4/test/BaseTest.java | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+diff --git a/test/org/stringtemplate/v4/test/BaseTest.java b/test/org/stringtemplate/v4/test/BaseTest.java
+index 536d686..74a3949 100644
+--- a/test/org/stringtemplate/v4/test/BaseTest.java
++++ b/test/org/stringtemplate/v4/test/BaseTest.java
+@@ -258,7 +258,7 @@ public abstract class BaseTest {
+             fileManager.getJavaFileObjectsFromFiles(files);
+ 
+         Iterable<String> compileOptions =
+-            Arrays.asList("-g", "-source", "1.6", "-target", "1.6", "-implicit:class", "-Xlint:-options", "-d", workingDirName, "-cp", workingDirName+pathSep+CLASSPATH);
++            Arrays.asList("-g", "-source", "1.8", "-target", "1.8", "-implicit:class", "-Xlint:-options", "-d", workingDirName, "-cp", workingDirName+pathSep+CLASSPATH);
+ 
+         JavaCompiler.CompilationTask task =
+             compiler.getTask(null, fileManager, null, compileOptions, null,
+-- 
+2.34.1
+
diff --git a/dev-java/stringtemplate/stringtemplate-4.3.1.ebuild b/dev-java/stringtemplate/stringtemplate-4.3.1.ebuild
new file mode 100644
index 000000000000..3eb42e302549
--- /dev/null
+++ b/dev-java/stringtemplate/stringtemplate-4.3.1.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+JAVA_PKG_IUSE="doc source test"
+MAVEN_ID="org.antlr:ST4:4.3.1"
+JAVA_TESTING_FRAMEWORKS="junit-4"
+
+inherit java-pkg-2 java-pkg-simple
+
+DESCRIPTION="A Java template engine"
+HOMEPAGE="https://www.stringtemplate.org/"
+# Maven Central sources JAR for *.java sources pre-generated from *.g files;
+# the source generation requires antlr-tool-3.5, which depends on this package.
+# Tarball for the test suite and DOCS files
+SRC_URI="
+	https://repo1.maven.org/maven2/org/antlr/ST4/${PV}/ST4-${PV}-sources.jar
+	https://github.com/antlr/${PN}4/archive/${PV}.tar.gz -> ${P}.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="4"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86 ~amd64-linux ~x86-linux ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+CP_DEPEND="
+	dev-java/antlr-runtime:3.5
+"
+
+BDEPEND="
+	app-arch/unzip
+"
+
+DEPEND="
+	>=virtual/jdk-1.8:*
+	${CP_DEPEND}
+	test? (
+		dev-java/antlr-tool:3.5
+	)
+"
+
+RDEPEND="
+	>=virtual/jre-1.8:*
+	${CP_DEPEND}
+"
+
+S="${WORKDIR}"
+TARBALL_S="${S}/${PN}4-${PV}"
+
+JAVA_SRC_DIR="org"
+
+JAVA_TEST_GENTOO_CLASSPATH="junit-4,antlr-tool-3.5"
+JAVA_TEST_SRC_DIR="${TARBALL_S}/test"
+
+DOCS=( "${TARBALL_S}/"{CHANGES.txt,contributors.txt,README.md} )
+
+src_prepare() {
+	java-pkg_clean # Just in case Maven Central sources JAR contains binary
+	if use test; then
+		pushd "${TARBALL_S}" > /dev/null ||
+			die "Failed to enter directory storing tarball contents"
+		eapply "${FILESDIR}/${P}-BaseTest-javac-source-target.patch"
+		popd > /dev/null ||
+			die "Failed to leave directory storing tarball contents"
+	fi
+	java-pkg-2_src_prepare
+	# Some of these tests requires a graphical display.
+	rm -v "${JAVA_TEST_SRC_DIR}/org/stringtemplate/v4/test/TestEarlyEvaluation.java" || die
+}
+
+src_install() {
+	java-pkg-simple_src_install
+	einstalldocs # https://bugs.gentoo.org/789582
+}