Revert "Adding metadata"

This reverts commit f716a9fe6455d39eef01e718aae68dae61c19704.

4 files changed, 156 insertions, 0 deletions

diff --git a/dev-debug/drgn/Manifest b/dev-debug/drgn/Manifest
new file mode 100644
index 000000000000..09d4a727cea4
--- /dev/null
+++ b/dev-debug/drgn/Manifest
@@ -0,0 +1,2 @@
+DIST drgn-0.0.33.tar.gz 1674341 BLAKE2B 3995dd5c4b0242bea63e1fe40a031ac117376287b323da24286700d455ce8bacfee56dc7fc7fb873ef67295f47ae93b7f2ff56483ddd5cbe30ccc83f9e9f32af SHA512 163a281af90320287914b5544adb05f1dd5b96d9f2478df82f70f8258f30814c03be673fa9db177297b5fa1223c9923c041209c68b3df6e34f2b63b14fd74301
+DIST drgn-0.1.0.tar.gz 1850058 BLAKE2B 1556b67c59b565a94874eb88fa5cf3d30326560c4b599e45b750f74715d96fa0e4ae3675378503ecb4ae81a0e2bd2f810ff3cc4a1ccf1e6d0049aa2deeea2df2 SHA512 de17207b7badfc685c1a4d9593f9cd9e330ae6d7bf4f80628bf2b5c9d5c2a309b88bd05c0d46837aa9bacc5f3bd35711ed9226fbcaef1b6e37b3bb1830c652ca
diff --git a/dev-debug/drgn/drgn-0.0.33.ebuild b/dev-debug/drgn/drgn-0.0.33.ebuild
new file mode 100644
index 000000000000..7391a8237363
--- /dev/null
+++ b/dev-debug/drgn/drgn-0.0.33.ebuild
@@ -0,0 +1,68 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 multiprocessing pypi toolchain-funcs
+
+DESCRIPTION="Programmable debugger"
+HOMEPAGE="
+	https://github.com/osandov/drgn
+	https://pypi.org/project/drgn/
+	https://drgn.readthedocs.io/en/latest/
+"
+
+LICENSE="LGPL-2.1+"
+# Note that as of 0.0.31 at least, the API+ABI of libdrgn is unstable.
+SLOT="0/${PV}"
+KEYWORDS="~amd64"
+IUSE="debuginfod lzma openmp"
+
+DEPEND="
+	>=dev-libs/elfutils-0.165[debuginfod?]
+	dev-libs/libkdumpfile:=
+	lzma? ( app-arch/xz-utils )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	test? ( dev-libs/check )
+"
+
+distutils_enable_tests unittest
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_configure() {
+	tc-export AR CC OBJCOPY OBJDUMP PKG_CONFIG RANLIB STRIP
+
+	cat >> setup.cfg <<-EOF || die
+	[build_ext]
+	parallel = $(makeopts_jobs)
+	EOF
+
+	# setuptools calls autotools (!)
+	export CONFIGURE_FLAGS
+	CONFIGURE_FLAGS="--disable-dependency-tracking --disable-silent-rules"
+	CONFIGURE_FLAGS+=" --with-libkdumpfile"
+	CONFIGURE_FLAGS+=" --enable-libdrgn"
+	CONFIGURE_FLAGS+=" --enable-python-extension"
+	CONFIGURE_FLAGS+=" --disable-dlopen-debuginfod"
+	CONFIGURE_FLAGS+=" $(use_with debuginfod)"
+	CONFIGURE_FLAGS+=" $(use_with lzma)"
+	CONFIGURE_FLAGS+=" $(use_enable openmp)"
+	CONFIGURE_FLAGS+=" --build=${CBUILD}"
+	CONFIGURE_FLAGS+=" --host=${CHOST}"
+	CONFIGURE_FLAGS+=" --target=${CTARGET}"
+	distutils-r1_src_configure
+}
diff --git a/dev-debug/drgn/drgn-0.1.0.ebuild b/dev-debug/drgn/drgn-0.1.0.ebuild
new file mode 100644
index 000000000000..f43acbdec2a3
--- /dev/null
+++ b/dev-debug/drgn/drgn-0.1.0.ebuild
@@ -0,0 +1,70 @@
+# Copyright 2024-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 multiprocessing pypi toolchain-funcs
+
+DESCRIPTION="Programmable debugger"
+HOMEPAGE="
+	https://github.com/osandov/drgn
+	https://pypi.org/project/drgn/
+	https://drgn.readthedocs.io/en/latest/
+"
+
+LICENSE="LGPL-2.1+"
+# Note that as of 0.0.31 at least, the API+ABI of libdrgn is unstable.
+SLOT="0/${PV}"
+KEYWORDS="~amd64"
+IUSE="debuginfod lzma openmp pcre"
+
+DEPEND="
+	>=dev-libs/elfutils-0.165[debuginfod?]
+	dev-libs/libkdumpfile:=
+	lzma? ( app-arch/xz-utils )
+	pcre? ( dev-libs/libpcre2 )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	test? ( dev-libs/check )
+"
+
+distutils_enable_tests unittest
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_configure() {
+	tc-export AR CC OBJCOPY OBJDUMP PKG_CONFIG RANLIB STRIP
+
+	cat >> setup.cfg <<-EOF || die
+	[build_ext]
+	parallel = $(makeopts_jobs)
+	EOF
+
+	# setuptools calls autotools (!)
+	export CONFIGURE_FLAGS
+	CONFIGURE_FLAGS="--disable-dependency-tracking --disable-silent-rules"
+	CONFIGURE_FLAGS+=" --with-libkdumpfile"
+	CONFIGURE_FLAGS+=" --enable-libdrgn"
+	CONFIGURE_FLAGS+=" --enable-python-extension"
+	CONFIGURE_FLAGS+=" --disable-dlopen-debuginfod"
+	CONFIGURE_FLAGS+=" $(use_with debuginfod)"
+	CONFIGURE_FLAGS+=" $(use_with lzma)"
+	CONFIGURE_FLAGS+=" $(use_enable openmp)"
+	CONFIGURE_FLAGS+=" $(use_with pcre pcre2)"
+	CONFIGURE_FLAGS+=" --build=${CBUILD}"
+	CONFIGURE_FLAGS+=" --host=${CHOST}"
+	CONFIGURE_FLAGS+=" --target=${CTARGET}"
+	distutils-r1_src_configure
+}
diff --git a/dev-debug/drgn/metadata.xml b/dev-debug/drgn/metadata.xml
new file mode 100644
index 000000000000..93a3688bd14f
--- /dev/null
+++ b/dev-debug/drgn/metadata.xml
@@ -0,0 +1,16 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>sam@gentoo.org</email>
+		<name>Sam James</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="pypi">drgn</remote-id>
+		<remote-id type="github">osandov/drgn</remote-id>
+	</upstream>
+	<use>
+		<flag name="debuginfod">Enable debuginfod support</flag>
+		<flag name="lzma">Support XZ-compressed debug information (MiniDebugInfo).</flag>
+	</use>
+</pkgmetadata>