Adding metadata

6 files changed, 170 insertions, 2 deletions

diff --git a/dev-cpp/jwt-cpp/Manifest b/dev-cpp/jwt-cpp/Manifest
new file mode 100644
index 000000000000..056eade7e21c
--- /dev/null
+++ b/dev-cpp/jwt-cpp/Manifest
@@ -0,0 +1 @@
+DIST jwt-cpp-0.6.0.tar.gz 275126 BLAKE2B 4bf9bed9b2aa9584b497b2ab4d1d2582d9b5e4ded402200ea3f70b0e6752338fd4e2ef9c5836c728a6907a0190209c7baeaecd26032ce64dc6bf12a23594f27b SHA512 b6d5ebb3a7eeb6fef9a1d41c707251d1ab05bf47920c280d5203f1b9ee5bf6f8e914cd2ffaed66550cfa6d78c34465d4cf86517a759d5f8739b429faf1c2c0ef
diff --git a/dev-cpp/jwt-cpp/jwt-cpp-0.6.0.ebuild b/dev-cpp/jwt-cpp/jwt-cpp-0.6.0.ebuild
new file mode 100644
index 000000000000..c7f9802a739a
--- /dev/null
+++ b/dev-cpp/jwt-cpp/jwt-cpp-0.6.0.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/Thalhammer/jwt-cpp.git"
+else
+	SRC_URI="https://github.com/Thalhammer/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="header only library for creating and validating JSON Web Tokens in C++11"
+HOMEPAGE="https://thalhammer.github.io/jwt-cpp/"
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="doc +picojson test"
+
+DEPEND="
+	dev-cpp/nlohmann_json
+	dev-libs/openssl
+	picojson? ( dev-cpp/picojson )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	doc? ( app-doc/doxygen[dot] )
+	test? ( dev-cpp/gtest )
+"
+RESTRICT="
+	!picojson? ( test )
+	!test? ( test )
+"
+DOCS=( README.md docs/{faqs,ssl,traits}.md )
+
+src_prepare() {
+	# Unbundle dev-cpp/nlohmann_json.
+	rm -vrf include/nhlomann || die
+	# Unbundle dev-cpp/picojson and fix include paths.
+	# See also: https://github.com/Thalhammer/jwt-cpp/issues/213
+	rm -vrf include/picojson || die
+	find -name '*.h' -type f -print0 | xargs -0 sed -r -e "s:picojson/picojson\.h:picojson.h:g" -i || die
+	# Prevent installation of bundled dev-cpp/picojson.
+	sed -i -e 's:^\s*install.*picojson/picojson\.h.*$::' CMakeLists.txt || die
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+			-DJWT_DISABLE_PICOJSON="$(usex !picojson)"
+			# Not useful for now, asks for non-existent CMake module.
+			#-DJWT_EXTERNAL_PICOJSON="$(usex picojson)"
+			# Examples are not installed and for development only.
+			-DJWT_BUILD_EXAMPLES=NO
+			-DJWT_BUILD_TESTS="$(usex test)"
+			-DJWT_CMAKE_FILES_INSTALL_DIR="${EPREFIX}"/usr/share/cmake
+			)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+	if use doc; then
+		doxygen || die
+	fi
+}
+
+src_test() {
+	"${BUILD_DIR}"/tests/jwt-cpp-test || die
+}
+
+src_install() {
+	cmake_src_install
+	use doc && local HTML_DOCS=(doxy/html/.)
+	einstalldocs
+}
diff --git a/dev-cpp/jwt-cpp/metadata.xml b/dev-cpp/jwt-cpp/metadata.xml
new file mode 100644
index 000000000000..d9488b035eb5
--- /dev/null
+++ b/dev-cpp/jwt-cpp/metadata.xml
@@ -0,0 +1,23 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
+<pkgmetadata>
+ <maintainer type="person">
+  <email>o.freyermuth@googlemail.com</email>
+  <name>Oliver Freyermuth</name>
+ </maintainer>
+ <maintainer type="person">
+  <email>amadio@gentoo.org</email>
+  <name>Guilherme Amadio</name>
+ </maintainer>
+ <maintainer type="project">
+  <email>proxy-maint@gentoo.org</email>
+  <name>Proxy Maintainers</name>
+ </maintainer>
+ <upstream>
+  <bugs-to>https://github.com/Thalhammer/jwt-cpp/issues</bugs-to>
+ </upstream>
+ <use>
+  <flag name="picojson">Enable use of <pkg>dev-cpp/picojson</pkg></flag>
+ </use>
+ <origin>gentoo-staging</origin>
+</pkgmetadata>
\ No newline at end of file
diff --git a/dev-cpp/picojson/picojson-1.3.0.ebuild b/dev-cpp/picojson/picojson-1.3.0.ebuild
index ca57d8fb939c..69aa38b5ea25 100644
--- a/dev-cpp/picojson/picojson-1.3.0.ebuild
+++ b/dev-cpp/picojson/picojson-1.3.0.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2023 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -11,7 +11,7 @@ SRC_URI="https://github.com/kazuho/picojson/archive/v${PV}.tar.gz -> ${P}.tar.gz
 
 LICENSE="BSD-2"
 SLOT="0"
-KEYWORDS="~amd64"
+KEYWORDS="~amd64 ~x86"
 
 src_compile() {
 	:
diff --git a/dev-cpp/scitokens-cpp/metadata.xml b/dev-cpp/scitokens-cpp/metadata.xml
index 8cb7923156d1..043451253c2f 100644
--- a/dev-cpp/scitokens-cpp/metadata.xml
+++ b/dev-cpp/scitokens-cpp/metadata.xml
@@ -2,9 +2,17 @@
 <!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
 <pkgmetadata>
  <maintainer type="person">
+  <email>o.freyermuth@googlemail.com</email>
+  <name>Oliver Freyermuth</name>
+ </maintainer>
+ <maintainer type="person">
   <email>amadio@gentoo.org</email>
   <name>Guilherme Amadio</name>
  </maintainer>
+ <maintainer type="project">
+  <email>proxy-maint@gentoo.org</email>
+  <name>Proxy Maintainers</name>
+ </maintainer>
  <longdescription lang="en">
   SciTokens provide a token format for distributed authorization. The tokens are
   self-describing, can be verified in a distributed fashion (no need to contact
diff --git a/dev-cpp/scitokens-cpp/scitokens-cpp-1.0.1-r1.ebuild b/dev-cpp/scitokens-cpp/scitokens-cpp-1.0.1-r1.ebuild
new file mode 100644
index 000000000000..19a7d9f94ecc
--- /dev/null
+++ b/dev-cpp/scitokens-cpp/scitokens-cpp-1.0.1-r1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/scitokens/scitokens-cpp"
+else
+	SRC_URI="https://github.com/scitokens/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION=" A C++ implementation of the SciTokens library with a C library interface"
+HOMEPAGE="https://scitokens.org/"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="test"
+
+DEPEND="
+	dev-cpp/jwt-cpp
+	dev-db/sqlite
+	dev-libs/openssl:0=
+	net-misc/curl:0=
+	sys-apps/util-linux
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	test? ( dev-cpp/gtest )
+"
+RESTRICT="!test? ( test )"
+
+src_prepare() {
+	# Unbundle dev-cpp/gtest, dev-cpp/jwt-cpp
+	rm -r vendor || die
+	# Fix include path for picojson.
+	find src/ \( -name '*.cpp' -o -name '*.h' \) -type f -print0 | \
+		xargs -0 sed -r -e "s:picojson/picojson\.h:picojson.h:g" -i || die
+	# Disable network-based tests relying on external services.
+	if use test; then
+		sed -i	-e '/^TEST_F/s#RefreshTest#DISABLED_RefreshTest#' \
+			-e '/^TEST_F/s#RefreshExpiredTest#DISABLED_RefreshExpiredTest#' test/main.cpp || die
+	fi
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DSCITOKENS_BUILD_UNITTESTS="$(usex test)"
+		-DSCITOKENS_EXTERNAL_GTEST=YES
+	)
+	cmake_src_configure
+}