Adding metadata

3 files changed, 90 insertions, 0 deletions

diff --git a/dev-cpp/sdbus-c++/Manifest b/dev-cpp/sdbus-c++/Manifest
new file mode 100644
index 000000000000..9f8fb85d545c
--- /dev/null
+++ b/dev-cpp/sdbus-c++/Manifest
@@ -0,0 +1 @@
+DIST sdbus-c++-2.3.1.tar.gz 263568 BLAKE2B ae36590d5b3cfb3d1c26fbfb6ec69d6e517b31615ebae0c77e9e6b95864fe61fc102f94de670011aef025ba75cd609907d83d889b83e62f793dd1b161af5c841 SHA512 621618ad88a379788714fe5291c4db88a0d21fce92e7ca0d0e72d5a230d83f916a4ae89341a603542275a3700b264e769e111562a6468bd4b76e21495358bc2a
diff --git a/dev-cpp/sdbus-c++/metadata.xml b/dev-cpp/sdbus-c++/metadata.xml
new file mode 100644
index 000000000000..23e12fd528ef
--- /dev/null
+++ b/dev-cpp/sdbus-c++/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>chewi@gentoo.org</email>
+    <name>James Le Cuirot</name>
+  </maintainer>
+  <use>
+    <flag name="systemd">Use external libsystemd instead of statically-linked build</flag>
+    <flag name="tools">Install interface stub code generator</flag>
+  </use>
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
diff --git a/dev-cpp/sdbus-c++/sdbus-c++-2.3.1.ebuild b/dev-cpp/sdbus-c++/sdbus-c++-2.3.1.ebuild
new file mode 100644
index 000000000000..824802974d39
--- /dev/null
+++ b/dev-cpp/sdbus-c++/sdbus-c++-2.3.1.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson cmake
+
+DESCRIPTION="High-level C++ D-Bus library"
+HOMEPAGE="https://github.com/Kistler-Group/sdbus-cpp"
+SRC_URI="https://github.com/Kistler-Group/sdbus-cpp/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/sdbus-cpp-${PV}"
+
+LICENSE="LGPL-2.1+ Nokia-Qt-LGPL-Exception-1.1" # Nothing to do with Qt but exception text is exactly the same.
+SLOT="0/2"
+KEYWORDS="~amd64 ~arm64"
+IUSE="doc +elogind systemd test tools"
+REQUIRED_USE="?? ( elogind systemd )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	elogind? ( >=sys-auth/elogind-252 )
+	systemd? ( >=sys-apps/systemd-252:= )
+	!elogind? ( !systemd? ( >=sys-libs/basu-0.2.1 ) )
+	tools? ( dev-libs/expat )
+"
+
+DEPEND="
+	${RDEPEND}
+	test? ( >=dev-cpp/gtest-1.14.0 )
+"
+
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-text/doxygen[dot] )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DSDBUSCPP_BUILD_CODEGEN=$(usex tools)
+		-DSDBUSCPP_BUILD_DOCS=yes
+		-DSDBUSCPP_BUILD_DOXYGEN_DOCS=$(usex doc)
+		-DSDBUSCPP_BUILD_LIBSYSTEMD=no
+		-DSDBUSCPP_BUILD_TESTS=$(usex test)
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile all $(usev doc)
+}
+
+src_test() {
+	if ! cmp -s {"${S}"/tests/integrationtests/files,/etc/dbus-1/system.d}/org.sdbuscpp.integrationtests.conf; then
+		ewarn "Not running the tests as a D-Bus configuration file has not been"
+		ewarn "installed yet or has changed since. The tests can be run after"
+		ewarn "the package has been merged."
+		return
+	elif [[ ! -S /run/dbus/system_bus_socket ]]; then
+		ewarn "Not running the tests as the system-wide D-Bus daemon is unavailable."
+		return
+	fi
+
+	# Can't use cmake_src_test with dbus-run-session. Don't bother with all the
+	# extra arguments because there's only two tests.
+	dbus-run-session ctest --test-dir "${BUILD_DIR}" || die
+}
+
+src_install() {
+	cmake_src_install
+	rm -v "${ED}"/usr/share/doc/${PF}/COPYING || die
+
+	if use test; then
+		# Delete installed test binaries.
+		rm -rv "${ED}"/usr/tests || die
+	fi
+}