Adding metadata

4 files changed, 116 insertions, 0 deletions

diff --git a/app-doc/gnu-c-intro-ref/Manifest b/app-doc/gnu-c-intro-ref/Manifest
new file mode 100644
index 000000000000..e0914329fac5
--- /dev/null
+++ b/app-doc/gnu-c-intro-ref/Manifest
@@ -0,0 +1 @@
+DIST c-intro-and-ref-0.1.tar.gz 1556218 BLAKE2B 7691d115a71b0a019c9b9f4d0c31a6d7a73a2a170a6fb1349064e766dd649c883f9c289f0a8301d7ea799ed8018e41a864a2b3a0aea44fbc1fabce204547d58c SHA512 f225ee2382b8146db91552ff6f9cf5facc4ce3fb82fba9d6f09c8f8b1a2be92bdf40f0c1917b5fcc9320a5e1a54e52573901e5660dacc7894d98bac50d195c06
diff --git a/app-doc/gnu-c-intro-ref/gnu-c-intro-ref-0.1.ebuild b/app-doc/gnu-c-intro-ref/gnu-c-intro-ref-0.1.ebuild
new file mode 100644
index 000000000000..f5a1999b3e2e
--- /dev/null
+++ b/app-doc/gnu-c-intro-ref/gnu-c-intro-ref-0.1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 2022-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="GNU C Language Intro and Reference Manual"
+HOMEPAGE="https://savannah.gnu.org/projects/c-intro-and-ref/"
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://git.savannah.gnu.org/git/c-intro-and-ref.git"
+	inherit git-r3
+elif [[ ${PV} != *_p* ]] ; then
+	SRC_URI="mirror://gnu/c-intro-and-ref/c-intro-and-ref-${PV}.tar.gz"
+	S="${WORKDIR}"/c-intro-and-ref-${PV}
+else
+	MY_COMMIT="62962013107481127176ef04d69826e41f51313c"
+	SRC_URI="https://git.savannah.nongnu.org/cgit/c-intro-and-ref.git/snapshot/c-intro-and-ref-${MY_COMMIT}.tar.gz"
+	S="${WORKDIR}"/c-intro-and-ref-${MY_COMMIT}
+fi
+
+LICENSE="FDL-1.3+"
+SLOT="0"
+IUSE="pdf"
+if [[ ${PV} != 9999 ]] ; then
+	KEYWORDS="~amd64 ~ppc64"
+fi
+
+BDEPEND="
+	sys-apps/texinfo
+	pdf? (
+		app-text/ghostscript-gpl
+		app-text/texlive-core
+		virtual/texi2dvi
+	)
+"
+
+src_prepare() {
+	default
+
+	# We don't need it for releases but they're infrequent, so let's
+	# not bother conditionalising it (as we often use snapshots).
+	eautoreconf
+}
+
+src_compile() {
+	emake info html $(usev pdf 'pdf')
+}
+
+src_install() {
+	emake DESTDIR="${D}" install-info install-html $(usev pdf 'install-pdf')
+}
diff --git a/app-doc/gnu-c-intro-ref/gnu-c-intro-ref-9999.ebuild b/app-doc/gnu-c-intro-ref/gnu-c-intro-ref-9999.ebuild
new file mode 100644
index 000000000000..f67150d705c8
--- /dev/null
+++ b/app-doc/gnu-c-intro-ref/gnu-c-intro-ref-9999.ebuild
@@ -0,0 +1,53 @@
+# Copyright 2022-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="GNU C Language Intro and Reference Manual"
+HOMEPAGE="https://savannah.gnu.org/projects/c-intro-and-ref/"
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://git.savannah.gnu.org/git/c-intro-and-ref.git"
+	inherit git-r3
+elif [[ ${PV} != *_p* ]] ; then
+	SRC_URI="mirror://gnu/c-intro-and-ref/c-intro-and-ref-${PV}.tar.gz"
+	S="${WORKDIR}"/c-intro-and-ref-${PV}
+else
+	MY_COMMIT="62962013107481127176ef04d69826e41f51313c"
+	SRC_URI="https://git.savannah.nongnu.org/cgit/c-intro-and-ref.git/snapshot/c-intro-and-ref-${MY_COMMIT}.tar.gz"
+	S="${WORKDIR}"/c-intro-and-ref-${MY_COMMIT}
+fi
+
+LICENSE="FDL-1.3+"
+SLOT="0"
+IUSE="pdf"
+if [[ ${PV} != 9999 ]] ; then
+	KEYWORDS="~amd64"
+fi
+
+BDEPEND="
+	sys-apps/texinfo
+	pdf? (
+		app-text/ghostscript-gpl
+		app-text/texlive-core
+		virtual/texi2dvi
+	)
+"
+
+src_prepare() {
+	default
+
+	# We don't need it for releases but they're infrequent, so let's
+	# not bother conditionalising it (as we often use snapshots).
+	eautoreconf
+}
+
+src_compile() {
+	emake info html $(usev pdf 'pdf')
+}
+
+src_install() {
+	emake DESTDIR="${D}" install-info install-html $(usev pdf 'install-pdf')
+}
diff --git a/app-doc/gnu-c-intro-ref/metadata.xml b/app-doc/gnu-c-intro-ref/metadata.xml
new file mode 100644
index 000000000000..d9201802d6c5
--- /dev/null
+++ b/app-doc/gnu-c-intro-ref/metadata.xml
@@ -0,0 +1,9 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>sam@gentoo.org</email>
+    <name>Sam James</name>
+  </maintainer>
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>