# Copyright 2026 BaldEagleOS Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8

inherit cmake-multilib

MY_SIMD=(
	x86_{avx,avx2,avx512f,sse,sse2,ssse3,sse4_2}
	arm_neon
)

DESCRIPTION="Open-source implementation of JPEG2000 Part-15, aka JPH or HTJ2K"
HOMEPAGE="https://github.com/aous72/OpenJPH"
SRC_URI="https://github.com/aous72/OpenJPH/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="BSD-2"
KEYWORDS="~amd64"
SLOT="0/$(ver_cut 2)"
RESTRICT="primaryuri"
S="${WORKDIR}/OpenJPH-${PV}"
IUSE="${MY_SIMD[@]/#/cpu_flags_} +simd tiff"

DEPEND="
	tiff? ( media-libs/tiff:=[${MULTILIB_USEDEP}] )
"
RDEPEND="
	${DEPEND}
"
multilib_src_configure() {
	local mycmakeargs=(
		-DOJPH_ENABLE_TIFF_SUPPORT=$(usex tiff)
		-DOJPH_BUILD_STREAM_EXPAND=yes
		-DOJPH_DISABLE_SIMD=$(usex !simd)
	)
	if use simd; then
		mycmakeargs+=(
			-DOJPH_DISABLE_AVX=$(usex !cpu_flags_x86_avx)
			-DOJPH_DISABLE_AVX2=$(usex !cpu_flags_x86_avx2)
			-DOJPH_DISABLE_AVX512=$(usex !cpu_flags_x86_avx512f)
			-DOJPH_DISABLE_SSE=$(usex !cpu_flags_x86_sse)
			-DOJPH_DISABLE_SSE2=$(usex !cpu_flags_x86_sse2)
			-DOJPH_DISABLE_SSSE3=$(usex !cpu_flags_x86_ssse3)
			-DOJPH_DISABLE_SSE4=$(usex !cpu_flags_x86_sse4_2)
			-DOJPH_DISABLE_NEON=$(usex !cpu_flags_arm_neon)
		)
	fi
	cmake_src_configure
}