# Copyright 2026 BaldEagleOS Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517="setuptools"
PYTHON_COMPAT=( python3_{13..14} )

inherit distutils-r1

DESCRIPTION="Inspectable orchestration around Portage and OSForge runs"
HOMEPAGE="https://git.baldeagleos.com/osforge"
SRC_URI="https://distfiles.baldeagleos.com/${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64"
IUSE="usb-writer"

PATCHES=(
	"${FILESDIR}/osforge-0.2.1-fast-seed-restore.patch"
)

RDEPEND="
	${PYTHON_DEPS}
	acct-group/osforge
	app-arch/tar
	dev-python/prompt-toolkit[${PYTHON_USEDEP}]
	dev-vcs/git
	net-misc/rsync
	sys-apps/portage
	usb-writer? (
		sys-apps/gptfdisk
		sys-block/parted
		sys-boot/grub
		sys-fs/dosfstools
		sys-fs/e2fsprogs
	)
"
BDEPEND="
	test? (
		app-arch/tar
		dev-vcs/git
		net-misc/rsync
	)
"

distutils_enable_tests unittest

python_test() {
	eunittest -s tests
}

python_install_all() {
	distutils-r1_python_install_all

	newinitd src/osforge/data/openrc/osforged osforged
	newconfd src/osforge/data/openrc/osforged.confd osforged

	dodoc -r examples

	if use usb-writer; then
		dosbin scripts/osforge-write-usb
	fi
}

pkg_postinst() {
	elog "OSForge installed. To start the daemon now:"
	elog "  rc-service osforged start"
	elog "To enable it at boot:"
	elog "  rc-update add osforged default"
}