Adding metadata

6 files changed, 193 insertions, 3 deletions

diff --git a/app-office/libreoffice-bin/libreoffice-bin-25.8.4-r1.ebuild b/app-office/libreoffice-bin/libreoffice-bin-25.8.4-r1.ebuild
index ee42c992b13d..7357fda6713c 100644
--- a/app-office/libreoffice-bin/libreoffice-bin-25.8.4-r1.ebuild
+++ b/app-office/libreoffice-bin/libreoffice-bin-25.8.4-r1.ebuild
@@ -19,7 +19,7 @@ S="${WORKDIR}"
 
 LICENSE="LGPL-3"
 SLOT="0"
-KEYWORDS="-* ~amd64"
+KEYWORDS="-* amd64"
 IUSE="java offlinehelp python"
 
 # "en:en-US" for mapping from Gentoo "en" to upstream "en-US" etc.
diff --git a/app-office/lyx/Manifest b/app-office/lyx/Manifest
index 616bfcce89e1..18a20c8595da 100644
--- a/app-office/lyx/Manifest
+++ b/app-office/lyx/Manifest
@@ -2,3 +2,5 @@ DIST lyx-2.4.4.tar.xz 18360996 BLAKE2B fb7bd1188061b1910eba00a2869321a7175ba8955
 DIST lyx-2.4.4.tar.xz.sig 310 BLAKE2B e06143dad791bf8b2bee7b10e11e2ef08634bc06efd23891e779d7e1129c07334171836ce42b9fddba23a658d31f81fd8edab3b93e2c08391a35bf28d4680b5f SHA512 1e81a83e2c5f1c3a446fef3afeaf6c169b50f0c747926b8d02cff1fcf25e5ae88a0494f9be399e389eebea51f5a09e2658cb31d5085d8e01358bfeda6a3bfb36
 DIST lyx-2.5.0.tar.xz 18650808 BLAKE2B 70a46dba51245449ae5e59992b6964e5de88053ee15a3340ce2a14740b2f8f5f8f424e50a5724a12b8c00bd6476409bbfc4c24848ef37c7ab84a6decd9d5f6dc SHA512 9e08529ef66fc908227e2504a33392baa2688c619d49666ac1c9cffedd7438496eee9cab8ad07abfb8891a11743f6b33193f90313198eb4d4a015c093a69b8a8
 DIST lyx-2.5.0.tar.xz.sig 310 BLAKE2B 8bd2f171af79f6112d132e2b0fa2942c995ed3e77f04acbcce09348b7511fae753ce38a54a53b0ba8f399b3dc82155822628b06a9fa045f20d15e88c90754264 SHA512 f55954042e37473275e070f3391097ef27fdd256d4820b4d1c49537116c4f9ecb1d6a962075d24872d0ea5403769938df0c5410a411943f11dea041c26c53ed4
+DIST lyx-2.5.1.tar.xz 18673876 BLAKE2B 698f3f708395c022ff99ec29d7b6a8f05c0defaef958542a579a8e7619a7c58ebc4ac63f5b520690ef83b276a443d039c9ae1586eef39986e4568382ae43e35c SHA512 77c3bd1deeb2c6d174d21ee9620654ac82d0695fbeba22b653819129d2d27f2a999e28cdff444c1e9fd64a0a7fae5ce0effa69818bce2aea1b708f7a27858e54
+DIST lyx-2.5.1.tar.xz.sig 310 BLAKE2B 27ccf3fea705655c16512ae50770e2423f53da101417ba56501d15fde52ddc540151b78d0f7aac73a1f57e044b724d6c040ff154abcb81400884cbccad984cea SHA512 c8832da923011049d525ec272a52fa8d07c303a8c8af860baa9c0267e8d53b95ebf271faf36334485e473e806d876696f5427a4b579c686b16c72cc7a64adac2
diff --git a/app-office/lyx/lyx-2.5.0.ebuild b/app-office/lyx/lyx-2.5.0.ebuild
index 073f98343376..687703f3fe5e 100644
--- a/app-office/lyx/lyx-2.5.0.ebuild
+++ b/app-office/lyx/lyx-2.5.0.ebuild
@@ -19,7 +19,7 @@ S=${WORKDIR}/${P/_rc/~RC}
 
 LICENSE="GPL-2+"
 SLOT="0"
-KEYWORDS="~amd64 ~arm64"
+KEYWORDS="amd64 ~arm64"
 IUSE="aspell cups dia dot enchant gnumeric html +hunspell +latex monolithic-build nls rcs rtf svg l10n_he"
 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
 RESTRICT="test"
diff --git a/app-office/lyx/lyx-2.5.1.ebuild b/app-office/lyx/lyx-2.5.1.ebuild
new file mode 100644
index 000000000000..c68585bfac00
--- /dev/null
+++ b/app-office/lyx/lyx-2.5.1.ebuild
@@ -0,0 +1,188 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit desktop font optfeature python-single-r1 cmake verify-sig xdg
+
+DESCRIPTION="WYSIWYM (What You See Is What You Mean) document processor based on LaTeX"
+HOMEPAGE="https://www.lyx.org/"
+SRC_URI="
+	http://ftp.lyx.org/pub/lyx/stable/$(ver_cut 1-2).x/${P/_rc/~RC}.tar.xz
+	http://ftp.lyx.org/pub/lyx/devel/lyx-$(ver_cut 1-2)/${P/_rc/~RC}.tar.xz
+	verify-sig? (
+		http://ftp.lyx.org/pub/lyx/stable/$(ver_cut 1-2).x/${P/_rc/~RC}.tar.xz.sig
+		http://ftp.lyx.org/pub/lyx/devel/lyx-$(ver_cut 1-2)/${P/_rc/~RC}.tar.xz.sig
+	)
+"
+S=${WORKDIR}/${P/_rc/~RC}
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="aspell cups dia dot enchant gnumeric html +hunspell +latex monolithic-build nls rcs rtf svg l10n_he"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="test"
+
+RDEPEND="${PYTHON_DEPS}
+	app-text/mythes
+	dev-qt/qt5compat:6
+	dev-qt/qtbase:6[concurrent,dbus,gui,widgets]
+	dev-qt/qtsvg:6
+	sys-apps/file
+	virtual/zlib:=
+	virtual/imagemagick-tools[png,svg?]
+	x11-libs/libxcb
+	x11-misc/xdg-utils
+	aspell? ( app-text/aspell )
+	cups? ( net-print/cups )
+	dia? ( app-office/dia )
+	dot? ( media-gfx/graphviz )
+	enchant? ( app-text/enchant:2 )
+	gnumeric? ( app-office/gnumeric )
+	html? ( dev-tex/html2latex )
+	hunspell? ( app-text/hunspell:= )
+	l10n_he? (
+		dev-tex/culmus-latex
+		dev-texlive/texlive-langarabic
+	)
+	latex? (
+		app-text/dvipng
+		app-text/ghostscript-gpl
+		app-text/ps2eps
+		app-text/texlive
+		dev-texlive/texlive-fontsrecommended
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-mathscience
+		dev-texlive/texlive-pictures
+		dev-texlive/texlive-plaingeneric
+		|| (
+			dev-tex/latex2html
+			dev-tex/hevea
+			dev-tex/tex4ht[java]
+			dev-tex/tth
+		)
+	)
+	rcs? ( dev-vcs/rcs )
+	rtf? (
+		app-text/unrtf
+		dev-tex/html2latex
+		dev-tex/latex2rtf
+	)
+	svg? ( || (
+		gnome-base/librsvg
+		media-gfx/inkscape
+	) )
+"
+DEPEND="${RDEPEND}"
+# bc needed http://comments.gmane.org/gmane.editors.lyx.devel/137498 and bug #787839
+BDEPEND="
+	app-alternatives/bc
+	virtual/pkgconfig
+	dev-qt/qttools:6[linguist]
+	nls? ( sys-devel/gettext )
+	verify-sig? ( sec-keys/openpgp-keys-lyx )
+"
+
+VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/lyx.asc"
+
+DOCS=( ANNOUNCE NEWS README RELEASE-NOTES UPGRADING )
+
+FONT_S="${S}/lib/fonts"
+FONT_SUFFIX="ttf"
+
+PATCHES=(
+	"${FILESDIR}"/lyx-2.4.0-fix-hunspell.patch
+	# Try first with xdg-open before hardcoded commands
+	# Patch from Debian using a similar approach to Fedora
+	"${FILESDIR}"/lyx-2.4.4-prefer-xdg-open.patch
+)
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	font_pkg_setup
+}
+
+src_prepare() {
+	sed "s:python -tt:${EPYTHON} -tt:g" -i lib/configure.py || die
+	cmake_src_prepare
+}
+
+src_configure() {
+	#bug 221921
+	export VARTEXFONTS="${T}"/fonts
+
+	local mycmakeargs=(
+		-DLYX_INSTALL=ON
+		-DLYX_USE_QT=QT6
+		-DLYX_INSTALL_PREFIX="${EPREFIX}/usr"
+		-DLYX_CXX_FLAGS_EXTRA="${CXXFLAGS}"
+
+		-DLYX_NLS=$(usex nls)
+		-DLYX_ASPELL=$(usex aspell)
+		-DLYX_ENCHANT=$(usex enchant)
+		-DLYX_HUNSPELL=$(usex hunspell)
+
+		# external dependencies
+		-DLYX_EXTERNAL_Z=ON
+		-DLYX_EXTERNAL_ICONV=ON
+		-DLYX_EXTERNAL_HUNSPELL=ON
+		-DLYX_EXTERNAL_MYTHES=ON
+		-DLYX_PROGRAM_SUFFIX=OFF
+
+		# debug control
+		-DLYX_NO_OPTIMIZE=OFF
+		-DLYX_RELEASE=ON
+		-DLYX_DEBUG=OFF
+		-DLYX_DEBUG_GLIBC=OFF
+		-DLYX_STDLIB_DEBUG=OFF
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	newicon -s 32 "development/Win32/packaging/icons/lyx_32x32.png" ${PN}.png
+	doicon -s 48 "lib/images/lyx.png"
+	doicon -s scalable "lib/images/lyx.svg"
+
+	# fix for bug 91108
+	if use latex; then
+		dosym -r /usr/share/lyx/tex /usr/share/texmf-site/tex/latex/lyx
+	fi
+
+	# fonts needed for proper math display, see also bug #15629
+	font_src_install
+
+	python_fix_shebang "${ED}"/usr/share/${PN}
+
+	if use hunspell; then
+		dosym ../myspell /usr/share/lyx/dicts
+		dosym ../myspell /usr/share/lyx/thes
+	fi
+}
+
+pkg_postinst() {
+	font_pkg_postinst
+	xdg_pkg_postinst
+
+	# fix for bug 91108
+	if use latex ; then
+		texhash || die
+	fi
+
+	optfeature "handling more fonts" dev-texlive/texlive-fontsextra
+}
+
+pkg_postrm() {
+	font_pkg_postrm
+	xdg_pkg_postrm
+
+	if use latex ; then
+		texhash || die
+	fi
+}
diff --git a/app-office/portfolio-performance-bin/Manifest b/app-office/portfolio-performance-bin/Manifest
index 202b3a3d0900..801cbd0b5de3 100644
--- a/app-office/portfolio-performance-bin/Manifest
+++ b/app-office/portfolio-performance-bin/Manifest
@@ -1,2 +1,2 @@
-DIST PortfolioPerformance-0.83.0-linux.gtk.x86_64.tar.gz 64451509 BLAKE2B 4975c338b8b7d6a980467ed10547fc9e65834ae24eb0c145da8635b913843154cd65191c7e75b1ce67f32d1550ab4581b0e9d9ac974020e3a32dd671f58baa1f SHA512 74743227073a2ab743c69c1e83c45a07d14aa141864fe3f55f272dc83922d5b1e5e05feb99c67fd27d7da1a181ff5f76256e1954a47f9dcf180e258b69c68342
 DIST PortfolioPerformance-0.83.1-linux.gtk.x86_64.tar.gz 64468698 BLAKE2B 592854954e53aeb0d65ce1e41fc9b5b710e94661c7de5b0b9af0b809763d2d43d20903a4305fe41d04c43085527ca919407cc2843265f64f8fd5fb7cca912a77 SHA512 d5f1802a90fe0fd0ed814708986643ac6ce6b79b66c56eb9a90930937a4167d3f788e4ca2d0921c7c04e86a00e2aad87d13a95dc145b2a21f9ce8c95dd3e6ddb
+DIST PortfolioPerformance-0.83.2-linux.gtk.x86_64.tar.gz 64482676 BLAKE2B 18290b9e5d9bdde457297bb4467d23a99f0f0e0cfcb29b28281f9ce782c6adef13f448ed6ac65b723f869757fe4fa8e51011eb3a6bc7a1de6afbe7cc663f26d8 SHA512 ff117ead5c37c338642ec2e7a53853e912b21edb81acaa2d93445e2aa1caaf572b1bed9ddcc304fc4492e52f63856a089af707c2efa2c814bcf84605caf9304c
diff --git a/app-office/portfolio-performance-bin/portfolio-performance-bin-0.83.0.ebuild b/app-office/portfolio-performance-bin/portfolio-performance-bin-0.83.2.ebuild
index b63c5fd0cec8..b63c5fd0cec8 100644
--- a/app-office/portfolio-performance-bin/portfolio-performance-bin-0.83.0.ebuild
+++ b/app-office/portfolio-performance-bin/portfolio-performance-bin-0.83.2.ebuild