Adding metadata

4 files changed, 167 insertions, 7 deletions

diff --git a/dev-embedded/pico-sdk/Manifest b/dev-embedded/pico-sdk/Manifest
new file mode 100644
index 000000000000..f87ad10d1851
--- /dev/null
+++ b/dev-embedded/pico-sdk/Manifest
@@ -0,0 +1,6 @@
+DIST btstack-501e6d2b86e6c92bfb9c390bcf55709938e25ac1.tar.gz 54737745 BLAKE2B 012432d83c46cf11386a51a7714ec68cca632597f7cf3376635472d90f003e83653d3b8373e08a47a4a191cca8cfaad9f55ab113352bce8003f3c93cdb599421 SHA512 4aa70c23bad0b90ad663fbe3bfb1ee49a8cda6b0a4b1178afcc29709dd00ae01ace256f6a180a1cf9ef1bc722cbe2b2bb564b046f04c844f557fa1a187287c26
+DIST cyw43-driver-c1075d4bc440422cf2b2fd12c64a1f53f77660ee.tar.gz 1520548 BLAKE2B acf5da64ab755dd4279ac8865dbce425f110ad9198433b23e32203603bf08a6c045aa6dd304ee562c211d1dbd43e243f3e7749d56b7634fd8befae92e1fe6bc1 SHA512 a79b067f3a2d19f4bd025939662baa287ad7fbb848cdec69b62e0269300a6577415aaaa74082ecea33a210c5c1a2868d2be85c85cb9fc9cddf11dcad1e4d0360
+DIST lwip-STABLE-2_2_0_RELEASE.tar.gz 1592352 BLAKE2B be91fdf775bad7ec8824af7000c446a6c5eef007bd01af53eccffee4915fe9bd5436056c862e36aed7fd89133dd2e234ed74bf0389e67e19d018ba3c2688bf13 SHA512 df60b14ee50ee2ab5e3fc07844f44b9b0698cc581407a22b05a2da834a23b9a946ea46e30e373b64694999920bc06b2787c733623a459591d66f88ee3470f86b
+DIST mbedtls-2.28.8.tar.bz2 3343796 BLAKE2B 1efde6698662873c40df9733bae902db4e009f3dd26a937e05707ca1a208b71675df0737b44b5895a60cfbf42f18f92dae88cba62f32b55733947b9c0481880e SHA512 c8e91ec50ab2caf1f33e907279dc30fca2a8cd97e6e531be857149589e52aeffb95b445b2a9fa674886f0071f446381da3bb8107f7e850f3390128b069ac9ea7
+DIST pico-sdk-2.1.1.tar.gz 2437119 BLAKE2B 3c165355221e4b3855df79cc2da28bd97143731ac2c6e4168ccfee5826d0c2b8c17f0173c6d01fcd7e396c04c95733fd107063ecda92c1f32e31cb964ec7f4ea SHA512 1a827d0783c2bf22a225dd924f95a0d766ecdb21f4f4eb4531e3c1d00c76f79d94f5fa3f97c5de84197c158508a8659f3cbe8ff4bee644c0fffc42c67a2d3102
+DIST tinyusb-0.18.0.tar.gz 3282996 BLAKE2B 32e20a22e6f7a705047c25773b5b404150e8f7d58fc1997b27330039307d196fd1173dbd551c57d375083e1dbd6a3f91a54229bd62e3d479313526b2857d53a8 SHA512 2fc854a32a43879af9b2ffcd934632fbf51df51c274859372548bbb049a02fbea6667060488a9cae9caf91e1ef8b047be9aab715fc04d8fed8b4c36d3fed965c
diff --git a/dev-embedded/pico-sdk/pico-sdk-2.1.1.ebuild b/dev-embedded/pico-sdk/pico-sdk-2.1.1.ebuild
index 81776c20c54a..d438436e49ff 100644
--- a/dev-embedded/pico-sdk/pico-sdk-2.1.1.ebuild
+++ b/dev-embedded/pico-sdk/pico-sdk-2.1.1.ebuild
@@ -3,22 +3,46 @@
 
 EAPI=8
 
-inherit git-r3
-
 DESCRIPTION="Libraries and tools for C/C++ development on RP2040 and RP2350 microcontrollers."
 HOMEPAGE="https://github.com/raspberrypi/pico-sdk"
 
-EGIT_REPO_URI="https://github.com/raspberrypi/pico-sdk.git"
-EGIT_BRANCH="master"
-EGIT_COMMIT="${PV}"
+SRC_URI="
+	https://github.com/raspberrypi/pico-sdk/releases/download/${PV}/${P}.tar.gz
+		-> ${P}.tar.gz
+
+	https://github.com/bluekitchen/btstack/archive/501e6d2b86e6c92bfb9c390bcf55709938e25ac1.tar.gz
+		-> btstack-501e6d2b86e6c92bfb9c390bcf55709938e25ac1.tar.gz
+
+	https://github.com/georgerobotics/cyw43-driver/archive/c1075d4bc440422cf2b2fd12c64a1f53f77660ee.tar.gz
+		-> cyw43-driver-c1075d4bc440422cf2b2fd12c64a1f53f77660ee.tar.gz
+
+	https://github.com/lwip-tcpip/lwip/archive/refs/tags/STABLE-2_2_0_RELEASE.tar.gz
+		-> lwip-STABLE-2_2_0_RELEASE.tar.gz
+
+	https://github.com/Mbed-TLS/mbedtls/releases/download/v2.28.8/mbedtls-2.28.8.tar.bz2
+		-> mbedtls-2.28.8.tar.bz2
+
+	https://github.com/hathach/tinyusb/archive/refs/tags/0.18.0.tar.gz
+		-> tinyusb-0.18.0.tar.gz
+"
 
 LICENSE="BSD"
 SLOT="0"
+KEYWORDS="~amd64"
+
+src_prepare() {
+	default
+
+	cp -r "${WORKDIR}"/btstack-501e6d2b86e6c92bfb9c390bcf55709938e25ac1/. "${S}/lib/btstack" || die
+	cp -r "${WORKDIR}"/cyw43-driver-c1075d4bc440422cf2b2fd12c64a1f53f77660ee/. "${S}/lib/cyw43-driver" || die
+	cp -r "${WORKDIR}"/lwip-STABLE-2_2_0_RELEASE/. "${S}/lib/lwip" || die
+	cp -r "${WORKDIR}"/mbedtls-2.28.8/. "${S}/lib/mbedtls" || die
+	cp -r "${WORKDIR}"/tinyusb-0.18.0/. "${S}/lib/tinyusb" || die
+}
 
 src_install() {
 	dodir /opt/pico-sdk
-	cp -r "${S}/." "${D}/opt/pico-sdk/"
-	find "${D}/opt/pico-sdk" -type d -name ".git" -exec rm -rf '{}' +
+	cp -r "${S}/." "${D}/opt/pico-sdk/" || die
 
 	echo "PICO_SDK_PATH=/opt/pico-sdk" > "${T}/99pico-sdk" || die
 	doenvd "${T}/99pico-sdk"
diff --git a/dev-embedded/rpi-openocd/metadata.xml b/dev-embedded/rpi-openocd/metadata.xml
new file mode 100644
index 000000000000..2011439cbad0
--- /dev/null
+++ b/dev-embedded/rpi-openocd/metadata.xml
@@ -0,0 +1,21 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
+<pkgmetadata>
+ <maintainer type="person">
+  <email>ljn0099@hotmail.com</email>
+  <name>Manuel</name>
+ </maintainer>
+ 
+ <use>
+  <flag name="capstone">Support for ARM disassembly via dev-libs/capstone</flag>
+  <flag name="cmsis-dap">Support for CMSIS-DAP adapter driver via dev-libs/hidapi</flag>
+  <flag name="dummy">Build the dummy port driver</flag>
+  <flag name="ftdi">Support for USB FTDI chips via dev-embedded/libftdi</flag>
+  <flag name="gpiod">Support for linuxgpiod driver via dev-libs/libgpiod</flag>
+  <flag name="jlink">Support for J-Link driver via dev-embedded/libjaylink</flag>
+  <flag name="parport">Support for parport JTAG devices</flag>
+  <flag name="verbose-io">Verbose IO and comm JTAG and USB messages</flag>
+  <flag name="usb">Support for the USB-based drivers</flag>
+ </use>
+ <origin>gentoo-guru-overlay</origin>
+</pkgmetadata>
\ No newline at end of file
diff --git a/dev-embedded/rpi-openocd/rpi-openocd-9999.ebuild b/dev-embedded/rpi-openocd/rpi-openocd-9999.ebuild
new file mode 100644
index 000000000000..d28770dfc0ec
--- /dev/null
+++ b/dev-embedded/rpi-openocd/rpi-openocd-9999.ebuild
@@ -0,0 +1,109 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools git-r3 udev
+
+DESCRIPTION="OpenOCD - Open On-Chip Debugger (Raspberry Pi Fork)"
+HOMEPAGE="https://github.com/raspberrypi/openocd"
+
+EGIT_REPO_URI="https://github.com/raspberrypi/openocd.git"
+EGIT_BRANCH="rpi-common"
+EGIT_SUBMODULES=()
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="capstone +cmsis-dap dummy +ftdi gpiod +jlink parport +usb verbose-io"
+RESTRICT="strip"
+
+DEPEND="
+	acct-group/plugdev
+	>=dev-lang/jimtcl-0.79
+	capstone? ( dev-libs/capstone )
+	cmsis-dap? ( dev-libs/hidapi )
+	ftdi? ( dev-embedded/libftdi:= )
+	gpiod? ( dev-libs/libgpiod:0/2 )
+	jlink? ( >=dev-embedded/libjaylink-0.2.0 )
+	usb? ( virtual/libusb:1 )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	default
+
+	AT_NO_RECURSIVE=yes eautoreconf
+}
+
+src_configure() {
+	local myconf=(
+		--program-prefix=rpi-
+		--datadir=/usr/share/openocd-rpi
+		--infodir=/usr/share/info/rpi-openocd
+		--docdir=/usr/share/doc/rpi-openocd
+		--enable-amtjtagaccel
+		--enable-am335xgpio
+		--enable-arm-jtag-ew
+		--enable-at91rm9200
+		--enable-bcm2835gpio
+		--enable-buspirate
+		--enable-ep93xx
+		--enable-gw16012
+		--enable-jtag_dpi
+		--enable-sysfsgpio
+		--enable-vdebug
+		--disable-internal-jimtcl
+		--disable-internal-libjaylink
+		--disable-parport-giveio
+		--disable-werror
+		$(use_with capstone)
+		$(use_enable cmsis-dap)
+		$(use_enable dummy)
+		$(use_enable ftdi openjtag)
+		$(use_enable ftdi presto)
+		$(use_enable ftdi usb-blaster)
+		$(use_enable gpiod linuxgpiod)
+		$(use_enable jlink)
+		$(use_enable parport)
+		$(use_enable parport parport_ppdev)
+		$(use_enable usb aice)
+		$(use_enable usb armjtagew)
+		$(use_enable usb ftdi)
+		$(use_enable usb osbdm)
+		$(use_enable usb opendous)
+		$(use_enable usb rlink)
+		$(use_enable usb stlink)
+		$(use_enable usb ti-icdi)
+		$(use_enable usb usbprog)
+		$(use_enable usb usb-blaster-2)
+		$(use_enable usb ulink)
+		$(use_enable usb vsllink)
+		$(use_enable verbose-io verbose-jtag-io)
+		$(use_enable verbose-io verbose-usb-io)
+		$(use_enable verbose-io verbose_usb_comms)
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	dostrip /usr/bin
+
+	mv "${ED}/usr/share/openocd-rpi/openocd/contrib/60-openocd.rules" \
+		"${ED}/usr/share/openocd-rpi/openocd/contrib/60-openocd-rpi.rules" || die
+
+	udev_dorules "${ED}"/usr/share/openocd-rpi/openocd/contrib/*.rules
+}
+
+pkg_postinst() {
+	udev_reload
+
+	elog "To access openocd devices as user you must be in the plugdev group"
+	elog "Installed as rpi-openocd"
+}
+
+pkg_postrm() {
+	udev_reload
+}