Adding metadata

2 files changed, 131 insertions, 0 deletions

diff --git a/app-portage/gentoolkit/Manifest b/app-portage/gentoolkit/Manifest
index b445dab358ca..d56481748641 100644
--- a/app-portage/gentoolkit/Manifest
+++ b/app-portage/gentoolkit/Manifest
@@ -1,2 +1,3 @@
 DIST gentoolkit-0.7.2.tar.bz2 3190909 BLAKE2B b8646c98858cd4e7c1c4dee5656319fd30b2668ea0b6739e327b94fc9955bb0fd8591769df0168fae46a98e28a96d1a95ff28fa35fe4a146cb100c554cd8a55a SHA512 9afe0e249bcee9f184cf5e691dd841756d00ac4ea63de223d89bc6a4a457f30a7def4390afe2e3f6f83425828f4c22086d381930e35b161000dea4c7146d5cd2
 DIST gentoolkit-0.7.6.tar.bz2 3191813 BLAKE2B a56c575ab2026abe2ace0b6fe7c411d892b8aeb8722ecac929ccfe8da141683c630c490d35bedcfe0cf67e0fe071a2f45b7b7731b052a34b47f798c10102f240 SHA512 723611caea039272870b928a8fb3c2681fbde68ace09049d2f1b44fb9181b4ceb706593b9e6c7b4b465393e80e3582791c384d79b8622423bbc676b3d28a6a44
+DIST gentoolkit-0.8.0.tar.bz2 3191836 BLAKE2B 4fc4db2b394521ae6ee41b18868c022628a6c69d814810821713ba5b203d21e9bdda789ff37588efe77f2af7625a7b6993d4d24e68da2a13e8cdda2a25999767 SHA512 96d343401afd548106280120bfa7e8e25f3b31027cf84a3f950bec93680bc3fe49d56f1c0a6fb4284a8505bf1868a36d0f7eb68815c556edf0c48a541d172fad
diff --git a/app-portage/gentoolkit/gentoolkit-0.8.0.ebuild b/app-portage/gentoolkit/gentoolkit-0.8.0.ebuild
new file mode 100644
index 000000000000..93fd6972062a
--- /dev/null
+++ b/app-portage/gentoolkit/gentoolkit-0.8.0.ebuild
@@ -0,0 +1,130 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{13..14} )
+PYTHON_REQ_USE="xml(+),threads(+)"
+
+inherit meson python-r1 tmpfiles
+
+if [[ ${PV} = 9999* ]]; then
+	EGIT_REPO_URI="
+		https://anongit.gentoo.org/git/proj/gentoolkit.git
+		https://github.com/gentoo/gentoolkit
+	"
+	inherit git-r3
+else
+	SRC_URI="https://gitweb.gentoo.org/proj/gentoolkit.git/snapshot/${P}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos ~x64-solaris"
+fi
+
+DESCRIPTION="Collection of administration scripts for Gentoo"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Project:Portage-Tools"
+
+LICENSE="GPL-2"
+SLOT="0"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+# Need newer Portage for eclean-pkg API, bug #900224
+DEPEND="
+	>=sys-apps/portage-3.0.57[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	${DEPEND}
+	${PYTHON_DEPS}
+	app-alternatives/awk
+	sys-apps/gentoo-functions
+"
+
+# setuptools is still needed as a workaround for Python 3.12+ for now.
+# https://github.com/mesonbuild/meson/issues/7702
+#
+# >=meson-1.2.1-r1 for bug #912051
+BDEPEND="
+	${PYTHON_DEPS}
+	>=dev-build/meson-1.2.1-r1
+	$(python_gen_cond_dep '
+		dev-python/setuptools[${PYTHON_USEDEP}]
+	' python3_12)
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)
+"
+
+src_prepare() {
+	default
+	if use prefix-guest ; then
+		# use correct repo name, bug #632223
+		sed -i \
+			-e "/load_profile_data/s/repo='gentoo'/repo='gentoo_prefix'/" \
+			pym/gentoolkit/profile.py || die
+	fi
+}
+
+src_configure() {
+	local code_only=false
+	python_foreach_impl my_src_configure
+}
+
+my_src_configure() {
+	local emesonargs=(
+		-Dcode-only=${code_only}
+		$(meson_use test tests)
+		-Deprefix="${EPREFIX}"
+		-Ddocdir="${EPREFIX}/usr/share/doc/${PF}"
+	)
+
+	meson_src_configure
+	code_only=true
+}
+
+src_compile() {
+	python_foreach_impl meson_src_compile
+}
+
+src_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	python_foreach_impl epytest
+}
+
+src_install() {
+	python_foreach_impl my_src_install
+	dotmpfiles data/tmpfiles.d/revdep-rebuild.conf
+
+	local scripts
+	mapfile -t scripts < <(awk '/^#!.*python/ {print FILENAME} {nextfile}' "${ED}"/usr/bin/* || die)
+	python_replicate_script "${scripts[@]}"
+}
+
+my_src_install() {
+	local pydirs=(
+		"${D}$(python_get_sitedir)"
+	)
+
+	meson_src_install
+	python_optimize "${pydirs[@]}"
+}
+
+pkg_postinst() {
+	tmpfiles_process revdep-rebuild.conf
+
+	# Only show the elog information on a new install
+	if [[ ! ${REPLACING_VERSIONS} ]]; then
+		elog
+		elog "For further information on gentoolkit, please read the gentoolkit"
+		elog "guide: https://wiki.gentoo.org/wiki/Gentoolkit"
+		elog
+		elog "Another alternative to equery is app-portage/portage-utils"
+		elog
+		elog "Additional tools that may be of interest:"
+		elog
+		elog "    app-admin/eclean-kernel"
+		elog "    app-portage/diffmask"
+		elog "    app-portage/flaggie"
+		elog "    app-portage/portpeek"
+		elog "    app-portage/smart-live-rebuild"
+	fi
+}