Revert "Adding metadata"

This reverts commit f716a9fe6455d39eef01e718aae68dae61c19704.

4 files changed, 182 insertions, 0 deletions

diff --git a/dev-java/java-config/Manifest b/dev-java/java-config/Manifest
new file mode 100644
index 000000000000..b2a3450eed9c
--- /dev/null
+++ b/dev-java/java-config/Manifest
@@ -0,0 +1 @@
+DIST java-config-2.3.4.tar.gz 33833 BLAKE2B 36cb628375a05530f515d886d819bc99a7ed233bec2956db3562349ae845be57363a2b6629ab5536be15c5f64387d0760cca7959b76a5685918732ee7bf62300 SHA512 9df42a70aceb400a9fab73668151da783e98e767fa6289c13427095d7a3268bd4bb15de9ef980b82692e7c1cb0eaf5326c19a632679419d78a419294579fb29e
diff --git a/dev-java/java-config/java-config-2.3.4.ebuild b/dev-java/java-config/java-config-2.3.4.ebuild
new file mode 100644
index 000000000000..a1e91cb5214f
--- /dev/null
+++ b/dev-java/java-config/java-config-2.3.4.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit meson python-r1
+
+if [[ ${PV} = 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/java-config.git"
+else
+	SRC_URI="https://gitweb.gentoo.org/proj/${PN}.git/snapshot/${P}.tar.gz"
+	KEYWORDS="amd64 ~arm arm64 ppc64 ~riscv x86 ~x64-macos ~x64-solaris"
+fi
+
+DESCRIPTION="Java environment configuration query tool"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Project:Java"
+
+LICENSE="GPL-2"
+SLOT="2"
+IUSE="+compat test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="test? ( sys-apps/portage[${PYTHON_USEDEP}] )"
+
+# baselayout-java is added as a dep till it can be added to eclass.
+RDEPEND="
+	${PYTHON_DEPS}
+	sys-apps/baselayout-java
+	sys-apps/portage[${PYTHON_USEDEP}]
+"
+
+src_configure() {
+	local python_only=false
+	python_foreach_impl my_src_configure
+}
+
+my_src_configure() {
+	local emesonargs=(
+		-Darch="${ARCH}"
+		-Dpython-only="${python_only}"
+		-Deprefix="${EPREFIX}"
+	)
+
+	meson_src_configure
+	python_only=true
+}
+
+src_compile() {
+	python_foreach_impl meson_src_compile
+}
+
+src_test() {
+	python_foreach_impl meson_src_test --no-rebuild --verbose
+}
+
+src_install() {
+	python_foreach_impl my_src_install
+
+	local scripts
+	mapfile -t scripts < <(awk '/^#!.*python/ {print FILENAME} {nextfile}' "${ED}"/usr/bin/* || die)
+	python_replicate_script "${scripts[@]}"
+
+	if use compat; then
+		# Symlink java-config-2 to java-config for now.
+		dosym java-config /usr/bin/java-config-2
+	fi
+}
+
+my_src_install() {
+	meson_src_install
+
+	local pydirs=(
+		"${D}$(python_get_sitedir)"
+	)
+	python_optimize "${pydirs[@]}"
+}
diff --git a/dev-java/java-config/java-config-9999.ebuild b/dev-java/java-config/java-config-9999.ebuild
new file mode 100644
index 000000000000..08875aa8d005
--- /dev/null
+++ b/dev-java/java-config/java-config-9999.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit meson python-r1
+
+if [[ ${PV} = 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/java-config.git"
+else
+	SRC_URI="https://gitweb.gentoo.org/proj/${PN}.git/snapshot/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86 ~x64-macos ~x64-solaris"
+fi
+
+DESCRIPTION="Java environment configuration query tool"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Project:Java"
+
+LICENSE="GPL-2"
+SLOT="2"
+IUSE="+compat test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="test? ( sys-apps/portage[${PYTHON_USEDEP}] )"
+
+# baselayout-java is added as a dep till it can be added to eclass.
+RDEPEND="
+	${PYTHON_DEPS}
+	sys-apps/baselayout-java
+	sys-apps/portage[${PYTHON_USEDEP}]
+"
+
+src_configure() {
+	local python_only=false
+	python_foreach_impl my_src_configure
+}
+
+my_src_configure() {
+	local emesonargs=(
+		-Darch="${ARCH}"
+		-Dpython-only="${python_only}"
+		-Deprefix="${EPREFIX}"
+	)
+
+	meson_src_configure
+	python_only=true
+}
+
+src_compile() {
+	python_foreach_impl meson_src_compile
+}
+
+src_test() {
+	python_foreach_impl meson_src_test --no-rebuild --verbose
+}
+
+src_install() {
+	python_foreach_impl my_src_install
+
+	local scripts
+	mapfile -t scripts < <(awk '/^#!.*python/ {print FILENAME} {nextfile}' "${ED}"/usr/bin/* || die)
+	python_replicate_script "${scripts[@]}"
+
+	if use compat; then
+		# Symlink java-config-2 to java-config for now.
+		dosym java-config /usr/bin/java-config-2
+	fi
+}
+
+my_src_install() {
+	meson_src_install
+
+	local pydirs=(
+		"${D}$(python_get_sitedir)"
+	)
+	python_optimize "${pydirs[@]}"
+}
diff --git a/dev-java/java-config/metadata.xml b/dev-java/java-config/metadata.xml
new file mode 100644
index 000000000000..faeac11b5e48
--- /dev/null
+++ b/dev-java/java-config/metadata.xml
@@ -0,0 +1,21 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>java@gentoo.org</email>
+		<name>Java</name>
+	</maintainer>
+	<longdescription>
+		java-config is used to configure the Java subsystem on your Gentoo
+		installation. In particular, it can be used to configure system-wide and
+		per-user default JVMs, construct classpath env vars from installed java
+		packages and be used to query for the path to various JDK tools.
+	</longdescription>
+	<use>
+		<flag name="compat">Install bin/java-config-2 symlink pointing to java-config</flag>
+	</use>
+	<upstream>
+		<remote-id type="gentoo">proj/java-config</remote-id>
+		<remote-id type="github">gentoo/java-config</remote-id>
+	</upstream>
+</pkgmetadata>