Adding metadata

3 files changed, 82 insertions, 16 deletions

diff --git a/dev-cpp/libcmis/Manifest b/dev-cpp/libcmis/Manifest
index c1568ef2f82e..6dd6b81353db 100644
--- a/dev-cpp/libcmis/Manifest
+++ b/dev-cpp/libcmis/Manifest
@@ -1 +1,2 @@
+DIST libcmis-0.5.2-patchset.tar.xz 16632 BLAKE2B 0a9802955059214428e7c2d6171093b171e47899de05404ee462bbf2c68c808927759a0808d79aa3aa9c8b9cd1a60b55686f7596b121701704a2d9720d6a8ba8 SHA512 bca4cc908e5510a9f597d6f1b560b3bbfdcda185b79d21320c6e3f7e5c559b7dda375407dfd6f05420b6f4edd666f6e7e70b7b72808506acc22fdfdab344f52c
 DIST libcmis-0.5.2.tar.gz 295020 BLAKE2B 325eacedd87eb1888a439c727a648c5aeb8d58c9b80add9761ffc55381193b71b589865d13ecd55177faafa935642685001f60456c1354e037989b29e9451c05 SHA512 45d8cd6d420a9593b46e1f2d6fbf384ea248cb218b0db6326ee2f082ff29100b65a2cc999ccb849e61df4f4ed7c3721b09addc6c322ef03c6c93f8c0acc02bde
diff --git a/dev-cpp/libcmis/libcmis-0.5.2-r2.ebuild b/dev-cpp/libcmis/libcmis-0.5.2-r2.ebuild
new file mode 100644
index 000000000000..51b24e07e554
--- /dev/null
+++ b/dev-cpp/libcmis/libcmis-0.5.2-r2.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/tdf/libcmis.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/tdf/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
+	https://dev.gentoo.org/~asturm/distfiles/${P}-patchset.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+fi
+inherit autotools
+
+DESCRIPTION="C++ client library for the CMIS interface"
+HOMEPAGE="https://github.com/tdf/libcmis"
+
+LICENSE="|| ( GPL-2 LGPL-2 MPL-1.1 )"
+SLOT="0.5"
+IUSE="man test tools"
+
+RESTRICT="test"
+
+DEPEND="
+	dev-libs/boost:=
+	dev-libs/libxml2
+	net-misc/curl
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	man? (
+		app-text/docbook2X
+		dev-libs/libxslt
+	)
+	test? (
+		dev-util/cppcheck
+		dev-util/cppunit
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/${P}-icu-64.2.patch" # bug 674414
+	"${WORKDIR}/${P}-patchset/${P}-fix-onedrive.patch"
+	"${WORKDIR}/${P}-patchset/${P}-gdrive-do-not-allow-copying.patch"
+	"${WORKDIR}/${P}-patchset/${P}-onedrive-do-not-allow-copying.patch"
+	"${WORKDIR}/${P}-patchset/${P}-fix-gdrive-onedrive.patch"
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--program-suffix=-$(ver_cut 1-2)
+		--disable-werror
+		$(use_with man)
+		$(use_enable test tests)
+		$(use_enable tools client)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
diff --git a/dev-cpp/libcmis/libcmis-9999.ebuild b/dev-cpp/libcmis/libcmis-9999.ebuild
index 2cccc1fd0ee9..10de5182674b 100644
--- a/dev-cpp/libcmis/libcmis-9999.ebuild
+++ b/dev-cpp/libcmis/libcmis-9999.ebuild
@@ -1,25 +1,32 @@
 # Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
-if [[ ${PV} = 9999 ]]; then
+if [[ ${PV} == *9999* ]]; then
 	EGIT_REPO_URI="https://github.com/tdf/libcmis.git"
 	inherit git-r3
 else
 	SRC_URI="https://github.com/tdf/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
 	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~x86 ~amd64-linux ~x86-linux"
 fi
-inherit autotools flag-o-matic
+inherit autotools
 
 DESCRIPTION="C++ client library for the CMIS interface"
 HOMEPAGE="https://github.com/tdf/libcmis"
 
 LICENSE="|| ( GPL-2 LGPL-2 MPL-1.1 )"
 SLOT="0.5"
+IUSE="man test tools"
 
-IUSE="man static-libs test tools"
+RESTRICT="test"
 
+DEPEND="
+	dev-libs/boost:=
+	dev-libs/libxml2
+	net-misc/curl
+"
+RDEPEND="${DEPEND}"
 BDEPEND="
 	virtual/pkgconfig
 	man? (
@@ -31,14 +38,6 @@ BDEPEND="
 		dev-util/cppunit
 	)
 "
-DEPEND="
-	dev-libs/boost:=
-	dev-libs/libxml2
-	net-misc/curl
-"
-RDEPEND="${DEPEND}"
-
-RESTRICT="test"
 
 src_prepare() {
 	default
@@ -46,14 +45,10 @@ src_prepare() {
 }
 
 src_configure() {
-	# bug 618778
-	append-cxxflags -std=c++14
-
 	local myeconfargs=(
 		--program-suffix=-$(ver_cut 1-2)
 		--disable-werror
 		$(use_with man)
-		$(use_enable static-libs static)
 		$(use_enable test tests)
 		$(use_enable tools client)
 	)